TSQL - Как использовать GO внутри блока BEGIN .. END?

Я создаю сценарий для автоматического переноса изменений из нескольких баз данных разработки в промежуточную / производственную. По сути, он берет кучу сценариев изменений и объединяет их в один сценарий, заключая каждый сценарий в IF whatever BEGIN ... ENDоператор.

Однако для некоторых сценариев требуется GOоператор, чтобы, например, синтаксический анализатор SQL знал о новом столбце после его создания.

ALTER TABLE dbo.EMPLOYEE 
ADD COLUMN EMP_IS_ADMIN BIT NOT NULL
GO -- Necessary, or next line will generate "Unknown column:  EMP_IS_ADMIN"
UPDATE dbo.EMPLOYEE SET EMP_IS_ADMIN = whatever

Однако, как только я заключу это в IFблок:

IF whatever
BEGIN
    ALTER TABLE dbo.EMPLOYEE ADD COLUMN EMP_IS_ADMIN BIT NOT NULL
    GO
    UPDATE dbo.EMPLOYEE SET EMP_IS_ADMIN = whatever
END

Это не удается, потому что я отправляю BEGINбез соответствия END. Однако, если я удалю, GOон снова жалуется на неизвестный столбец.

Есть ли способ создать и обновить один и тот же столбец в одном IFблоке?

У меня была такая же проблема, и мне, наконец, удалось решить ее с помощью SET NOEXEC .

IF not whatever
BEGIN
    SET NOEXEC ON; 
END

ALTER TABLE dbo.EMPLOYEE ADD COLUMN EMP_IS_ADMIN BIT NOT NULL
GO
UPDATE dbo.EMPLOYEE SET EMP_IS_ADMIN = whatever

SET NOEXEC OFF; 

GO не является SQL - это просто разделитель пакетов, используемый в некоторых инструментах MS SQL.

Если вы не используете это, вам необходимо убедиться, что операторы выполняются отдельно - либо в разных пакетах, либо с использованием динамического SQL для населения (спасибо @gbn):

IF whatever
BEGIN
    ALTER TABLE dbo.EMPLOYEE ADD COLUMN EMP_IS_ADMIN BIT NOT NULL;

    EXEC ('UPDATE dbo.EMPLOYEE SET EMP_IS_ADMIN = whatever')
END

Вы можете попробовать sp_executesqlразделить содержимое каждого GOоператора на отдельную строку для выполнения, как показано в примере ниже. Кроме того, существует переменная @statementNo, чтобы отслеживать, какой оператор выполняется, для упрощения отладки, где произошло исключение. Номера строк будут относиться к началу номера соответствующего оператора, вызвавшего ошибку.

BEGIN TRAN

DECLARE @statementNo INT
BEGIN TRY
    IF 1=1
    BEGIN
        SET @statementNo = 1
        EXEC sp_executesql
            N'  ALTER TABLE dbo.EMPLOYEE
                    ADD COLUMN EMP_IS_ADMIN BIT NOT NULL'

        SET @statementNo = 2
        EXEC sp_executesql
            N'  UPDATE dbo.EMPLOYEE
                    SET EMP_IS_ADMIN = 1'

        SET @statementNo = 3
        EXEC sp_executesql
            N'  UPDATE dbo.EMPLOYEE
                    SET EMP_IS_ADMIN = 1x'
    END
END TRY
BEGIN CATCH
    PRINT 'Error occurred on line ' + cast(ERROR_LINE() as varchar(10)) 
       + ' of ' + 'statement # ' + cast(@statementNo as varchar(10)) 
       + ': ' + ERROR_MESSAGE()
    -- error occurred, so rollback the transaction
    ROLLBACK
END CATCH
-- if we were successful, we should still have a transaction, so commit it
IF @@TRANCOUNT > 0
    COMMIT

Вы также можете легко выполнять многострочные операторы, как показано в примере выше, просто заключив их в одинарные кавычки ( '). Не забывайте экранировать одинарные кавычки внутри строки двойными одинарными кавычками ( '') при создании скриптов.

В конечном итоге я заставил его работать, заменив каждый экземпляр в GOотдельной строке на

END
GO

---Automatic replacement of GO keyword, need to recheck IF conditional:
IF whatever
BEGIN

Это намного предпочтительнее, чем заключать каждую группу операторов в строку, но все же далеко от идеала. Если кто-нибудь найдет лучшее решение, опубликуйте его, и я приму его.

Вы можете заключить инструкции в BEGIN и END вместо GO между

IF COL_LENGTH('Employees','EMP_IS_ADMIN') IS NULL --Column does not exist
BEGIN
    BEGIN
        ALTER TABLE dbo.Employees ADD EMP_IS_ADMIN BIT
    END

    BEGIN
        UPDATE EMPLOYEES SET EMP_IS_ADMIN = 0
    END
END

(Проверено в базе данных Northwind)

Изменить: (Вероятно, протестировано на SQL2012)

Вы можете попробовать это решение:

if exists(
SELECT...
)
BEGIN
PRINT 'NOT RUN'
RETURN
END

--if upper code not true

ALTER...
GO
UPDATE...
GO

Я использовал RAISERRORв прошлом для этого

IF NOT whatever BEGIN
    RAISERROR('YOU''RE ALL SET, and sorry for the error!', 20, -1) WITH LOG
END

ALTER TABLE dbo.EMPLOYEE ADD COLUMN EMP_IS_ADMIN BIT NOT NULL
GO
UPDATE dbo.EMPLOYEE SET EMP_IS_ADMIN = whatever

Вы можете включить операторы GOTOи, LABELчтобы пропустить код, оставив GOключевые слова нетронутыми.