При написании командного файла для автоматизации чего-либо на Windows-боксе мне нужно было приостановить его выполнение на несколько секунд (обычно в цикле тестирования / ожидания, ожидая запуска процесса). В то время лучшее решение, которое я мог найти, использует ping (я не шучу) для достижения желаемого эффекта. Я нашел лучшую рецензию его здесь , который описывает вызываемый «wait.bat», осуществляется следующим образом :

@ping 127.0.0.1 -n 2 -w 1000 > nul
@ping 127.0.0.1 -n %1% -w 1000> nul

Затем вы можете включить вызовы wait.bat в свой собственный пакетный файл, передав количество секунд, в течение которых он переходит в режим ожидания.

Очевидно, Windows 2003 Resource Kit предоставляет Unix-подобную команду сна (наконец-то!). В то же время, для тех из нас, кто все еще использует Windows XP, Windows 2000 или (к сожалению) Windows NT , есть ли лучший способ?

Я изменил sleep.pyскрипт в принятом ответе , так что по умолчанию он равен одной секунде, если в командной строке не передано никаких аргументов:

import time, sys

time.sleep(float(sys.argv[1]) if len(sys.argv) > 1 else 1)

ОБНОВИТЬ

Команда timeout, доступная в Windows Vista и далее, должна быть используемой командой, как описано в другом ответе на этот вопрос. Ниже следует старый ответ.

Старый ответ

Если у вас установлен Python или вы не против его установить (он также используется и в других целях :), просто создайте следующий скрипт sleep.py и добавьте его где-нибудь в вашей переменной PATH:

import time, sys

time.sleep(float(sys.argv[1]))

Это позволит делать субсекундные паузы (например, 1,5 с, 0,1 и т. Д.), Если у вас есть такая необходимость. Если вы хотите назвать его как, sleepа не как sleep.py, то вы можете добавить .PYрасширение в переменную среды PATHEXT. В Windows XP вы можете редактировать его в:

Мой компьютер → Свойства (меню) → Дополнительно (вкладка) → Переменные среды (кнопка) → Системные переменные (рамка)

Команда timeoutдоступна в Windows Vista и более поздних версиях:

c:\> timeout /?

TIMEOUT [/T] timeout [/NOBREAK]

Description:
    This utility accepts a timeout parameter to wait for the specified
    time period (in seconds) or until any key is pressed. It also
    accepts a parameter to ignore the key press.

Parameter List:
    /T        timeout       Specifies the number of seconds to wait.
                            Valid range is -1 to 99999 seconds.

    /NOBREAK                Ignore key presses and wait specified time.

    /?                      Displays this help message.

NOTE: A timeout value of -1 means to wait indefinitely for a key press.

Examples:
    TIMEOUT /?
    TIMEOUT /T 10
    TIMEOUT /T 300 /NOBREAK
    TIMEOUT /T -1

Примечание: он не работает с перенаправлением ввода - тривиальный пример:

C:\>echo 1 | timeout /t 1 /nobreak
ERROR: Input redirection is not supported, exiting the process immediately.

Используя ping описанный выше метод, я делаю это, когда не могу (или не хочу) добавлять дополнительные исполняемые файлы или устанавливать любое другое программное обеспечение.

Вы должны быть то , что не существует пинг, и используя -wфлаг так , чтобы он не после этого промежутка времени, не пинг то , что это есть (как локальный хост) -nраз. Это позволяет обрабатывать время менее секунды, и я думаю, что это немного более точно.

например

(проверить, что 1.1.1.1 не принято)

ECHO Waiting 15 seconds

PING 1.1.1.1 -n 1 -w 15000 > NUL
  or
PING -n 15 -w 1000 127.1 >NUL

SLEEP.exeвходит в большинство комплектов ресурсов, например, комплект ресурсов Windows Server 2003, который также можно установить в Windows XP.

Usage:  sleep      time-to-sleep-in-seconds
        sleep [-m] time-to-sleep-in-milliseconds
        sleep [-c] commited-memory ratio (1%-100%)

Я не согласен с ответами, которые нашел здесь.

Я использую следующий метод, полностью основанный на возможностях Windows XP, чтобы сделать задержку в командном файле:

DELAY.BAT:

@ECHO OFF
REM DELAY seconds

REM GET ENDING SECOND
FOR /F "TOKENS=1-3 DELIMS=:." %%A IN ("%TIME%") DO SET /A H=%%A, M=1%%B%%100, S=1%%C%%100, ENDING=(H*60+M)*60+S+%1

REM WAIT FOR SUCH A SECOND
:WAIT
FOR /F "TOKENS=1-3 DELIMS=:." %%A IN ("%TIME%") DO SET /A H=%%A, M=1%%B%%100, S=1%%C%%100, CURRENT=(H*60+M)*60+S
IF %CURRENT% LSS %ENDING% GOTO WAIT

Вы также можете вставить день в расчет, чтобы метод также работал, когда интервал задержки превышал полночь.

Я столкнулся с подобной проблемой, но я просто выбил очень короткое консольное приложение C ++, чтобы сделать то же самое. Просто запустите MySleep.exe 1000 - возможно, проще, чем скачать / установить весь комплект ресурсов.

#include <tchar.h>
#include <stdio.h>
#include "Windows.h"

int _tmain(int argc, _TCHAR* argv[])
{
    if (argc == 2)
    {
        _tprintf(_T("Sleeping for %s ms\n"), argv[1]);
        Sleep(_tstoi(argv[1]));
    }
    else
    {
        _tprintf(_T("Wrong number of arguments.\n"));
    }
    return 0;
}

В Server Fault, был задан похожий вопрос , и решение было:

choice /d y /t 5 > nul

Вы можете использовать слой WSH cscript для Windows и этот файл JavaScript wait.js :

if (WScript.Arguments.Count() == 1)
    WScript.Sleep(WScript.Arguments(0)*1000);
else
    WScript.Echo("Usage: cscript wait.js seconds");

В зависимости от ваших потребностей совместимости, используйте ping:

ping -n <numberofseconds+1> localhost >nul 2>&1

например, подождать 5 секунд, используйте

ping -n 6 localhost >nul 2>&1

или на Windows 7 или более поздней версии timeout:

timeout 6 >nul

Вы можете использовать пинг:

ping 127.0.0.1 -n 11 -w 1000 >nul: 2>nul:

Это будет ждать 10 секунд.

Причина, по которой вы должны использовать 11, заключается в том, что первый пинг пропадает сразу, а не через одну секунду. Число всегда должно быть на единицу больше, чем количество секунд, которое вы хотите подождать.

Имейте в виду, что цель -wсостоит не в том, чтобы ждать одну секунду. Это гарантирует, что вы будете ждать не более одной секунды в случае возникновения проблем с сетью. pingсам отправит один ICMP-пакет в секунду. Это, вероятно, не требуется для localhost, но старые привычки сильно умирают.

Есть лучший способ спать, используя пинг. Вы захотите пропинговать адрес, который не существует, поэтому вы можете указать время ожидания с точностью до миллисекунды. К счастью, такой адрес определен в стандарте (RFC 3330), и это так 192.0.2.x. Это не выдумка, это действительно адрес с единственной целью несуществования (это может быть непонятно, но это применимо даже в локальных сетях):

192.0.2.0/24 - Этот блок назначен как «TEST-NET» для использования в документации и примере кода. Он часто используется вместе с именами доменов example.com или example.net в документации поставщика и протокола. Адреса в этом блоке не должны появляться в общедоступном Интернете.

Чтобы спать в течение 123 миллисекунд, используйте ping 192.0.2.1 -n 1 -w 123 >nul

Если у вас есть PowerShell в вашей системе, вы можете просто выполнить эту команду:

powershell -command "Start-Sleep -s 1"

Изменить: из моего ответа на аналогичную тему , люди подняли вопрос о том, сколько времени требуется PowerShell, чтобы начать, по сравнению с тем, сколько времени вы пытаетесь ждать. Если важна точность времени ожидания (т. Е. Дополнительная или вторая задержка не приемлема), вы можете использовать этот подход:

powershell -command "$sleepUntil = [DateTime]::Parse('%date% %time%').AddSeconds(5); $sleepDuration = $sleepUntil.Subtract((get-date)).TotalMilliseconds; start-sleep -m $sleepDuration"

Это занимает время, когда была введена команда windows, и сценарий powershell спит до 5 секунд после этого времени. Так что, пока PowerShell требует меньше времени для запуска, чем продолжительность сна, этот подход будет работать (на моей машине это около 600 мс).

timeout /t <seconds> <options>

Например, чтобы скрипт выполнял непрерывное 2-секундное ожидание:

timeout /t 2 /nobreak >NUL

Это означает, что сценарий будет ждать 2 секунды, прежде чем продолжить.

По умолчанию нажатие клавиши прерывает тайм-аут, поэтому используйте /nobreakпереключатель, если вы не хотите, чтобы пользователь мог прервать (отменить) ожидание. Кроме того, время ожидания предоставит посекундные уведомления, чтобы уведомить пользователя о том, сколько еще осталось ждать; это можно удалить, отправив командуNUL .

редактировать: как @martineau указывает в комментариях , timeoutкоманда доступна только в Windows 7 и выше. Кроме того, pingкоманда использует меньше процессорного времени, чем timeout. Я все еще верю в использование, timeoutгде это возможно, хотя, поскольку это более читабельно, чем ping«взломать». Узнайте больше здесь .

Просто поместите это в ваш пакетный файл, где вы хотите ждать.

@ping 127.0.0.1 -n 11 -w 1000 > null

В блокноте напишите:

@echo off
set /a WAITTIME=%1+1
PING 127.0.0.1 -n %WAITTIME% > nul
goto:eof

Теперь сохраните как wait.bat в папке C: \ WINDOWS \ System32, затем, когда вы захотите подождать, используйте:

CALL WAIT.bat <whole number of seconds without quotes>

Пакет ресурсов всегда включал это. По крайней мере, с Windows 2000.

Кроме того, в пакете Cygwin есть sleep- plop, который входит в вашу PATH, и включает cygwin.dll(или как он там называется) и путь!

Мне нравится ответ Аасини . Я добавил его для обработки дня, а также включил обработку секунд ( %TIME%выходных данных H:MM:SS.CC):

:delay
SET DELAYINPUT=%1
SET /A DAYS=DELAYINPUT/8640000
SET /A DELAYINPUT=DELAYINPUT-(DAYS*864000)

::Get ending centisecond (10 milliseconds)
FOR /F "tokens=1-4 delims=:." %%A IN ("%TIME%") DO SET /A H=%%A, M=1%%B%%100, S=1%%C%%100, X=1%%D%%100, ENDING=((H*60+M)*60+S)*100+X+DELAYINPUT
SET /A DAYS=DAYS+ENDING/8640000
SET /A ENDING=ENDING-(DAYS*864000)

::Wait for such a centisecond
:delay_wait
FOR /F "tokens=1-4 delims=:." %%A IN ("%TIME%") DO SET /A H=%%A, M=1%%B%%100, S=1%%C%%100, X=1%%D%%100, CURRENT=((H*60+M)*60+S)*100+X
IF DEFINED LASTCURRENT IF %CURRENT% LSS %LASTCURRENT% SET /A DAYS=DAYS-1
SET LASTCURRENT=%CURRENT%
IF %CURRENT% LSS %ENDING% GOTO delay_wait
IF %DAYS% GTR 0 GOTO delay_wait
GOTO :EOF

Я использовал эту программу сна C #. Возможно, вам будет удобнее, если вы предпочитаете C #:

using System;
using System.Collections.Generic;
using System.Linq;
using System.Text;
using System.Threading;

namespace sleep
{
    class Program
    {
        static void Main(string[] args)
        {
            if (args.Length == 1)
            {
                double time = Double.Parse(args[0]);
                Thread.Sleep((int)(time*1000));
            }
            else
            {
                Console.WriteLine("Usage: sleep <seconds>\nExample: sleep 10");
            }
        }
    }
}

Еще более легким, чем решение Python, является однострочный Perl.

Чтобы поспать семь секунд, поместите это в скрипт BAT:

perl -e "sleep 7"

Это решение обеспечивает разрешение только в одну секунду.

Если вам нужно более высокое разрешение, используйте модуль Time :: HiRes из CPAN. Он обеспечивает то, usleep()что спит в микросекундах, а nanosleep()какое - в наносекундах (обе функции принимают только целочисленные аргументы). См. Вопрос переполнения стека. Как мне спать на миллисекундах в Perl? для дальнейших деталей.

Я использовал ActivePerl в течение многих лет. Это очень легко установить.

Или командная строка Python, например, за 6 с половиной секунд:

python -c "import time;time.sleep(6.5)"

Использование пинга - это хорошо, если вы просто хотите «немного подождать». Это связано с тем, что вы зависите от других функций, таких как ваша сеть и тот факт, что на 127.0.0.1 ничего не отвечает. ;-) Может быть, это не очень вероятно, что это не удастся, но это не невозможно ...

Если вы хотите быть уверены, что вы ждете точно указанное время, вы должны использовать sleep функциональность (которая также имеет то преимущество, что она не использует мощность процессора или ожидает готовности сети).

Найти уже готовый исполняемый файл для сна - самый удобный способ. Просто поместите его в свою папку Windows или любую другую часть стандартного пути, и он всегда доступен.

В противном случае, если у вас есть среда компиляции, вы можете легко создать ее самостоятельно. SleepФункция доступна kernel32.dll, так что вам просто нужно использовать , что один. :-) Для VB / VBA объявите следующее в начале вашего источника, чтобы объявить функцию сна:

private Declare Sub Sleep Lib "kernel32" Alias "Sleep" (byval dwMilliseconds as Long)

Для C #:

[DllImport("kernel32.dll")]
static extern void Sleep(uint dwMilliseconds);

Вы найдете здесь больше об этой функции (доступно с Windows 2000) в спящем режиме (MSDN).

В стандарте C sleep()он включен в стандартную библиотеку, а в Microsoft Visual Studio C эта функция называется Sleep(), если мне не изменяет память. ;-) Эти два принимают аргумент в секундах, а не в миллисекундах, как два предыдущих объявления.

Лучшее решение, которое должно работать на всех версиях Windows после Windows 2000:

timeout numbersofseconds /nobreak > nul

Pathping.exe может спать меньше секунды.

@echo off
setlocal EnableDelayedExpansion 
echo !TIME! & pathping localhost -n -q 1 -p %~1 2>&1 > nul & echo !TIME!

,

> sleep 10
17:01:33,57
17:01:33,60

> sleep 20
17:03:56,54
17:03:56,58

> sleep 50
17:04:30,80
17:04:30,87

> sleep 100
17:07:06,12
17:07:06,25

> sleep 200
17:07:08,42
17:07:08,64

> sleep 500
17:07:11,05
17:07:11,57

> sleep 800
17:07:18,98
17:07:19,81

> sleep 1000
17:07:22,61
17:07:23,62

> sleep 1500
17:07:27,55
17:07:29,06

Я впечатлен этим:

http://www.computerhope.com/batch.htm#02

choice /n /c y /d y /t 5 > NUL

Технически вы говорите choiceкоманде принять только y. По умолчанию используется значение y, чтобы сделать это за 5 секунд, не выводить подсказки и выводить все, что говорит NUL (например, нулевой терминал в Linux).

Вы также можете использовать файл .vbs для определенных таймаутов:

Код ниже создает файл .vbs. Поместите это в верхней части кода rbatch:

echo WScript.sleep WScript.Arguments(0) >"%cd%\sleeper.vbs"

Затем приведенный ниже код открывает файл .vbs и указывает, как долго ждать:

start /WAIT "" "%cd%\sleeper.vbs" "1000"

В приведенном выше коде «1000» - это значение временной задержки, отправляемой в файл .vbs в миллисекундах, например, 1000 мс = 1 с. Вы можете изменить эту часть так долго, как вы хотите.

Код ниже удаляет файл .vbs после того, как вы закончите с ним. Поместите это в конец вашего командного файла:

del /f /q "%cd%\sleeper.vbs"

И вот код все вместе, поэтому его легко скопировать:

echo WScript.sleep WScript.Arguments(0) >"%cd%\sleeper.vbs"
start /WAIT "" "%cd%\sleeper.vbs" "1000"
del /f /q "%cd%\sleeper.vbs"

Начиная с Windows Vista, у вас есть команды TIMEOUT и SLEEP , но чтобы использовать их в Windows XP или Windows Server 2003, вам потребуется набор ресурсов Windows Server 2003 .

Здесь у вас есть хороший обзор альтернатив сна (подход ping является наиболее популярным, поскольку он будет работать на каждой машине с Windows), но есть (по крайней мере) не упомянутое, которое (ab) использует команду W32TM(Time Service):

w32tm /stripchart /computer:localhost /period:1 /dataonly /samples:N  >nul 2>&1

Где вы должны заменить N на секунды, которые вы хотите сделать паузу. Кроме того, он будет работать в любой системе Windows без предварительных условий.

Typeperf также можно использовать:

typeperf "\System\Processor Queue Length" -si N -sc 1 >nul

С помощью mshta и javascript (можно использовать для сна менее секунды):

start "" /wait /min /realtime mshta "javascript:setTimeout(function(){close();},5000)"

Это должно быть еще точнее (для ожидания менее секунды) - самокомпилируемый исполняемый файл, основанный на .net:

@if (@X)==(@Y) @end /* JScript comment
@echo off
setlocal
::del %~n0.exe /q /f
::
:: For precision better call this like
:: call waitMS 500
:: in order to skip compilation in case there's already built .exe
:: as without pointed extension first the .exe will be called due to the ordering in PATEXT variable
::
::
for /f "tokens=* delims=" %%v in ('dir /b /s /a:-d  /o:-n "%SystemRoot%\Microsoft.NET\Framework\*jsc.exe"') do (
   set "jsc=%%v"
)

if not exist "%~n0.exe" (
    "%jsc%" /nologo /w:0 /out:"%~n0.exe" "%~dpsfnx0"
)


%~n0.exe %*

endlocal & exit /b %errorlevel%


*/


import System;
import System.Threading;

var arguments:String[] = Environment.GetCommandLineArgs();
function printHelp(){
    Console.WriteLine(arguments[0]+" N");
    Console.WriteLine(" N - milliseconds to wait");
    Environment.Exit(0);    
}

if(arguments.length<2){
    printHelp();
}

try{
    var wait:Int32=Int32.Parse(arguments[1]);
    System.Threading.Thread.Sleep(wait);
}catch(err){
    Console.WriteLine('Invalid Number passed');
    Environment.Exit(1);
}

Есть много способов сделать сон cmd / batch »:

Мой любимый:

TIMEOUT /NOBREAK 5 >NUL 2>NUL

Это остановит консоль на 5 секунд без вывода.

Наиболее используемое:

ping localhost -n 5 >NUL 2>NUL

Это попытается установить соединение до localhost5 раз. Поскольку он размещен на вашем компьютере, он всегда достигает хоста, поэтому каждую секунду он будет пробовать новое каждую секунду. -nФлаг указывает на то, сколько раз скрипт будет пытаться соединение. В этом случае это 5, так что это будет длиться 5 секунд.

Варианты последнего:

ping 1.1.1.1 -n 5 >nul

В этом скрипте есть некоторые отличия по сравнению с последним. Это не будет пытаться позвонить localhost. Вместо этого он попытается подключиться к 1.1.1.1очень быстрому веб-сайту. Действие будет длиться 5 секунд, только если у вас есть активное подключение к Интернету. Иначе это продлится приблизительно 15, чтобы закончить действие . Я не рекомендую использовать этот метод.

ping 127.0.0.1 -n 5 >nul

Это точно так же, как в примере 2 (чаще всего используется). Также вы можете также использовать:

ping [::1] -n 5 >nul

Вместо этого используется localhostверсия IPv6 .

Есть много способов выполнить это действие. Однако я предпочитаю метод 1 для Windows Vista и более поздних версий и наиболее часто используемый метод (метод 2) для более ранних версий ОС.

Вы можете получить фантазию, поместив сообщение PAUSE в строку заголовка:

@ECHO off
SET TITLETEXT=Sleep
TITLE %TITLETEXT%
CALL :sleep 5
GOTO :END
:: Function Section
:sleep ARG
ECHO Pausing...
FOR /l %%a in (%~1,-1,1) DO (TITLE Script %TITLETEXT% -- time left^
 %%as&PING.exe -n 2 -w 1000 127.1>NUL)
EXIT /B 0
:: End of script
:END
pause
::this is EOF

Это было проверено на Windows XP SP3 и Windows 7 и использует CScript. Я поставил несколько безопасных предохранителей, чтобы избежать подсказок. ( /qбыло бы опасно)

Подождите одну секунду:

sleepOrDelayExecution 1000

Подождите 500 мс, а затем запустите вещи после:

sleepOrDelayExecution 500 dir \ /s

sleepOrDelayExecution.bat:

@echo off
if "%1" == "" goto end
if NOT %1 GTR 0 goto end
setlocal
set sleepfn="%temp%\sleep%random%.vbs"
echo WScript.Sleep(%1) >%sleepfn%
if NOT %sleepfn% == "" if NOT EXIST %sleepfn% goto end
cscript %sleepfn% >nul
if NOT %sleepfn% == "" if EXIST %sleepfn% del %sleepfn%
for /f "usebackq tokens=1*" %%i in (`echo %*`) DO @ set params=%%j
%params%
:end

Поскольку другие предлагают сторонние программы (Python, Perl, пользовательские приложения и т. Д.), Другой вариант - GNU CoreUtils для Windows, доступный по адресу http://gnuwin32.sourceforge.net/packages/coreutils.htm .

2 варианта размещения:

1. Установите полный пакет (который будет включать полный пакет CoreUtils, зависимости, документацию и т. Д.).
2. Устанавливайте только двоичный файл «sleep.exe» и необходимые зависимости (для получения зависимостей используйте зависимость от.exe).

Одним из преимуществ развертывания CoreUtils является то, что вы дополнительно получите множество других программ, которые полезны для сценариев (пакет Windows оставляет желать лучшего).