Может ли один Ubuntu SDK предназначаться для сенсорного экрана и рабочего стола с разными макетами?

Я знаю, что сенсорные приложения будут работать на рабочем столе с тем же интерфейсом, но мне было интересно, возможно ли, чтобы одно приложение Ubuntu SDK имело многооконный интерфейс с элементами стиля рабочего стола при работе в режиме рабочего стола, а также предоставление отдельного сенсорного интерфейса при работе на сенсорных платформах.

Изменение аспектов макета в зависимости от размера окна может быть выполнено несколькими способами. На самом базовом уровне вы можете просто установить свойства на разные значения в зависимости от размеров. Вот минимальный пример, который рисует серый квадрат, который становится оранжевым, если вы увеличиваете окно:

Бежать с qmlscene path/to/file.qml

import QtQuick 2.0
import Ubuntu.Components 0.1

MainView {
    id: root
    width: units.gu(50)
    height: units.gu(50)

    Rectangle {
        id: hello
        color: parent.width > units.gu(60) ? UbuntuColors.orange : UbuntuColors.warmGrey
        anchors.fill: parent
    }
}

Конечно, если у вас есть более сложные элементы в вашем приложении, это может быть немного утомительно. Чтобы помочь с этим, Ubuntu Toolkit предоставляет компонент ConditionalLayout, где вы можете определить различные макеты, которые будут активированы при выполнении условия. Это происходит динамически, и вы можете видеть изменения при изменении размера окна.

Вот более сложный пример использования ConditionalLayout:

import QtQuick 2.0
import Ubuntu.Components 0.1
import Ubuntu.Components.ListItems 0.1 as ListItem
import Ubuntu.Layouts 0.1

MainView {
    id: root
    width: units.gu(50)
    height: units.gu(75)

    Page {
        anchors.fill: parent

        Layouts {
            id: layouts
            anchors.fill: parent
            layouts: [

                ConditionalLayout {
                    name: "flow"
                    when: layouts.width > units.gu(60)

                    Flow {
                        anchors.fill: parent
                        flow: Flow.LeftToRight

                        ItemLayout {
                            item: "sidebar"
                            id: sidebar
                            anchors {
                                top: parent.top
                                bottom: parent.bottom
                            }
                            width: parent.width / 3
                        }

                        ItemLayout {
                            item: "colors"
                            anchors {
                                top: parent.top
                                bottom: parent.bottom
                                right: parent.right
                                left: sidebar.right
                            }
                        }
                    }
                }
            ]

            Column {
                id: sidebar
                anchors {
                    left: parent.left
                    top: parent.top
                    right: parent.right
                }
                Layouts.item: "sidebar"

                ListItem.Header {
                    text: "Ubuntu Color Palette"
                }

                ListItem.Standard {
                    id: orangeBtn
                    text: "Ubuntu Orange"
                    control: Button {
                        text: "Click me"
                        onClicked: {
                            hello.color = UbuntuColors.orange
                        }
                    }
                }

                ListItem.Standard {
                    id: auberBtn
                    text: "Canonical Aubergine"
                    control: Button {
                        text: "Click me"
                        onClicked: {
                            hello.color = UbuntuColors.lightAubergine
                        }
                    }
                }

                ListItem.Standard {
                    id: grayBtn
                    text: "Warm Grey"
                    control: Button {
                        text: "Click me"
                        onClicked: {
                            hello.color = UbuntuColors.warmGrey
                        }
                    }
                }
            } // Column

            Rectangle {
                id: hello
                Layouts.item: "colors"
                color: UbuntuColors.warmGrey
                anchors {
                    top: sidebar.bottom
                    bottom: parent.bottom
                    left: parent.left
                    right: parent.right
                }

                Label {
                    anchors.centerIn: parent
                    text: "Hello (ConditionalLayout) World!"
                    color: "black"
                    fontSize: "large"
                }
            }
        } // Layouts
    } // Page
} // Main View

Когда по умолчанию телефон подобен размеру, он выглядит так:

Когда он расширяется до размера планшета или рабочего стола, он выглядит следующим образом:

Я думаю, что вы можете получить этот результат, используя условные макеты .