В Outlook2010 есть ли способ просмотреть текущие дремлющие напоминания?

Есть ли способ в Outlook 2010, чтобы получить список элементов, которые в настоящее время откладываются? Например, скажем, через две недели я установил напоминание, которое должно появиться в пятницу для важного обеденного собрания в следующий понедельник (мне нравится напоминать о заданиях в понедельник перед выходными). Когда в пятницу всплывает напоминание, я откладываю его на три дня, чтобы оно снова всплыло прямо перед обедом в понедельник. Затем наступает понедельник, и моя память становится нечеткой, и я немного параноидален, потому что я случайно отклонил напоминание в пятницу вместо того, чтобы правильно отложить его. Я все еще вижу исходную встречу в своем календаре, но мне нужно убедиться, что у меня действительно будет всплывающее напоминание, когда я ожидаю его, чтобы я не пропустил свою встречу.

Есть ли способ в Outlook 2010, чтобы получить список напоминаний, которые в настоящее время откладываются? Это также было бы полезно в тех случаях, когда я выполняю задание, напоминание которого я отложил до позднего времени, и теперь я хочу открыть отложенное напоминание и отменить его.

Sub SnoozedReminders()

' http://www.jpsoftwaretech.com/check-your-outlook-reminders-in-vba/

Dim MyReminder As Outlook.Reminder
Dim MyReminders As Outlook.Reminders
Dim Report As String
Dim i As Long

Set MyReminders = Outlook.Reminders

i = 0

For Each MyReminder In MyReminders

    If HasReminderFired(MyReminder) = True Then
        i = i + 1
        Report = Report & i & ": " & MyReminder.Caption & vbCr & _
            "     Snoozed to " & MyReminder.NextReminderDate & vbCr & vbCr
    End If

Next MyReminder

CreateReportAsEmail "Snoozed Items", Report

End Sub


Function HasReminderFired(rmndr As Outlook.Reminder) As Boolean
    HasReminderFired = (rmndr.OriginalReminderDate <> rmndr.NextReminderDate)
End Function


' VBA SubRoutine which displays a report inside an email
' Programming by Greg Thatcher, http://www.GregThatcher.com

Public Sub CreateReportAsEmail(Title As String, Report As String)

    On Error GoTo On_Error

    Dim Session As Outlook.Namespace
    Dim mail As MailItem
    Dim MyAddress As AddressEntry
    Dim Inbox As Outlook.folder 

    Set Session = Application.Session
    Set Inbox = Session.GetDefaultFolder(olFolderInbox)
    Set mail = Inbox.items.Add("IPM.Mail")

    mail.Subject = Title
    mail.Body = Report

    mail.Save
    mail.Display

Exiting:
    Set Session = Nothing
    Set Inbox = Nothing
    Set mail = Nothing
    Exit Sub

On_Error:
    MsgBox "error=" & Err.Number & " " & Err.Description
    Resume Exiting

End Sub

Если вы не знакомы с VBA, см. Страницу объяснения Slipstick . Вы найдете информацию о:

• настройки безопасности макросов;
• куда поместить код (Вы можете использовать обычный модуль с Insert | Module); и
• как создать кнопку.

В соответствии с этим сообщением на форуме Просмотр отложенных элементов невозможно просмотреть список отложенных элементов. В публикации предполагается, что вы можете увидеть ограниченное количество полезной информации, создав собственное представление, отображающее некоторые поля напоминания.

Попробуйте нажать на вкладку «Календарь», выбрать «Просмотр и изменение вида». Затем выберите Список. Появится список всех напоминаний.