Ответы @Kin, @AaronBertrand и @DBAFromTheCold великолепны и были очень полезны. Одна важная часть информации, которую я обнаружил во время тестирования, но другие ответы были опущены, это то, что вам нужно использовать индекс, который возвращается sys.partitionsдля заданного HOBT_IDпри поиске %%lockres%%(через подсказку запроса индекса). Этот индекс не всегда является PK или кластеризованным индексом.
Например:
--Sometimes this does not return the correct results.
SELECT lockResKey = %%lockres%% ,*
FROM [MyDB].[dbo].[myTable]
WHERE %%lockres%% = @lockres
;
--But if you add the index query hint, it does return the correct results
SELECT lockResKey = %%lockres%% ,*
FROM [MyDB].[dbo].[myTable] WITH(NOLOCK INDEX([IX_MyTable_NonClustered_index]))
WHERE %%lockres%% = @lockres
;
Вот пример сценария, модифицированного с использованием кусочков каждого из этих ответов.
declare @keyValue varchar(256);
SET @keyValue = 'KEY: 5:72057598157127680 (92d211c2a131)' --Output from deadlock graph: process-list/process[waitresource] -- CHANGE HERE !
------------------------------------------------------------------------
--Should not have to change anything below this line:
declare @lockres nvarchar(255), @hobbitID bigint, @dbid int, @databaseName sysname;
--.............................................
--PARSE @keyValue parts:
SELECT @dbid = LTRIM(SUBSTRING(@keyValue, CHARINDEX(':', @keyValue) + 1, CHARINDEX(':', @keyValue, CHARINDEX(':', @keyValue) + 1) - (CHARINDEX(':', @keyValue) + 1) ));
SELECT @hobbitID = convert(bigint, RTRIM(SUBSTRING(@keyValue, CHARINDEX(':', @keyValue, CHARINDEX(':', @keyValue) + 1) + 1, CHARINDEX('(', @keyValue) - CHARINDEX(':', @keyValue, CHARINDEX(':', @keyValue) + 1) - 1)));
SELECT @lockRes = RTRIM(SUBSTRING(@keyValue, CHARINDEX('(', @keyValue) + 0, CHARINDEX(')', @keyValue) - CHARINDEX('(', @keyValue) + 1));
--.............................................
--Validate DB name prior to running dynamic SQL
SELECT @databaseName = db_name(@dbid);
IF not exists(select * from sys.databases d where d.name = @databaseName)
BEGIN
RAISERROR(N'Database %s was not found.', 16, 1, @databaseName);
RETURN;
END
declare @objectName sysname, @indexName sysname, @schemaName sysname;
declare @ObjectLookupSQL as nvarchar(max) = '
SELECT @objectName = o.name, @indexName = i.name, @schemaName = OBJECT_SCHEMA_NAME(p.object_id, @dbid)
FROM ' + quotename(@databaseName) + '.sys.partitions p
JOIN ' + quotename(@databaseName) + '.sys.indexes i ON p.index_id = i.index_id AND p.[object_id] = i.[object_id]
JOIN ' + quotename(@databaseName)+ '.sys.objects o on o.object_id = i.object_id
WHERE hobt_id = @hobbitID'
;
--print @ObjectLookupSQL
--Get object and index names
exec sp_executesql @ObjectLookupSQL
,N'@dbid int, @hobbitID bigint, @objectName sysname OUTPUT, @indexName sysname OUTPUT, @schemaName sysname OUTPUT'
,@dbid = @dbid
,@hobbitID = @hobbitID
,@objectName = @objectName output
,@indexName = @indexName output
,@schemaName = @schemaName output
;
DECLARE @fullObjectName nvarchar(512) = quotename(@databaseName) + '.' + quotename(@schemaName) + '.' + quotename(@objectName);
SELECT fullObjectName = @fullObjectName, lockIndex = @indexName, lockRes_key = @lockres, hobt_id = @hobbitID, waitresource_keyValue = @keyValue;
--Validate object name prior to running dynamic SQL
IF OBJECT_iD( @fullObjectName) IS NULL
BEGIN
RAISERROR(N'The object "%s" was not found.',16,1,@fullObjectName);
RETURN;
END
--Get the row that was blocked
--NOTE: we use the NOLOCK hint to avoid locking the table when searching by %%lockres%%, which might generate table scans.
DECLARE @finalResult nvarchar(max) = N'SELECT lockResKey = %%lockres%% ,*
FROM ' + @fullObjectName
+ ISNULL(' WITH(NOLOCK INDEX(' + QUOTENAME(@indexName) + ')) ', '')
+ ' WHERE %%lockres%% = @lockres'
;
--print @finalresult
EXEC sp_executesql @finalResult, N'@lockres nvarchar(255)', @lockres = @lockres;
У вас есть hobt_id, поэтому следующий запрос идентифицирует таблицу: -
После этого вы можете выполнить следующую инструкцию, чтобы идентифицировать строку в таблице (если она все еще существует):
Будьте осторожны с приведенным выше оператором, однако, он просканирует целевую таблицу, поэтому запустите команду READ UNCOMMITTED и проследите за своим сервером.
Вот статья Гранта Фричи о %% LOCKRES %% - http://www.scarydba.com/2010/03/18/undocumented-virtual-column-lockres/
А вот статья из моего собственного блога об использовании %% LOCKRES %% для идентификации строк из расширенного события: - https://dbafromthecold.wordpress.com/2015/02/24/identifying-blocking-via-extended-events/
источник
Это дополнение к ответам, уже опубликованным DBAFromTheCold и Аароном Бертраном .
Microsoft все еще оставила
%%lockres%%недокументированную функцию .Ниже приведен скрипт, который поможет вам :
Также обратитесь к этому превосходному сообщению в блоге: Загадочная история о сомнительном тупике и не очень логическом замке
источник
Извините, уже работал над этим ответом и собирался опубликовать, когда появился другой. Добавление в качестве сообщества вики только потому, что это немного другой подход и добавляет немного другой информации.
По
543066506c7cсути, это хеш первичного ключа, и вы можете извлечь эту строку (и, возможно, любые строки с коллизией хеша), используя этот динамический SQL:Конечно, вы можете сделать это без динамического SQL, но это дает вам хороший шаблон для фрагмента или хранимой процедуры, в который вы можете просто вставить значения, если вы много чего устраняете. (Вы также можете параметризовать имя таблицы и встроить разбор строки KEY:, чтобы динамически определить все для вас, но я подумал, что это может выходить за рамки этого сообщения.)
источник