Получение результата динамического SQL в переменную для sql-сервера

116

Выполнение динамического SQL следующим образом в хранимой процедуре:

DECLARE @sqlCommand nvarchar(1000)
DECLARE @city varchar(75)
SET @city = 'London'
SET @sqlCommand = 'SELECT COUNT(*) FROM customers WHERE City = @city'
EXECUTE sp_executesql @sqlCommand, N'@city nvarchar(75)', @city = @city

Как использовать значение столбца count (*) в качестве возвращаемого значения в SP?

sql sql-server sql-server-2005 tsql dynamic-sql Питер Линдхольм
источник

203

DECLARE @sqlCommand nvarchar(1000)
DECLARE @city varchar(75)
declare @counts int
SET @city = 'New York'
SET @sqlCommand = 'SELECT @cnt=COUNT(*) FROM customers WHERE City = @city'
EXECUTE sp_executesql @sqlCommand, N'@city nvarchar(75),@cnt int OUTPUT', @city = @city, @cnt=@counts OUTPUT
select @counts as Counts

шалфей
источник

4

+1: вы меня опередили, нужно объявить переменную и пометить ее как ВЫХОД. Для получения дополнительной информации и рекомендуемой литературы по динамическому SQL SQL Server см. Проклятие и благословение динамического SQL

OMG Ponies

1

Спасибо. Ключевое слово OUTPUT в N '@ city nvarchar (75), @ cnt int OUTPUT' было тем, чего мне не хватало.

Питер Линдхольм,

1

Нет ли решения, которое не требует добавления выходной переменной в динамический оператор ???

Tab Alleman

2

Вы, наверное, пробовали это, но ваши спецификации позволяют это сделать?

DECLARE @city varchar(75)
DECLARE @count INT
SET @city = 'London'
SELECT @count = COUNT(*) FROM customers WHERE City = @city

штифтик
источник

2

динамическая версия

    ALTER PROCEDURE [dbo].[ReseedTableIdentityCol](@p_table varchar(max))-- RETURNS int
    AS
    BEGIN
        -- Declare the return variable here
       DECLARE @sqlCommand nvarchar(1000)
       DECLARE @maxVal INT
       set @sqlCommand = 'SELECT @maxVal = ISNULL(max(ID),0)+1 from '+@p_table
       EXECUTE sp_executesql @sqlCommand, N'@maxVal int OUTPUT',@maxVal=@maxVal OUTPUT
       DBCC CHECKIDENT(@p_table, RESEED, @maxVal)
    END


exec dbo.ReseedTableIdentityCol @p_table='Junk'

Эб Беннетт
источник

0

DECLARE @sqlCommand nvarchar(1000)
DECLARE @city varchar(75)
DECLARE @cnt int
SET @city = 'London'
SET @sqlCommand = 'SELECT @cnt=COUNT(*) FROM customers WHERE City = @city'
EXECUTE sp_executesql @sqlCommand, N'@city nvarchar(75)', @city = @city
RETURN @cnt

CristiC
источник

1

Думаю, твой ответ оборвался.

Sage

Msg 137, Must declare the scalar variable "@cnt". Msg 178, A RETURN statement with a return value cannot be used in this context.. Хорошая работа, братан))

it3xl

0

это могло быть решением?

declare @step2cmd nvarchar(200)
DECLARE @rcount NUMERIC(18,0)   
set @step2cmd = 'select count(*) from uat.ap.ztscm_protocollo' --+ @nometab
EXECUTE @rcount=sp_executesql @step2cmd
select @rcount

Стефано Педоне
источник

-2

 vMYQUERY := 'SELECT COUNT(*) FROM ALL_OBJECTS WHERE OWNER = UPPER(''MFI_IDBI2LIVE'') AND OBJECT_TYPE = ''TABLE'' 
    AND OBJECT_NAME  =''' || vTBL_CLIENT_MASTER || '''';
    PRINT_STRING(VMYQUERY);
    EXECUTE IMMEDIATE  vMYQUERY INTO VCOUNTTEMP ;

Paone
источник

Это не относится к sql server.

Роберт Луджо

Получение результата динамического SQL в переменную для sql-сервера

Ответы: