Формула электронной таблицы для назначения буквенных оценок на основе числовых диапазонов

Я пытаюсь выяснить, как написать оператор IF, который будет «истинным», если значение находится между двумя значениями.

Пример:

Если значение находится между 60 и 69,9, вернуть «D»

Если значение находится между 70 и 79,9, вернуть «C»

Если значение находится между 80 и 89,9, вернуть «B»

У меня есть это, но я не могу понять, как его изменить, чтобы тест был промежуточным, а не меньшим или большим, чем.

=IF(A1<60, "F", IF(A1>60, "A", 0))

Держите знаки неравенства в одном направлении:

=IF(A1<60, "F", IF(A1<70, "D", IF(A1<80, "C", IF(A1<90, "B", "A"))))

Вышеуказанное работает нормально, если не так много случаев. Но если бы у вас было много вариантов, C-, C +, B-, B + ... было бы лучше вместо этого использовать таблицу поиска. Например, если у вас есть справочная таблица, такая как приведенная ниже, то

=vlookup(A1, $K$1:$L$5) 

выполняет ту же работу, что и вложенные IF. Таблицу также легче поддерживать в случае изменений: например, вы решили перенести некоторые отсечки.

+---+----+---+
|   | K  | L |
+---+----+---+
| 1 |  0 | F |
| 2 | 60 | D |
| 3 | 70 | C |
| 4 | 80 | B |
| 5 | 90 | A |
+---+----+---+

Другое решение, взятое на Справочном форуме Документов Google , поддерживает срезы непосредственно в формуле, что исключает возможность их сохранения отдельно.

Для отрезков, определенных в OP, формула

=VLOOKUP($A1,{0,"F";60,"D";70,"C";80,"B";90,"A"},2)

Изменение срезов может показаться громоздким, но это можно сделать следующим образом. Измените срезы в формуле в самой верхней ячейке, а затем fill downвыполните a CMD-Dили в CTRL-Dзависимости от вашей платформы.

Я изменил пороговые значения @ wsaleem, добавив оценки - / + (по шкале в моем колледже):

=VLOOKUP(BB2,{0,"F";60,"D-";63,"D";68,"D+";70,"C-";73,"C";78,"C+";80,"B-";83,"B";88,"B+";90,"A-";93,"A"},2)

Убедитесь, что ROUND () ваше входное значение. Я использовал AVERAGE (), и хотя поле визуально округлено, значение не было.