Можно ли использовать два разных цветовых фона в одном буфере vim?

Я ищу возможное решение для применения двух разных цветов фона внутри одного буфера vim в зависимости от контекста, как в этом примере возвышенного текста .

Один из вариантов использования - по-разному раскрасить фрагменты кода внутри файлов разметки, чтобы они выделялись больше.

Однако я никогда не видел пример с такой установкой.

Это вообще возможно в vim?

Поскольку мне было любопытно, насколько хорошо это будет работать, я взломал что-то подобное.

Как упоминалось в комментариях к предыдущему ответу, единственный способ сделать это - заполнить регионы пробелами; именно это мы и делаем; перед тем как написать, мы удалим эти пробелы, поэтому вам не следует беспокоить кого-либо еще.

Обратите внимание, что этот пример очень специфичен для типа файла уценки!

Побочные эффекты :

• Копирование текста также скопирует много пробелов
• Использование $и Endбольше не работает должным образом (это относится к столбцу 80), а ключи, такие как jи, kведут себя по-другому.
• Фон не отображается, когда 'list'включен
• Полностью пустые строки не работают, вам нужно вручную добавить табуляцию или 4 пробела
• ... может быть, еще?

Во-первых, вам нужно добавить это в ваш ~/.vim/after/syntax/markdown.vim:

syn clear markdownCodeBlock                                                 
syn region markdownCodeBlock start="    \|\t" end="$"                       
hi def markdownCodeBlock ctermbg=230 guibg=lightyellow                      

Вы можете настроить цвета по своему вкусу, конечно ;-)

Затем добавьте это в ваш vimrc:

fun! MarkdownBlocks()                                                       
    fun! s:fill(line)                                                       
        " Remove all trailing whitespace                                    
        let l:line = substitute(a:line, " *$", "", "")                      

        " Add trailing whitespace up to 'textwidth' length                  
        return l:line . repeat(' ', (&tw > 0 ? &tw : 80) - strdisplaywidth(l:line))
    endfun                                                                  

    " Get all lines in a list                                               
    let l:lines = getline(1, line('$'))                                     

    " Map s:fill() to the lines that are a code block                       
    call map(l:lines, 'v:val[0] == "\t" || v:val[:3] == "    " ? s:fill(v:val) : v:val')

    " Reset the buffer to the lines                                         
    call setline(1, l:lines)                                                
endfun                                                                      

" Remove all the trailing spaces                                            
fun! MarkdownBlocksClean()                                                  
    let l:save_cursor = getpos(".")                                         
    silent %s/^\(    \|\t\)\(.\{-}\)\( *\)$/\1\2/e                          
    call setpos('.', l:save_cursor)                                         
endfun                                                                      
au BufWritePre *.markdown call MarkdownBlocksClean()                        

" Set spaces on loading the file, leaving insert mode, and after writing it 
au FileType markdown call MarkdownBlocks()                                  
au InsertLeave *.markdown call MarkdownBlocks()                             
au BufWritePost *.markdown call MarkdownBlocks()                            

Я не собираюсь объяснять код построчно, комментарии должны прояснить общую суть ;-)

Конечно, можно использовать другой цвет фона для выделенных синтаксисом элементов. Просто определите guibgи ctermbgцвета в вашей hilightкоманде. Первый устанавливает цвет фона для графического интерфейса Vim, а второй - для терминала Vim.

Однако это имеет важное ограничение: он может устанавливать цвета фона только для символов, которые фактически существуют в файле.

Результатом этого является то, что цвет фона не может простираться за конец текста на линии до края окна, поэтому раскраска блоков кода, показанная в вашем примере, невозможна:

Вы также можете изменить цвет фона целых линий, используя функцию подписи. (См. linehlВ :help sign.txt)

Однако обратите внимание, что:

1. Это требует написания кода для размещения знаков в каждой строке, которая должна быть окрашена, и их обновления по мере изменения содержимого файла,

2. По умолчанию при размещении знака столбец знака будет отображаться в левой части окна. Можно изменить окраску столбца знака с группой SignColumnподсветки, и в более поздних версиях Vim ее можно полностью удалить. (См :help 'signcolumn'.)

Например, чтобы адаптировать решение Carpetsmoker для использования (более надежного) механизма подписи, вы можете сделать следующее:

" Define a highlight group and a sign that uses it
highlight default markdownCodeBlock ctermbg=230 guibg=lightyellow
sign define codeblock linehl=markdownCodeBlock

" Use signs to highlight code blocks
function! MarkdownBlocks()
    function! s:applySign(idx, val)
        if a:val[0] == "\t" || a:val[:3] == "    "
            let l = a:idx + 1
            execute "sign place " . l . " line=" . l . " name=codeblock file=" . expand("%:p")
        endif
    endfunction

    " Remove old signs
    execute "sign unplace * file=" . expand("%:p")

    " Get all lines in a list
    let l:lines = getline(1, line('$'))
    " Add new signs
    call map(l:lines, function('s:applySign'))
endfunction

" Set signs on loading the file, leaving insert mode, and after writing it
au FileType markdown call MarkdownBlocks()
au InsertLeave *.markdown call MarkdownBlocks()
au BufWritePost *.markdown call MarkdownBlocks()

Это несколько упрощает код и имеет меньше предостережений, чем версия Carpetsmoker.

@ChristianBrabandt «s DynamicSigns плагин делает с помощью функции Sign для этой цели проще: он описывает , как использовать его , чтобы сделать это в этом ответе .