Как правильно выровнять регион и / или линию?

Мы можем центрировать текст с помощью M-x center-regionи M-o M-s. Есть ли что-то подобное для выравнивания по правому краю?

Пример перед:

Item 0: value                                                       |
Item 100: value                                                     |
Item 30: value                                                      |

после:

                                                       Item 0: value|
                                                     Item 100: value|
                                                      Item 30: value|
                                                       fill-column  ^

Какой самый простой способ выровнять текст по правому краю?

Согласно руководству по заполнению , некоторые функции заполнения принимают необязательный аргумент JUSTIFY, который вы можете использовать. Так, например, чтобы заполнить абзац правильным обоснованием, вы можете использовать (fill-paragraph 'right).

Вы также можете использовать (justify-current-line 'right)для одной строки.

Если вы планируете часто использовать эти параметры, вы можете заключить их в функции, такие как следующие, и затем связать эти функции с клавишами по вашему выбору:

(defun right-justify-current-line ()
  "Right-justify this line."
  (interactive)
  (justify-current-line 'right))

(defun right-fill-paragraph ()
  "Fill paragraph with right justification."
  (interactive)
  (fill-paragraph 'right))

Вот функция, которую вы можете использовать в качестве замены fill-paragraph. С различными префиксами это позволяет вам решить, какое оправдание использовать в абзаце, который вы заполняете:

(defun fill-paragraph-dwim (&optional arg)
  "Fills the paragraph as normal with no prefix. With C-u,
right-justify.  With C-u C-u, center-justify.  With C-u C-u C-u,
full-justify."
  (interactive "p")
  (fill-paragraph (cond ((= arg 4)  'right)
                        ((= arg 16) 'center)
                        ((= arg 64) 'full))))

Если вы не хотите заполнять при выравнивании по правому краю, вы можете использовать следующую функцию, которая извлекается непосредственно из center-regionфункции с изменением в одну строку, чтобы выровнять ее по правому краю:

(defun right-region (from to)
  "Right-justify each nonblank line starting in the region."
  (interactive "r")
  (if (> from to)
      (let ((tem to))
    (setq to from from tem)))
  (save-excursion
    (save-restriction
      (narrow-to-region from to)
      (goto-char from)
      (while (not (eobp))
    (or (save-excursion (skip-chars-forward " \t") (eolp))
        ;; (center-line))              ; this was the original code
        (justify-current-line 'right)) ; this is the new code
    (forward-line 1)))))