Как я могу автоматически обновлять Flash Player при выходе новой версии?

Резюме:

Флэш - служба обновления плеер не работает на надежную графике, и не автоматически загружать и применять обновления , когда он действительно работать.

Учитывая важность наличия обновленной версии Flash Player (для тех из нас, кто не использует Chrome со встроенным проигрывателем), я хотел бы найти способ обеспечить своевременное обнаружение новых обновлений. и установлен.

Ниже приведены подробности моих попыток решить эту проблему самостоятельно ...

Приложение А. Служба обновления Flash Player

Хорошо, еще в Flash Player 11.2 (или около того?) Adobe добавила службу обновления Flash Player (FlashPlayerUpdateService.exe), она должна была поддерживать Flash Player обновленной ...

• После установки FPUS настраивается для работы в качестве службы Windows, для параметра «Тип запуска» задано значение «Вручную».

• Запланированное задание (Adobe Flash Player Updater.job) добавляется для запуска этой службы каждый час.

Пока все хорошо - эта установка позволяет избежать постоянно работающей службы, но гарантирует, что проверки выполняются достаточно часто, чтобы быстро перехватывать любые обновления. Средство обновления программного обеспечения Google настроено аналогичным образом, и это прекрасно работает ...

... И все же, когда я проверил версию моего установленного Flash Player, я обнаружил, что это была версия 11.6.602.180 , которая, основываясь на данных о временных отметках файлов, C:\Windows\System32\Macromed\Flashбыла в последний раз обновлена ​​(или установлена) в вторник, 12 марта, 2013 --- 3/12/13, 5:00:08 вечера .

Я сделал это замечание в четверг, 25 апреля 2013 г. - 25.04.13, 19:00 , и после проверки веб-сайта Adobe обнаружил, что текущая версия Flash Player была 11.7.700.169 .

Прошло более месяца с момента последнего обновления, с новым, явно доступным на веб-сайте, но без каких-либо указаний на то, что почасовая проверка, выполняемая на моем компьютере, заметила его или намеревается загрузить.

Приложение Б: запуск программы обновления Flash Player вручную

Когда-то, запуск дал бы вам окно с кнопкой Install ; нажатие на нее приведет к загрузке установщика для текущей версии (автоматически, без открытия браузера) и его запуску, затем вы щелкнете по этому установщику и все будет готово. Это было руководство, но это работало! Находя мою текущую установку устаревшей (см. Приложение A), я сначала попробовал этот процесс обновления вручную. Тем не мение...FlashUtil32_<version>_Plugin.exe -update plugin

• Выполняется (в моем случае это так ) ... представляет только окно с кнопкой «Загрузить», при нажатии этой кнопки «Загрузить» открывается в браузере URL-адрес https://get3.adobe.com/flashplayer/update/activex .FlashUtil32_<version>_ActiveX.exe -update activexFlashUtil32_11_6_602_180_ActiveX.exe -update activex

• Выполняется (в моем случае это так ) ... представляет только окно с кнопкой «Загрузить», при нажатии этой кнопки «Загрузить» открывается в браузере URL-адрес https://get3.adobe.com/flashplayer/update/plugin .FlashUtil32_<version>_Plugin.exe -update pluginFlashUtil32_11_6_602_180_Plugin.exe -update plugin

Я мог бы продолжить со страницы загрузки, на которую он мне отправил, снять флажок с программным обеспечением («Бесплатно! McAfee Security Scan Plus»), загрузить этот установщик (ActiveX, без программного обеспечения: install_flashplayer11x32axau_mssd_aih.exe, Плагин, без программного обеспечения: install_flashplayer11x32au_mssd_aih.exe) Возможно, у вас есть обновленная версия Flash ... но какой смысл использовать службу обновления Flash Player, если мне нужно вручную загрузить и запустить другой exe-файл?

эпилог

С тех пор я начал подозревать, что служба обновлений намеренно затруднена, чтобы вывести первых пользователей на страницу загрузки руководства. Если это правда, то, вероятно, нет решения этой короткой записи моего собственного средства обновления; надеюсь я ошибаюсь

Возможно, средство обновления применяет обновления только в диапазоне 11.6.x?

Вы всегда можете использовать прямые ссылки на установщики, которые я считаю более надежными: ActiveX ; Plugin .

С помощью этого .bat- файла он попытается автоматически обновить или установить флэш-плеер для Internet Explorer, Firefox (SeaMonkey и т. Д.), На основе Chromium (Chrome, Opera 15+ и т. Д.):

del install_flash_player.exe
del install_flash_player_ax.exe
del install_flash_player_ppapi.exe
wget http://fpdownload.macromedia.com/pub/flashplayer/latest/help/install_flash_player.exe
wget http://fpdownload.macromedia.com/pub/flashplayer/latest/help/install_flash_player_ax.exe
wget http://fpdownload.macromedia.com/pub/flashplayer/latest/help/install_flash_player_ppapi.exe
install_flash_player.exe -install
install_flash_player_ax.exe -install
install_flash_player_ppapi.exe -install

Необходимый wget вы можете скачать здесь, и вам нужно поместить его в тот же каталог, где был размещен .bat.

Чуть более продвинутый пример написан на Autoit .

Особенности: Простая проверка новой версии, если здесь нет новой версии, тогда выйдите из программы без загрузки установщика флеш-плеера. Если загрузка установщика не удалась, отобразите окно сообщения с ошибкой и выйдите. Скрытое окно командной строки. Не нужно Wget.

После установки Autoit и Editor . Щелкните правой кнопкой мыши на рабочем столе-> New-> Autoit Script. Щелкните правой кнопкой мыши на созданном файле -> Изменить. Теперь вы должны увидеть окно ScITE и после строки «Добавьте свой код ниже здесь» добавить этот код:

#NoTrayIcon
#include <WinAPIDiag.au3>
$flashplayerlink="http://fpdownload.macromedia.com/pub/flashplayer/latest/help/install_flash_player.exe"
$flashplayername="install_flash_player.exe"
$flashplayerlinkAX="http://fpdownload.macromedia.com/pub/flashplayer/latest/help/install_flash_player_ax.exe"
$flashplayernameAX="install_flash_player_ax.exe"
updateflashplayer($flashplayerlink,$flashplayername)
updateflashplayer($flashplayerlinkAX,$flashplayernameAX)

$flashplayerlinkPPAPI="http://fpdownload.macromedia.com/pub/flashplayer/latest/help/install_flash_player_ppapi.exe"
$flashplayernamePPAPI="install_flash_player_ppapi.exe"
updateflashplayer($flashplayerlinkPPAPI,$flashplayernamePPAPI)



Func updateflashplayer($link,$fname)
    if FileGetSize($fname)<>InetGetSize($link) then
        InetGet($link,$fname)
        if @error then
            MsgBox(16,"","Error: '"&_WinAPI_GetErrorMessage(@error)&"'"&@CRLF&$fname)
            Exit
        EndIf
        RunWait($fname&" -install","",@SW_HIDE)
    EndIf
EndFunc

Затем в окне SciTE нажмите Инструменты-> Построить или нажмите F7. Теперь вы получите автономный исполняемый файл в той же директории, где был скрипт Autoit.

Я рекомендую создать новую папку (с правами доступа для записи) для этого "средства обновления". Вы можете добавить ярлык для этого "обновления", чтобы начать тоже.

Здесь приложение для удаления Flash Player.

Просто хочу поделиться с вами своим пакетным скриптом, просто сохраните этот кусок кода в блокноте и назовите его Download_Install_Last_Flash_Player.bat

@echo off
REM Help page related to installation problems flash player windows (English)
REM English https://helpx.adobe.com/flash-player/kb/installation-problems-flash-player-windows.html
REM Page d'aide relative aux problèmes d'installation flash player windows (Français)
REM French https://helpx.adobe.com/fr/flash-player/kb/installation-problems-flash-player-windows.html
Mode 90,3 & color 9D
Title Download and install the latest version of Adobe Flash Player by Hackoo 2017
Set "Download_Folder=%~dp0Latest_Flash_Player_Installers"
Set "Uninstaller_Folder=%~dp0Uninstaller"
Set "Uninstaller_URL=https://fpdownload.macromedia.com/pub/labs/flashruntimes/flashplayer/uninstall_flash_player.exe"
Set "URL1=http://fpdownload.macromedia.com/pub/flashplayer/latest/help/install_flash_player.exe"
Set "URL2=http://fpdownload.macromedia.com/pub/flashplayer/latest/help/install_flash_player_ax.exe"
Set "URL3=http://fpdownload.macromedia.com/pub/flashplayer/latest/help/install_flash_player_ppapi.exe"
Set "URL_Help=https://helpx.adobe.com/flash-player/kb/installation-problems-flash-player-windows.html"
If Not Exist "%Uninstaller_Folder%" MD "%Uninstaller_Folder%"
If Not Exist "%Download_Folder%" MD "%Download_Folder%"
Call :Killing_Running_Browsers
Rem We Play radio just for fun and in order to let the user be patient until the download ended
Call :Play_DJ_Buzz_Radio
Call :Uninstalling_Flash_Player
Call :Download_and_Install_Flash_Player
REM Just to check (Check Button on the web page) if the latest Adobe Flash Player is installed successfully or not !
Start "Help page" "%URL_Help%" & Call :Stop_Radio & Exit
::***************************************************************************************************
:Uninstalling_Flash_Player
cls & echo( 
@For %%i in (%Uninstaller_URL%) do Set "Uninstaller_File=%%~nxi"
Call :Download "%Uninstaller_URL%" "%Uninstaller_Folder%\%Uninstaller_File%"
echo    Unistalling older and previous version of Adobe Flash Player ...
%Uninstaller_File% -uninstall
exit /b
::***************************************************************************************************
:Killing_Running_Browsers
set "Browsers_List=firefox chrome iexplore opera"
cls & echo(
echo     Killing any running instances of those browsers "%Browsers_List%" ...
@For %%i in (%Browsers_List%) Do ( 
    Taskkill /IM "%%i.exe" /F>nul 2>&1
)
exit /b
::***************************************************************************************************
:Download_and_Install_Flash_Player
@For %%i in (%URL1%) do Set "File1=%%~nxi"
Call :Download "%URL1%" "%Download_Folder%\%File1%"
Call :Installing_Flash_Player "%Download_Folder%\%File1%"
@For %%i in (%URL2%) do Set "File2=%%~nxi"
Call :Download "%URL2%" "%Download_Folder%\%File2%"
Call :Installing_Flash_Player "%Download_Folder%\%File2%"
@For %%i in (%URL3%) do Set "File3=%%~nxi"
Call :Download "%URL3%" "%Download_Folder%\%File3%"
Call :Installing_Flash_Player "%Download_Folder%\%File3%"
exit /b
::***************************************************************************************************
:Installing_Flash_Player <Install_File>
cls & color 9B
echo(
echo   Please wait a while ... installing "%~nx1" is in progress ...
%1 -install
exit /b
::***************************************************************************************************
:Download <url> <File>
cls & color 0A
echo(
echo      Please wait a while ... Downloading "%~n2" is in progress ...
Powershell.exe -command "(New-Object System.Net.WebClient).DownloadFile('%1','%2')"
exit /b
::***************************************************************************************************
:Play_DJ_Buzz_Radio
Taskkill /IM "wscript.exe" /F >nul 2>&1
Set "vbsfile=%temp%\DJBuzzRadio.vbs"
Set "URL=http://www.chocradios.ch/djbuzzradio_windows.mp3.asx"
Call:Play "%URL%" "%vbsfile%"
Start "" "%vbsfile%"
Exit /b
::**************************************************************
:Play
(
echo Play "%~1"
echo Sub Play(URL^)
echo    Dim Sound
echo    Set Sound = CreateObject("WMPlayer.OCX"^)
echo    Sound.URL = URL
echo    Sound.settings.volume = 100
echo    Sound.Controls.play
echo    do while Sound.currentmedia.duration = 0
echo       wscript.sleep 100
echo    loop
echo    wscript.sleep (int(Sound.currentmedia.duration^)+1^)*1000
echo End Sub
)>%~2
exit /b
::**************************************************************
:Stop_Radio
Taskkill /IM "wscript.exe" /F >nul 2>&1
If Exist "%vbsfile%" Del "%vbsfile%"
::**************************************************************