Как рассчитать разницу времени в моих таблицах Google?

У меня есть таблица Google, которая выглядит примерно так:

 Date        | Start time  | End time    | Minutes
 ------------+-------------+-------------+-----------
 1/11/2012   | 11:39       | 12:41       | ?!
 ------------+-------------+-------------+-----------
             |             |             | 

Прямо сейчас, если я вручную укажу количество минут между двумя временами дня. Есть ли простой способ рассчитать дельту времени и сделать это для меня в электронной таблице?

Google добавил новый числовой формат под названием «Продолжительность». Установите начальное и конечное поля, Format -> Number -> Timeа поле вычисления -Format -> Number -> Duration

Как только вы это сделаете, вы можете вычесть поля, чтобы получить разницу, как отметил Стефано Палаццо в своем ответе.

Да, если ваши поля времени правильно отформатированы (нажмите Формат → Число → Время ), вы можете просто добавить и вычесть время:

=C2-B2

или же

21:58:00 - 20:44:00 = 1:14:00

Это даст вам время дельта как HH:MM:SS. И если вы хотите , чтобы вычислить количество минут, вы можете использовать Hour(), Minute()и Second()функцию на этом поле:

=(Hour(D2) * 60) + Minute(D2) + (Second(D2) / 60)

Конечно, если есть високосные секунды, изменения часового пояса или если событие занимает больше 24 часов, вам все равно придется корректировать результаты вручную.

Предупреждение

Если одно событие продлится после полуночи, скажем, с 23:50 до 00:10, это будет отрицательное время!

Чтобы эти события обрабатывались «правильно», вы можете либо поставить «24:10», либо разбить событие на две части.

Лучший способ

Несмотря на то, что вводить данные немного сложнее, самый надежный способ сделать это - пометить поле начала и окончания как «Дата и время», а поле дельты - как «Часы», которое будет выглядеть так:

Beginning          End                  Delta
8/1/2013 0:00:00   8/2/2013 12:30:00    36:30:00

Если вы добавите следующую формулу в D2, то минуты будут рассчитаны автоматически:

формула

=ARRAYFORMULA(IF(ISBLANK(B2:B)=FALSE,((C2:C-B2:B)*24*60),""))

Разъяснения

Разница между временами в десятичном формате выражается в днях. Следовательно, умножение на время 24 на 60 приведет к минутам.

замечание

Есть одно предварительное условие: столбец D должен быть отформатирован как «нормальный».

пример

Смотрите пример файла, который я создал: Delta Time

Для более надежного решения мы используем пользовательскую функцию.

1. Добавление пользовательской функции

Использование редактора сценариев (следуйте инструкциям в https://developers.google.com/apps-script/execution_custom_functions ) - пишет:

function toEpoch (indate) {
  return indate.getTime();
}

2. Добавить формуляр

Затем в клетке пишет:

=(toEpoch(C2)-toEpoch(B2)) / 60*1000

Который конвертирует разницу в миллисекундах эпохи в минуты.

Я провел много экспериментов. Это самый простой способ вычислить разницу времени в таблицах Google. Отформатируйте ячейку, содержащую формулу, следующим образом:

Формат> Число> Дополнительные форматы> Дополнительные форматы даты и времени , удалите «второй» и :. Затем отформатируйте время окончания и время начала клетки , как это: h:mm am/pm.

Используйте формулу =abs(end time - start time). Это дает вам абсолютное значение, поэтому не будет отрицательных значений времени.

Намного проще: посмотрите на этот ответ на форуме Excel:

B2: 23:00
C2: 1:37
D2: =C2-B2+(B2>C2)

Почему это работает, время - это доля дня, сравнение B2> C2 возвращает True (1) или False (0), если добавлено true 1 день (24 часа).

Если вы хотите, чтобы ваша дельта времени измерялась в днях, используйте

=DAYS(end_date, start_date)

Вы также можете попробовать TIMEVALUE().

В приведенном выше случае решение будет:

(TIMEVALUE(End Time) - TIMEVALUE(Start Time))*24*60 даст вам разницу во времени в МИНУТАХ.

В Google Sheets я использовал следующую формулу

=Round((hour(A2-A1)*60 + minute(A2-A1))/60,2)

чтобы дать мне разницу в десятичных часах.

Я использую эту формулу:

=HOUR(C2-B2)*60+MINUTE(C2-B2)

тогда

Format -> Number -> More Formats -> Custom number format -> #,##0

=(C2-B1)*1440 затем установите формат «Обычный текст».

Для моего личного заявления:

StartTime (columnA)| EndTime(Column B)| Date (Column C)

Это сработало для меня:
=if(B4-A4<0,(B4+C4+1)-(A4+C4),B4-A4);Формат ячейки как Формат \ Время \ Продолжительность.

Для истинного состояния: формула, вдохновленная комментариями Стефано Палаццо.

Я согласен, что дельта времени выражается в днях, поэтому, чтобы вернуться к минутам, нужно умножить разницу на 1440, что составляет 24 x 60.

У меня была эта проблема сегодня, и я подумал, что упомяну другой простой способ узнать текущее время в электронной таблице Google Docs - ввести CONTROL:ячейку. Вы можете использовать это как для начальной, так и для конечной ячейки.

Если вам нужно ввести текущую дату в ячейку, то это достигается CONTROL;