Как я могу удалить все файлы / подпапки в данной папке через командную строку?

Я хотел бы удалить все файлы и подпапки в пакетном файле в Windows 7 и сохранить верхнюю папку. В основном очистка папки. Какова инструкция командной строки для этого?

Вы можете сделать это, используя delи /Sфлаг (чтобы удалить все файлы из всех подкаталогов):

del /S C:\Path\to\directory\*

Лучшее решение: например, я хочу удалить все файлы и подкаталоги родительского каталога, скажем «C: \ Users \ Desktop \ New folder \». Самый простой способ - создать командный файл из трех команд.

cd C: \ Users \ Desktop \ Новая папка \

del * / S / Q

rmdir / S / Q "C: \ Users \ Desktop \ Новая папка \"

Здесь сначала он очистит все файлы во всех подкаталогах, а затем очистит все пустые подкаталоги. Так как текущий рабочий каталог является родительским каталогом, то есть "\ New folder", команда rmdir не может удалить этот каталог самостоятельно.

Перейдите в родительский каталог:

pushd "Parent Directory"

Удалить вложенные папки:

rd /s /q . 2>nul

rmdir "c:\pathofyourdirectory" /q /s

Не забудьте использовать кавычки, и для /q /sэтого будут удалены все хранилища и без запроса.

Вы можете использовать rmdir для удаления файлов и подпапок, например так:

rmdir /s/q MyFolderPath

Тем не менее, это значительно быстрее, особенно когда в вашей структуре много подпапок для использования del перед rmdir, например:

del /f/s/q MyFolderPath > nul
rmdir /s/q MyFolderPath

Если вы хотите удалить все файлы в папке, включая все подпапки, и не полагаться на некоторые условия ошибки, чтобы сохранить корневую папку нетронутой (как я видел в другом ответе), у вас может быть пакетный файл, подобный этому:

@echo off

REM Checking for command line parameter
if "%~1"=="" (

    echo Parameter required.
    exit /b 1

) else (

    REM Change directory and keep track of the previous one
    pushd "%~1"

    if errorlevel 1 (

        REM The directory passed from command line is not valid, stop here.
        exit /b %errorlevel%

    ) else (

        REM First we delete all files, including the ones in the subdirs, without confirmation
        del * /S /Q

        REM Then we delete all the empty subdirs that were left behind
        for /f %%D IN ('dir /b /s /a:d "%~1"') DO rmdir /S /Q "%%D"

        REM Change directory back to the previous one
        popd

        REM All good.
        exit /b 0
    )

)

И тогда вы просто позвоните с помощью:

empty_my_folder.bat "C:\whatever\is\my folder"

Вы можете сделать это быстро и легко, поместив эти три инструкции в свой файл bat:

mkdir empty_folder
robocopy /mir empty_folder "path_to_directory"
rmdir empty_folder

Это работало лучше для меня, когда у меня были пробелы в именах папок.

@echo off
REM ---- Batch file to clean out a folder
REM Checking for command line parameter
if "%~1"=="" (

echo Parameter required.
exit /b 1

) else (
echo ***********************************************************************************
    echo *** Deleting all files, including the ones in the subdirs, without confirmation *** 
    del "%~1\*" /S /Q
echo ***********************************************************************************
    REM Deleting all the empty subdirs that were left behind
FOR /R "%~1" %%D IN (.) DO (
    if "%%D"=="%~1\."  (
    echo *** Cleaning out folder: %~1 *** 
    ) else (
    echo Removed folder "%%D"
    rmdir /S /Q "%%D"
    )
) 

    REM All good.
    exit /b 0

)

Чтобы удалить файл:

del PATH_TO_FILE

Чтобы удалить папку со всеми файлами в ней:

rmdir /s /q PATH_TO_FOLDER

Удалить все файлы из определенной папки (не удаляя саму папку) немного сложнее. del /s *.*не может удалить папки, но удаляет файлы из всех подпапок. Итак, нужны две команды:

del /q PATH_TO_FOLDER\*.*
for /d %i in (PATH_TO_FOLDER\*.*) do @rmdir /s /q "%i"

Вы можете создать скрипт для удаления всего, что вы хотите (папка или файл), например mydel.bat:

@echo off
setlocal enableextensions

if "%~1"=="" (
    echo Usage: %0 path
    exit /b 1
)

:: check whether it is folder or file
set ISDIR=0
set ATTR=%~a1
set DIRATTR=%ATTR:~0,1%
if /i "%DIRATTR%"=="d" set ISDIR=1

:: Delete folder or file
if %ISDIR%==1 (rmdir /s /q "%~1") else (del "%~1")
exit /b %ERRORLEVEL%

Несколько примеров использования:

mydel.bat "path\to\folder with spaces"
mydel.bat path\to\file_or_folder

Это то, что сработало для меня.

1. Перейдите в папку, где вы хотите удалить файлы.
2. Тип: del *
3. Y за да.
4. Выполнено