Как получить конечные данные архива gzip?

У меня есть архив gzip с последними данными. Если я распаковываю его, используя gzip -dего, он говорит мне: « декомпрессия в порядке, конечный мусор игнорируется » (то же самое относится и к тому, gzip -tчто можно использовать в качестве метода обнаружения наличия таких данных).

Теперь я хотел бы узнать этот мусор, но, как ни странно, я не мог найти способ его извлечь. gzip -l --verboseговорит мне, что «сжатый» размер архива - это размер файла (т.е. с последними данными), это неправильно и бесполезно. fileтакже не помогает, так что я могу сделать?

Теперь разобрался, как получить данные трейлинга.

Я создал Perl-скрипт, который создает файл с последними данными, он в значительной степени основан на https://bugs.debian.org/cgi-bin/bugreport.cgi?bug=604617#10 :

#!/usr/bin/perl
use strict;
use warnings; 

use IO::Uncompress::Gunzip qw(:all);
use IO::File;

unshift(@ARGV, '-') unless -t STDIN;

my $input_file_name = shift;
my $output_file_name = shift;

if (! defined $input_file_name) {
  die <<END;
Usage:

  $0 ( GZIP_FILE | - ) [OUTPUT_FILE]

  ... | $0 [OUTPUT_FILE]

Extracts the trailing data of a gzip archive.
Outputs to stdout if no OUTPUT_FILE is given.
- as input file file causes it to read from stdin.

Examples:

  $0 archive.tgz trailing.bin

  cat archive.tgz | $0

END
}

my $in = new IO::File "<$input_file_name" or die "Couldn't open gzip file.\n";
gunzip $in => "/dev/null",
  TrailingData => my $trailing;
undef $in;

if (! defined $output_file_name) {
  print $trailing;
} else {
  open(my $fh, ">", $output_file_name) or die "Couldn't open output file.\n";
  print $fh $trailing;
  close $fh;
  print "Output file written.\n";
}