Допустим, на D:диске есть какая-то папка :

D:\Air
D:\Abonden
D:\All
D:\Whatever

Я хочу удалить все папки, начинающиеся с «A» (включая все подпапки и файлы). Я попробовал эту команду:

rmdir D:\A* /s /q

Я получаю ошибку, хотя :(

Неверный синтаксис имени файла, имени каталога или метки тома.

Команда delработает с *, но мне нужно также удалить папки.
Есть ли способ добиться этого с помощью rmdirкоманды?

cd c:\temp
for /f %i in ('dir /a:d /s /b A*') do rd /s /q %i

Используйте это, чтобы проверить, хотя:

for /f %i in ('dir /a:d /s /b A*') do echo rd /s /q %i

Это выведет команды для запуска в командную строку и позволит вам увидеть, что происходит.

Имейте в виду, что это также будет искать подпапки, такие как "C: \ temp \ jjj \ aaa" и удалит папку aaa. Если вы хотите, чтобы он просто просматривал папки верхнего уровня «C: \ temp \ aaa», то удалите команду "/s"из команды.

Ключ к этому - A *, где вы бы указали строку поиска. Это будет принимать подстановочные знаки, такие как aaa*, aaa*и, *aaa*если вы хотите.

Удаление папок с использованием подстановочных знаков

rmdir/ rdКоманды в одиночку не поддерживает подстановочные символы (то есть, *и ?). Вы можете обойти это ограничение, заключив его в forцикл.

Пример использования

for /d %G in ("X:\A*") do rd /s /q "%~G"

Примечание. При удалении файлов и папок может потребоваться заменить rdкоманду echoпервой. Таким образом, вы можете гарантировать, что все, что не должно быть удалено, действительно будет.

Несколько моделей

Чтобы удалить несколько папок, соответствующих разным шаблонам, синтаксис не слишком отличается. Как правильно заметил @dbenham, достаточно однострочной команды. Вы также можете указать разные пути:

for /d %G in ("X:\A*","Y:\Whatever\B*","Z:\C?D") do rd /s /q "%~G"

Бонус - проверка существования папки

Если вы хотите проверить, существуют ли определенные папки, вы можете использовать следующую команду:

dir /b /a:d "X:\A*" >nul 2>&1 && echo Folders exist. || echo No folders found.

дальнейшее чтение

• for / d - цикл по каталогу
• Условное исполнение
• Справочник по командной строке

Как никто еще не рассказал ОП о файлах ?!

forfiles /P D:\ /M A* /C "cmd /c if @isdir==TRUE rmdir /s /q @file"

/ P это путь - где начинается поиск
/ M - маска поиска, ищущая файлы, которые начинаются с A
/ C - команда для выполнения
/ S - это рекурсивные подпапки (здесь их не было, потому что op не спрашивал)

Ответ adn31415 правильный, но ломается, если вы поместите это в пакетный или cmd-скрипт. Я часами колотил головой, пока не понял, как ты это используешь.

В командном окне DOS:

for /d %G in ("X:\A*") do rd /s /q "%~G"

В пакетном или cmd скрипте:

for /d %%G in ("X:\A*") do rd /s /q "%%~G"

Если вы хотите поместить его в файл «.bat» или «.cmd», вам необходимо удвоить символы «%».