установив ERRORLEVEL в 0

У меня есть командный файл, который является оберткой вокруг установщика. Этот пакетный файл проверяет уровень ошибок, возвращаемый установщиком, и печатает соответственно.

Я заметил, что если я выполню set ERRORLEVEL=0в командной строке прямо перед тем, как запустить пакетный файл (в том же окне / среде команды), установщик никогда не помешает уровню ошибки, и мой пакетный скрипт всегда возвращает пройденный. Я бы предположил, %ERRORLEVEL%что это переменная, определяемая Windows, которая используется специально для распечатки ошибок из программ и сценариев, и что использование переменной в командном файле или что-то еще будет «на ваш страх и риск», поскольку его можно изменить в любой момент другой процесс.

Из того, что кажется, когда я устанавливаю уровень ошибки в данной среде, это как-то прекращает использование уровня ошибок в качестве держателя кода выхода. Кто-нибудь знает, почему это? Для меня это просто странное неожиданное поведение. Любая информация по этому вопросу будет принята с благодарностью!

Вы переопределяете системную переменную в обычную. Когда вы сделаете это, система не будет использовать его, пока командный сеанс не будет закрыт.

Лучший способ будет использовать

exit /b 0

в другой пакетный файл и вызвать его из основного сценария. Где число 0 - это то, что вам нужно errorlevel. Либо так, либо используйте команду, которая сбрасывает errorlevelдля вас, например, echo, findstr и т. Д.

Например, следующие команды будут все установлены ERRORLEVELв 0 в вашем пакетном файле:

VERIFY > nul

cmd /c "exit /b 0"

ver > nul     

Никогда не следует присваивать собственное значение динамическим системным переменным, таким как ERRORLEVEL, PATH, CD, DATE, TIME и т. Д. Это не позволит коду видеть динамическое значение. Вы можете восстановить динамическое значение, просто отменив определенное пользователем значение. Например:

set "errorlevel="

Если вы хотите , чтобы заставить ErrorLevel в 0, то вы можете использовать это абсолютно не интуитивный, но очень эффективный синтаксис: (call ). Пробел после звонка имеет решающее значение. Если вы хотите установить уровень ошибки на 1, вы можете использовать (call). Очень важно, чтобы после звонка не было места.

(call)
echo %errorlevel%
(call )
echo %errorlevel%

Более интуитивно понятный, но менее удобный метод установки уровня ошибки - это использование выделенной подпрограммы в пакетном файле:

call :setErr 1
echo %errorlevel%
call :setErr 0
echo %errorlevel%
exit /b

:setErr
exit /b %1

Или, если в командной строке, вы можете использовать

cmd /c exit 1
echo %errorlevel%
cmd /c exit 0
echo %errorlevel%

Я лично использую это:

cd .

Работает даже в Unix Shell.

Вот некоторые другие способы сброса ErrorLevelсостояния, которые даже работают в MS-DOS (по крайней мере для версии 6.22):

more < nul > nul

rem // The `> nul` part can be omitted in Windows but is needed in MS-DOS to avoid a line-break to be returned:
sort < nul > nul

Следующие методы работают только в MS-DOS:

command /? > nul

fc nul nul > nul

Для полноты картины устанавливается ErrorLevelсостояние 1, действительное как для Windows, так и для MS-DOS:

< nul find ""

Это единственное, что я нашел, что работает.

call (exit /b 0)

Требуется в скрипте, который использует сторонний скрипт, который обнаруживает ERRORLEVEL, но не сбрасывает уровень ошибки самостоятельно.

Это также будет работать: (Устанавливает errorlevel в 1)

Способ 1

color 00

Способ 2

echo A | find "B"

Вы также можете использовать это, чтобы установить уровень ошибки 1-26:

echo Your errorlevel<sup>th</sup> character between A-Z | choice /c:Enter A-Z here /n