Можно ли быстро установить все пространства на одни и те же обои?

Здорово, что Lion позволяет разным пространствам иметь разные обои, но я не нашел простого способа заставить их использовать одинаковые обои.

Единственный способ, которым я достиг этого, - это либо вручную изменить обои для каждого пространства, либо закрыть все пространства (кроме того, в котором есть нужные обои) и снова открыть их.

У кого-нибудь есть решение, позволяющее мне быстро установить для всех пространств одинаковые обои?

У вас есть какое-нибудь решение?

Я столкнулся с той же проблемой, поэтому я создал быстрое решение для обезьян с AppleScript:

set spacenumber to 4 -- how many spaces do you have?

-- Try to get number of spaces from System preferences
tell application "System Preferences"
    reveal anchor "shortcutsTab" of pane id "com.apple.preference.keyboard"
    tell application "System Events" to tell window "Keyboard" of process "System Preferences"
        set spacenumber to count (UI elements of rows of outline 1 of scroll area 2 of splitter group 1 of tab group 1 whose name begins with "Switch to Desktop")
    end tell
    quit
end tell

tell application "System Events"
    set _desktops to every desktop
    if (count of _desktops) > 1 then
        -- if you have multiple displat (eg: external monitor) ask which
        display dialog "Choose your screen." buttons (get display name of every desktop) default button 1
        set _display to the button returned of the result
    else
        -- else set the one display as selected
        set _display to display name of the first desktop
    end if

    set new_file to choose file with prompt "Choose an image."
    repeat with i from 0 to (spacenumber - 1)
        delay 1
        tell (every desktop whose display name is _display) to set picture to new_file as alias
        tell process "WindowServer" to key code {124} using control down -- Go to the next space
    end repeat
end tell

Это хорошо для меня сейчас.

Обновить: number of spaces получатель добавлен из: https://discussions.apple.com/thread/3824777?start=0&tstart=0