T SQL табличная функция для разделения столбца на запятые

Я написал функцию с табличными значениями в Microsoft SQL Server 2008, чтобы в столбце базы данных содержался столбец с разделителями-запятыми, чтобы он выдвигал отдельные строки для каждого значения.

Пример: «один, два, три, четыре» вернул бы новую таблицу только с одним столбцом, содержащим следующие значения:

one
two
three
four

Ребята, этот код выглядит для вас подверженным ошибкам? Когда я проверяю это с

SELECT * FROM utvf_Split('one,two,three,four',',') 

он работает вечно и ничего не возвращает. Это становится действительно обескураживающим, особенно потому, что на сервере MSSQL нет встроенных функций разделения (ПОЧЕМУ, ПОЧЕМУ, ПОЧЕМУ ?!), и все подобные функции, которые я обнаружил в Интернете, являются абсолютным мусором или просто не имеют отношения к тому, что я пытаюсь сделать ,

Вот функция:

USE *myDBname*
GO
SET ANSI_NULLS ON
GO
SET QUOTED_IDENTIFIER ON
GO
ALTER FUNCTION [dbo].[utvf_SPlit] (@String VARCHAR(MAX), @delimiter CHAR)

RETURNS @SplitValues TABLE
(
    Asset_ID VARCHAR(MAX) NOT NULL
)

AS
BEGIN
            DECLARE @FoundIndex INT
            DECLARE @ReturnValue VARCHAR(MAX)

            SET @FoundIndex = CHARINDEX(@delimiter, @String)

            WHILE (@FoundIndex <> 0)
            BEGIN
                  DECLARE @NextFoundIndex INT
                  SET @NextFoundIndex = CHARINDEX(@delimiter, @String, @FoundIndex+1)
                  SET @ReturnValue = SUBSTRING(@String, @FoundIndex,@NextFoundIndex-@FoundIndex)
                  SET @FoundIndex = CHARINDEX(@delimiter, @String)
                  INSERT @SplitValues (Asset_ID) VALUES (@ReturnValue)
            END

            RETURN
END

Переделал это немного ...

DECLARE @FoundIndex INT
DECLARE @ReturnValue VARCHAR(MAX)

SET @FoundIndex = CHARINDEX(@delimiter, @String)

WHILE (@FoundIndex <> 0)
BEGIN
      SET @ReturnValue = SUBSTRING(@String, 0, @FoundIndex)
      INSERT @SplitValues (Asset_ID) VALUES (@ReturnValue)
      SET @String = SUBSTRING(@String, @FoundIndex + 1, len(@String) - @FoundIndex)
      SET @FoundIndex = CHARINDEX(@delimiter, @String)
END

INSERT @SplitValues (Asset_ID) VALUES (@String)

RETURN

Я не сделал бы это с петлей; Есть гораздо лучшие альтернативы. Безусловно лучший, когда вам нужно разделить, это CLR, и подход Адама Маханича является самым быстрым из всех, что я тестировал .

Следующий лучший подход IMHO, если вы не можете реализовать CLR, это таблица чисел:

SET NOCOUNT ON;

DECLARE @UpperLimit INT = 1000000;

WITH n AS
(
    SELECT
        x = ROW_NUMBER() OVER (ORDER BY s1.[object_id])
    FROM       sys.all_objects AS s1
    CROSS JOIN sys.all_objects AS s2
    CROSS JOIN sys.all_objects AS s3
)
SELECT Number = x
  INTO dbo.Numbers
  FROM n
  WHERE x BETWEEN 1 AND @UpperLimit
  OPTION (MAXDOP 1); -- protecting from Paul White's observation

GO
CREATE UNIQUE CLUSTERED INDEX n ON dbo.Numbers(Number) 
    --WITH (DATA_COMPRESSION = PAGE);
GO

... который позволяет эту функцию:

CREATE FUNCTION dbo.SplitStrings_Numbers
(
   @List       NVARCHAR(MAX),
   @Delimiter  NVARCHAR(255)
)
RETURNS TABLE
WITH SCHEMABINDING
AS
   RETURN
   (
       SELECT Item = SUBSTRING(@List, Number, 
         CHARINDEX(@Delimiter, @List + @Delimiter, Number) - Number)
       FROM dbo.Numbers
       WHERE Number <= CONVERT(INT, LEN(@List))
         AND SUBSTRING(@Delimiter + @List, Number, 1) = @Delimiter
   );
GO

Я полагаю, что все они будут работать лучше, чем ваша функция, когда вы ее заработаете, тем более что они встроенные, а не множественные операторы. Я не исследовал, почему у вас не работает, потому что я не думаю, что стоит того, чтобы эта функция работала.

Но это все сказано ...

Поскольку вы используете SQL Server 2008, есть ли причина, по которой вам нужно разделить в первую очередь? Я бы предпочел использовать TVP для этого:

CREATE TYPE dbo.strings AS TABLE
(
  string NVARCHAR(4000)
);

Теперь вы можете принять это как параметр для ваших хранимых процедур и использовать содержимое так же, как вы бы использовали TVF:

CREATE PROCEDURE dbo.foo
  @strings dbo.strings READONLY
AS
BEGIN
  SET NOCOUNT ON;

  SELECT Asset_ID = string FROM @strings;
  -- SELECT Asset_ID FROM dbo.utvf_split(@other_param, ',');
END

И вы можете передать TVP непосредственно из C # и т. Д. Как DataTable. Это почти наверняка превзойдет любое из вышеприведенных решений, особенно если вы специально строите в приложении строку, разделенную запятыми, чтобы ваша хранимая процедура могла вызывать TVP, чтобы разделить ее снова. Для получения дополнительной информации о ТВП см. Замечательную статью Эрланда Соммарскога .

Совсем недавно я написал серию о разделении строк:

• http://sqlperformance.com/2012/07/t-sql-queries/split-strings
• http://sqlperformance.com/2012/08/t-sql-queries/splitting-strings-follow-up
• http://sqlperformance.com/2012/08/t-sql-queries/splitting-strings-now-with-less-t-sql

И если вы используете SQL Server 2016 или более новую версию (или базу данных SQL Azure), есть новая STRING_SPLITфункция , о которой я писал здесь:

• Сюрпризы производительности и предположения: STRING_SPLIT ()
• STRING_SPLIT () в SQL Server 2016: продолжение № 1
• STRING_SPLIT () в SQL Server 2016: продолжение № 2

SQL Server 2016 представил функцию STRING_SPLIT () . У него есть два параметра - строка, которую нужно нарезать, и разделитель. Выход - одна строка на возвращаемое значение.

Для данного примера

SELECT * FROM string_split('one,two,three,four', ',');

вернусь

value
------------------
one
two
three
four

Я использую и люблю струнный сплиттер Джеффа Модена почти с тех пор, как он вышел.

Талли ОН! Улучшенная функция «CSV Splitter» для SQL 8K

CREATE FUNCTION [dbo].[DelimitedSplit8K]
--===== Define I/O parameters
        (@pString VARCHAR(8000), @pDelimiter CHAR(1))
--WARNING!!! DO NOT USE MAX DATA-TYPES HERE!  IT WILL KILL PERFORMANCE!
RETURNS TABLE WITH SCHEMABINDING AS
 RETURN
--===== "Inline" CTE Driven "Tally Table" produces values from 1 up to 10,000...
     -- enough to cover VARCHAR(8000)
  WITH E1(N) AS (
                 SELECT 1 UNION ALL SELECT 1 UNION ALL SELECT 1 UNION ALL
                 SELECT 1 UNION ALL SELECT 1 UNION ALL SELECT 1 UNION ALL
                 SELECT 1 UNION ALL SELECT 1 UNION ALL SELECT 1 UNION ALL SELECT 1
                ),                          --10E+1 or 10 rows
       E2(N) AS (SELECT 1 FROM E1 a, E1 b), --10E+2 or 100 rows
       E4(N) AS (SELECT 1 FROM E2 a, E2 b), --10E+4 or 10,000 rows max
 cteTally(N) AS (--==== This provides the "base" CTE and limits the number of rows right up front
                     -- for both a performance gain and prevention of accidental "overruns"
                 SELECT TOP (ISNULL(DATALENGTH(@pString),0)) ROW_NUMBER() OVER (ORDER BY (SELECT NULL)) FROM E4
                ),
cteStart(N1) AS (--==== This returns N+1 (starting position of each "element" just once for each delimiter)
                 SELECT 1 UNION ALL
                 SELECT t.N+1 FROM cteTally t WHERE SUBSTRING(@pString,t.N,1) = @pDelimiter
                ),
cteLen(N1,L1) AS(--==== Return start and length (for use in substring)
                 SELECT s.N1,
                        ISNULL(NULLIF(CHARINDEX(@pDelimiter,@pString,s.N1),0)-s.N1,8000)
                   FROM cteStart s
                )
--===== Do the actual split. The ISNULL/NULLIF combo handles the length for the final element when no delimiter is found.
 SELECT ItemNumber = ROW_NUMBER() OVER(ORDER BY l.N1),
        Item       = SUBSTRING(@pString, l.N1, l.L1)
   FROM cteLen l
;

CREATE FUNCTION [dbo].[fnSplit]
(

    @sInputList VARCHAR(8000),         -- List of delimited items

    @sDelimiter VARCHAR(8000) = ','    -- delimiter that separates items

)
RETURNS @List TABLE (colData VARCHAR(8000))

BEGIN

DECLARE @sItem VARCHAR(8000)

    WHILE CHARINDEX(@sDelimiter,@sInputList,0) <> 0

    BEGIN

        SELECT @sItem=RTRIM(LTRIM(SUBSTRING(@sInputList,1,CHARINDEX
(@sDelimiter,@sInputList,0)-1))),

        @sInputList=RTRIM(LTRIM(SUBSTRING(@sInputList,CHARINDEX(@sDelimiter,@sInputList,0)
+LEN(@sDelimiter),LEN(@sInputList))))

        IF LEN(@sItem) > 0
            INSERT INTO @List SELECT @sItem
        END

        IF LEN(@sInputList) > 0
            INSERT INTO @List SELECT @sInputList -- Put the last item in
        RETURN
    END

--TEST

--Example 1: select * from fnSplit('1,22,333,444,,5555,666', ',')

--Example 2: select * from fnSplit('1##22#333##444','##')  --note second colData has embedded #

--Example 3: select * from fnSplit('1 22 333 444  5555 666', ' ')