OS X Terminal.app: как запустить новую вкладку в том же каталоге, что и текущая вкладка?

Мне часто нужно открывать новую вкладку в том же каталоге, что и моя текущая вкладка, чтобы сделать что-то еще, пока моя текущая вкладка занята длительным процессом. Однако по умолчанию при создании новой вкладки Terminal.app начинается с ~ /. Есть идеи, как сделать автоматический переход?

В OS X 10.7 (Lion) Terminal.app изначально поддерживает это: New Windows/Tabs open in: Same working directory

Нужно быть очень осторожным при прохождении строк в разных средах.

Я использую 10.4, поэтому мой скрипт tfork всегда открывает новое окно. Должно быть легко адаптировать его для использования вкладки:

#!/bin/sh

# source: http://www.pycs.net/bob/weblog/2004/02/23.html#P49
# Rewritten to use osascript args -> run handler args.
# Added ability to pass additional initial command and args to new shell.
#    Bug: Non ASCII characters are unreliable on Tiger.
#         Tiger's osascript seems to expect args to be encoded in
#         the system's primary encoding (e.g. MacRoman).
#         Once in AppleScript, they are handled OK. Terminal sends them
#         back to the shell as UTF-8.

test $# -eq 0 && set -- : # default command if none given
osascript - "$(pwd)" "$@" <<\EOF
on run args
  set dir to quoted form of (first item of args)
  set cmd_strs to {}
  repeat with cmd_str in rest of args
    set end of cmd_strs to quoted form of cmd_str
  end
  set text item delimiters to " "
  set cmd to cmd_strs as Unicode text
  tell app "Terminal" to do script "cd " & dir & " && " & cmd
end
EOF

Пример: tfork git log -p ..FETCH_HEAD

Поправка: cwd уже запущенного процесса, «занимающего» вкладку « Терминал »

Идея «текущего каталога программы, занимающего текущую вкладку» не так очевидна, как можно было бы ожидать.

Каждая вкладка « Терминал » имеет одно tty-устройство, которое используется процессами, которые оно запускает (изначально оболочка; затем независимо от запуска оболочки).

Каждый (обычный) терминал tty имеет одну группу процессов переднего плана, которую можно считать «занимающей» tty.

В каждой группе процессов может быть несколько процессов.

Каждый процесс может иметь свой текущий рабочий каталог (cwd) (в некоторых средах каждому потоку присваивается собственный cwd или cwd-эквивалент, но мы будем игнорировать это).

Предыдущие факты указывают на то, что от tty к cwd: tty -> группа процессов переднего плана -> процессы группы процессов переднего плана -> cwds.

Первая часть (от tty до процессов переднего плана) проблемы может быть решена с помощью вывода ps :

ps -o tty,pid,tpgid,pgid,state,command | awk 'BEGIN{t=ARGV[1];ARGC=1} $1==t && $3==$4 {print $2}' ttyp6

(где «ttyp6» - это название интересующего вас tty)

Отображение из процесса (PID) в cwd может быть выполнено с помощью lsof :

lsof -F 0n -a -p 2515,2516 -d cwd

(где «2515,2516» - список интересующих процессов, разделенных запятыми)

Но под Tiger я не вижу прямого способа получить имя устройства tty конкретного окна терминала . Есть ужасно безобразный способ получить имя tty в Tiger. Может быть, Леопард или Снежный Барс могут сделать лучше.

Я собрал все это вместе в AppleScript следующим образом:

on run
    (* Find the tty. *)
    -- This is ugly. But is seems to work on Tiger. Maybe newer releases can do better.
    tell application "Terminal"
        set w to window 1
        tell w
            set origName to name
            set title displays device name to not title displays device name
            set newName to name
            set title displays device name to not title displays device name
        end tell
    end tell
    set tty to extractTTY(origName, newName)
    if tty is "" then
        display dialog "Could not find the tty for of the current Terminal window." buttons "Cancel" cancel button "Cancel" default button "Cancel"
    end if

    (* Find the PIDs of the processes in the foreground process group on that tty. *)
    set pids to paragraphs of (do shell script "
ps -o pid,tty,tpgid,pgid,state,command |
awk '
    BEGIN   {t=ARGV[1];ARGC=1}
    $2==t && $3==$4 {print $1}
' " & quoted form of tty)
    if pids is {} or pids is {""} then
        display dialog "Could not find the processes for " & tty & "." buttons "Cancel" cancel button "Cancel" default button "Cancel"
    end if

    (* Find the unique cwds of those processes. *)
    set text item delimiters to {","}
    set lsof to do shell script "lsof -F 0n -a -d cwd -p " & quoted form of (pids as Unicode text) without altering line endings
    set text item delimiters to {(ASCII character 0) & (ASCII character 10)}
    set cwds to {}
    repeat with lsofItem in text items of lsof
        if lsofItem starts with "n" then
            set cwd to text 2 through end of lsofItem
            if cwds does not contain cwd then ¬
                set end of cwds to cwd
        end if
    end repeat
    if cwds is {} then
        display dialog "No cwds found!?" buttons "Cancel" cancel button "Cancel" default button "Cancel"
    end if
    if length of cwds is greater than 1 then
        set cwds to choose from list cwds with title "Multiple Distinct CWDs" with prompt "Choose the directory to use:" without multiple selections allowed and empty selection allowed
        if cwds is false then error number -128 -- cancel
    end if

    (* Open a new Terminal. *)
    tell application "Terminal" to do script "cd " & quoted form of item 1 of cwds
end run

to extractTTY(a, b)
    set str to textLeftAfterRemovingMatchingHeadAndTail(a, b)
    set offs to offset of "tty" in str
    if offs > 0 then
        return text offs through (offs + 4) of str
    end if
    return ""
end extractTTY
to textLeftAfterRemovingMatchingHeadAndTail(big, little)
    set text item delimiters to space
    if class of big is not list then set big to text items of big
    if class of little is not list then set little to text items of little
    set {maxLen, minLen} to {length of big, length of little}
    if maxLen < minLen then ¬
        set {big, little, maxLen, minLen} to {little, big, minLen, maxLen}

    set start to missing value
    repeat with i from 1 to minLen
        if item i of big is not equal to item i of little then
            set start to i
            exit repeat
        end if
    end repeat
    if start is missing value then
        if maxLen is equal to minLen then
            return ""
        else
            return items (minLen + 1) through end of big as Unicode text
        end if
    end if

    set finish to missing value
    repeat with i from -1 to -minLen by -1
        if item i of big is not equal to item i of little then
            set finish to i
            exit repeat
        end if
    end repeat
    if finish is missing value then set finish to -(minLen + 1)

    return items start through finish of big as Unicode text
end textLeftAfterRemovingMatchingHeadAndTail

Сохраните его с помощью редактора сценариев ( AppleScript Editor в Snow Leopard) и используйте средство запуска (например, FastScripts ), чтобы назначить его клавише (или просто запустите его из меню AppleScript (включено через / Applications / AppleScript / AppleScript Utility.app )).

Я разместил скрипт, который использует приведенный выше код Криса Джонсона, и другой скрипт, чтобы открыть новую вкладку в текущем каталоге с текущими настройками, в основном потому, что я координирую цвета своих терминалов. Спасибо Крис, за этот сценарий, я использую его уже несколько месяцев, и это экономит время.

(* Этот сценарий открывает новую вкладку Terminal.app в каталоге текущей вкладки с теми же настройками. Вам необходимо, если вы этого еще не сделали, включить доступ для вспомогательных устройств, как описано здесь: http: // www .macosxautomation.com / AppleScript / uiscripting / index.html

Это почти вся работа двух скриптов вместе взятых, спасибо им:

Сценарий Криса Джонсена открывает новую вкладку в текущем каталоге: OS X Terminal.app: как запустить новую вкладку в том же каталоге, что и текущая вкладка?

«Menu_click» Джейкоба Руса позволяет мне создавать вкладку с теми же настройками, что и API терминала: http://hints.macworld.com/article.php?story=20060921045743404

Если вы измените имя профиля терминала, API-интерфейс AppleScript будет возвращать старое имя до тех пор, пока вы не перезапустите приложение, поэтому сценарий не будет работать с переименованными настройками до тех пор. Тьфу. Кроме того, необходимость активировать Терминал для выполнения команды меню переносит все окна терминала на передний план.

*)

-- from http://hints.macworld.com/article.php?story=20060921045743404
-- `menu_click`, by Jacob Rus, September 2006
-- 
-- Accepts a list of form: `{"Finder", "View", "Arrange By", "Date"}`
-- Execute the specified menu item.  In this case, assuming the Finder 
-- is the active application, arranging the frontmost folder by date.

on menu_click(mList)
    local appName, topMenu, r

    -- Validate our input
    if mList's length < 3 then error "Menu list is not long enough"

    -- Set these variables for clarity and brevity later on
    set {appName, topMenu} to (items 1 through 2 of mList)
    set r to (items 3 through (mList's length) of mList)

    -- This overly-long line calls the menu_recurse function with
    -- two arguments: r, and a reference to the top-level menu
    tell application "System Events" to my menu_click_recurse(r, ((process appName)'s ¬
        (menu bar 1)'s (menu bar item topMenu)'s (menu topMenu)))
end menu_click

on menu_click_recurse(mList, parentObject)
    local f, r

    -- `f` = first item, `r` = rest of items
    set f to item 1 of mList
    if mList's length > 1 then set r to (items 2 through (mList's length) of mList)

    -- either actually click the menu item, or recurse again
    tell application "System Events"
        if mList's length is 1 then
            click parentObject's menu item f
        else
            my menu_click_recurse(r, (parentObject's (menu item f)'s (menu f)))
        end if
    end tell
end menu_click_recurse



-- with the noted slight modification, from /superuser/61149/os-x-terminal-app-how-to-start-a-new-tab-in-the-same-directory-as-the-current-ta/61264#61264

on run
    (* Find the tty. *)
    -- This is ugly. But is seems to work on Tiger. Maybe newer releases can do better.
    tell application "Terminal"
        set w to the front window
        tell w
            set origName to name
            set title displays device name to not title displays device name
            set newName to name
            set title displays device name to not title displays device name
        end tell
    end tell
    set tty to extractTTY(origName, newName)
    if tty is "" then
        display dialog "Could not find the tty for of the current Terminal window." buttons "Cancel" cancel button "Cancel" default button "Cancel"
    end if

    (* Find the PIDs of the processes in the foreground process group on that tty. *)
    set pids to paragraphs of (do shell script "
ps -o pid,tty,tpgid,pgid,state,command |
awk '
    BEGIN   {t=ARGV[1];ARGC=1}
    $2==t && $3==$4 {print $1}
' " & quoted form of tty)
    if pids is {} or pids is {""} then
        display dialog "Could not find the processes for " & tty & "." buttons "Cancel" cancel button "Cancel" default button "Cancel"
    end if

    (* Find the unique cwds of those processes. *)
    set text item delimiters to {","}
    set lsof to do shell script "lsof -F 0n -a -d cwd -p " & quoted form of (pids as Unicode text) without altering line endings
    set text item delimiters to {(ASCII character 0) & (ASCII character 10)}
    set cwds to {}
    repeat with lsofItem in text items of lsof
        if lsofItem starts with "n" then
            set cwd to text 2 through end of lsofItem
            if cwds does not contain cwd then ¬
                set end of cwds to cwd
        end if
    end repeat
    if cwds is {} then
        display dialog "No cwds found!?" buttons "Cancel" cancel button "Cancel" default button "Cancel"
    end if
    if length of cwds is greater than 1 then
        set cwds to choose from list cwds with title "Multiple Distinct CWDs" with prompt "Choose the directory to use:" without multiple selections allowed and empty selection allowed
        if cwds is false then error number -128 -- cancel
    end if

    (* Open a new Terminal. *)

    -- Here is where I substituted the menu_click call to use the current settings

    tell application "Terminal"
        activate
        tell window 1
            set settings to name of current settings in selected tab
        end tell
    end tell
    menu_click({"Terminal", "Shell", "New Tab", settings})

    tell application "Terminal" to do script "cd " & quoted form of item 1 of cwds in selected tab of window 1
end run

to extractTTY(a, b)
    set str to textLeftAfterRemovingMatchingHeadAndTail(a, b)
    set offs to offset of "tty" in str
    if offs > 0 then
        return text offs through (offs + 6) of str
    end if
    return ""
end extractTTY
to textLeftAfterRemovingMatchingHeadAndTail(big, little)
    set text item delimiters to space
    if class of big is not list then set big to text items of big
    if class of little is not list then set little to text items of little
    set {maxLen, minLen} to {length of big, length of little}
    if maxLen < minLen then ¬
        set {big, little, maxLen, minLen} to {little, big, minLen, maxLen}

    set start to missing value
    repeat with i from 1 to minLen
        if item i of big is not equal to item i of little then
            set start to i
            exit repeat
        end if
    end repeat
    if start is missing value then
        if maxLen is equal to minLen then
            return ""
        else
            return items (minLen + 1) through end of big as Unicode text
        end if
    end if

    set finish to missing value
    repeat with i from -1 to -minLen by -1
        if item i of big is not equal to item i of little then
            set finish to i
            exit repeat
        end if
    end repeat
    if finish is missing value then set finish to -(minLen + 1)

    return items start through finish of big as Unicode text
end textLeftAfterRemovingMatchingHeadAndTail

Как упоминалось в другом месте , если вы используете Oh My Zsh , то вам просто нужно добавить terminalappплагин. В вашем файле .zshrc (если вы уже используете плагин git:

plugins=(terminalapp git)

Я использую этот псевдоним / сценарий оболочки, чтобы сделать это.

# modified from http://www.nanoant.com/programming/opening-specified-path-in-terminals-new-tab
alias twd=new_terminal_working_directory
function new_terminal_working_directory() {
osascript <<END 
        tell application "Terminal"
            tell application "System Events" to tell process "Terminal" to keystroke "t" using command down
        do script "cd $(pwd)" in first window
    end tell
END
}

http://www.entropy.ch/blog/Mac+OS+X/2008/06/27/Terminal-Tricks-"term"-revisited-with-tabs.html

tab -t $PWD