ярлык для создания карты из списка в Groovy?

Мне бы для этого нужна какая-то рука:

Map rowToMap(row) {
    def rowMap = [:];
    row.columns.each{ rowMap[it.name] = it.val }
    return rowMap;
}

учитывая то, как устроен GDK, я ожидал, что смогу сделать что-то вроде:

Map rowToMap(row) {
    row.columns.collectMap{ [it.name,it.val] }
}

но я ничего не видел в документации ... я что-то упускаю? или я просто слишком ленив?

Недавно я столкнулся с необходимостью сделать именно это: преобразовать список в карту. Этот вопрос был опубликован до выхода Groovy версии 1.7.9, поэтому метода collectEntriesеще не существовало. Работает в точности так, как был предложенcollectMap метод :

Map rowToMap(row) {
    row.columns.collectEntries{[it.name, it.val]}
}

Если по какой-то причине вы застряли на более старой версии Groovy, этот injectметод также можно использовать (как предлагается здесь ). Это немного измененная версия, которая принимает только одно выражение внутри замыкания (просто для сохранения символов!):

Map rowToMap(row) {
    row.columns.inject([:]) {map, col -> map << [(col.name): col.val]}
}

+Оператор также может быть использован вместо <<.

Отъезд "залить". Настоящие любители функционального программирования называют это «сворачиванием».

columns.inject([:]) { memo, entry ->
    memo[entry.name] = entry.val
    return memo
}

И пока вы это делаете, вы, вероятно, захотите определять методы как категории, а не прямо в метаклассе. Таким образом, вы можете определить его один раз для всех коллекций:

class PropertyMapCategory {
    static Map mapProperty(Collection c, String keyParam, String valParam) {
        return c.inject([:]) { memo, entry ->
            memo[entry[keyParam]] = entry[valParam]
            return memo
        }
    }
}

Пример использования:

use(PropertyMapCategory) {
    println columns.mapProperty('name', 'val')
}

Был ли метод groupBy недоступен, когда задавался этот вопрос?

Если вам нужна простая пара "ключ-значение", этого метода collectEntriesдолжно хватить. Например

def names = ['Foo', 'Bar']
def firstAlphabetVsName = names.collectEntries {[it.charAt(0), it]} // [F:Foo, B:Bar]

Но если вам нужна структура, подобная Multimap, в которой есть несколько значений для каждого ключа, тогда вы захотите использовать groupByметод

def names = ['Foo', 'Bar', 'Fooey']
def firstAlphabetVsNames = names.groupBy { it.charAt(0) } // [F:[Foo, Fooey], B:[Bar]]

Кроме того, если вы используете коллекции Google ( http://code.google.com/p/google-collections/ ), вы можете сделать что-то вроде этого:

  map = Maps.uniqueIndex(list, Functions.identity());

хорошо ... Я поигрался с этим еще немного, и я думаю, что это довольно крутой метод ...

def collectMap = {Closure callback->
    def map = [:]
    delegate.each {
        def r = callback.call(it)
        map[r[0]] = r[1]
    }
    return map
}
ExpandoMetaClass.enableGlobally()
Collection.metaClass.collectMap = collectMap
Map.metaClass.collectMap = collectMap

теперь любой подкласс Map или Collection имеет этот метод ...

здесь я использую его, чтобы изменить ключ / значение на карте

[1:2, 3:4].collectMap{[it.value, it.key]} == [2:1, 4:3]

а здесь я использую его для создания карты из списка

[1,2].collectMap{[it,it]} == [1:1, 2:2]

теперь я просто вставляю это в класс, который вызывается при запуске моего приложения, и этот метод доступен во всем моем коде.

РЕДАКТИРОВАТЬ:

чтобы добавить метод ко всем массивам ...

Object[].metaClass.collectMap = collectMap

Я не могу найти ничего встроенного ... но с помощью ExpandoMetaClass я могу сделать это:

ArrayList.metaClass.collectMap = {Closure callback->
    def map = [:]
    delegate.each {
        def r = callback.call(it)
        map[r[0]] = r[1]
    }
    return map
}

это добавляет метод collectMap ко всем ArrayLists ... Я не уверен, почему добавление его в List или Collection не сработало ... Думаю, это для другого вопроса ... но теперь я могу это сделать ...

assert ["foo":"oof", "42":"24", "bar":"rab"] ==
            ["foo", "42", "bar"].collectMap { return [it, it.reverse()] }

из списка в рассчитанную карту с одним закрытием ... именно то, что я искал.

Изменить: причина, по которой я не мог добавить метод в список интерфейсов и коллекцию, заключалась в том, что я этого не делал:

List.metaClass.enableGlobally()

после вызова этого метода вы можете добавлять методы в интерфейсы ... что в данном случае означает, что мой метод collectMap будет работать с такими диапазонами:

(0..2).collectMap{[it, it*2]}

что дает карту: [0: 0, 1: 2, 2: 4]

А что насчет этого?

// setup
class Pair { 
    String k; 
    String v; 
    public Pair(def k, def v) { this.k = k ; this.v = v; }
}
def list = [ new Pair('a', 'b'), new Pair('c', 'd') ]

// the idea
def map = [:]
list.each{ it -> map.putAt(it.k, it.v) }

// verify
println map['c']