Как получить текущее имя столбца в Excel?

Какова функция для получения текущего номера строки и текущего имени столбца для ячейки в Excel?

Вы можете использовать ROWи COLUMNфункцию , чтобы сделать это. Если вы опустите аргумент для этих формул, используется текущая ячейка. Они могут быть использованы непосредственно с в OFFSETфункции , или любой другой функции , где вы можете указать , как строки и столбца в виде числовых значений.

Например, если вы вводите =ROW()в ячейку D8, возвращаемое значение равно 8. Если вы вводите =COLUMN()в той же ячейке, возвращаемое значение равно 4.

Если вам нужна буква столбца, вы можете использовать CHARфункцию. Я не рекомендую использовать буквы для представления столбца, поскольку при переходе к двухбуквенным именам столбцов все становится сложнее (где использование цифр в любом случае более логично).

В любом случае, если вы все еще хотите получить букву столбца, вы можете просто добавить 64 к номеру столбца (64 - на один символ меньше A), поэтому в предыдущем примере, если вы установите значение ячейки равным =CHAR(COLUMN()+64), возвращаемое значение будет D, Если бы вы хотели, чтобы значением ячейки было само местоположение ячейки, была бы полная формула =CHAR(COLUMN()+64) & ROW().

Просто к вашему сведению, я получил 64 из таблицы ASCII. Вы также можете использовать CODEформулу, поэтому обновленная формула будет такой =CHAR(COLUMN() + CODE("A") - 1). Вы должны вычесть 1, поскольку минимальное значение COLUMNвсегда равно 1, а затем минимальное возвращаемое значение всей формулы будет B.

Однако это не будет работать с двухбуквенными столбцами. В этом случае вам потребуется следующая формула для правильного анализа двухбуквенных столбцов:

=IF(COLUMN()>26,IF(RIGHT(CHAR(IF(MOD(COLUMN()-1,26)=0,1,MOD(COLUMN()-1,26))+64),1)="Y",CHAR(INT((COLUMN()-1)/26)+64) & "Z",CHAR(INT((COLUMN()-1)/26)+64) & CHAR(IF(MOD(COLUMN(),26)=0,1,MOD(COLUMN(),26))+64)),CHAR(COLUMN()+64))&ROW()

Я не уверен, есть ли более простой способ сделать это или нет, но я знаю, что это работает от клетки A1к ZZ99без проблем. Однако это показывает, почему лучше избегать использования буквенных идентификаторов столбцов и придерживаться формул, основанных исключительно на числах (например, используя номер столбца вместо буквы с OFFSET).

Попробуйте следующую функцию:

=SUBSTITUTE(ADDRESS(1,COLUMN(),4),"1","")

Объяснение: ADDRESS(row_num, column_num, [abs_num]). [abs_num] = 4= относительный адрес. Это означает, что в возвращаемом значении нет $. Для столбца «AB» ADDRESSбудет возвращено «AB1». Заменитель удаляет «1».

Попробуй это

=SUBSTITUTE(SUBSTITUTE(CELL("address"),"$" & ROW(),""), "$", "")

Это дает вам точный заголовок столбца, без каких-либо $ и т. Д.

Введите это в любую ячейку:

Español :

=SI(ENTERO((COLUMNA()-1)/26)=0;"";CAR((ENTERO(COLUMNA()-1)/26)+64))&CAR(COLUMNA()-(ENTERO((COLUMNA()-1)/26)*26)+64)

Английский :

=IF(INT((COLUMN()-1)/26)=0,"",CHAR((INT(COLUMN()-1)/26)+64))&CHAR(COLUMN()-(INT((COLUMN()-1)/26)*26)+64)

Вы можете заменить column () номером строки.

Чтобы получить имя столбца, я использовал следующие формулы.

Для конкретной ячейки:

=SUBSTITUTE(CELL("address",H3),"$" & ROW(H3),"")

Для текущей ячейки:

=SUBSTITUTE(CELL("address"),"$" & ROW(),"")

Попробуйте этот вариант. Он работает на трехбуквенных столбцах и не оставляет «$» на переднем конце:

=SUBSTITUTE(ADDRESS(ROW(XFD123),COLUMN(XFD123),4),ROW(XFD123),"")

Немного ручная, но меньше VBA и более простая формула:

• В строке Excel, например, ячейка A1, введите номер столбца. =column()
• В строке ниже введите =Address(1,A1)
• Это обеспечит результат $A$1

После того, как значения скопированы, найдите и замените $и 1пустым.

Это будет работать так же

=MID(CELL("address"),2,FIND("$",CELL("address"),2)-2)

Другой возможный способ - использовать что-то вроде этого:

=INDIRECT("MySheet1!"&LOOKUP(COLUMN(),colid)&ROW())

Где colidотносится к именованному диапазону, который вы бы создали в другом месте в рабочей книге, содержащей два смежных столбца с несколькими строками: первый столбец, содержащий числа от 1 до n, соответствующий COLUMN()номеру, второй, содержащий буквы A - ZZ, или сколько бы столбцов ни ссылались на вас хочу разместить. Это ROW()нормально, чтобы вернуть номер строки.

Поэтому, если вы скопируете указанную выше строку в ячейку A1 «MySheet2», она получит значение =MySheet1!A1и вернет найденное значение в соответствующей ячейке MySheet1.

Это позволит вам, например, использовать MySheet1в качестве рабочей области удаление и повторную вставку новых данных, в то время как любое форматирование или вычисления MySheet2, относящиеся к этому содержимому, будут продолжать корректно работать с новыми наборами данных из целевой таблицы с вкладками.

Решение для польской версии Excel:

• для конкретной ячейки:

=PODSTAW(PODSTAW(KOMÓRKA("adres";B1);"$" & WIERSZ();""); "$"; "")

• для текущей ячейки:

=PODSTAW(PODSTAW(KOMÓRKA("adres");"$" & WIERSZ();""); "$"; "")

Вот VBA, пользовательская формула, решение. Работает с 1, 2 и 3 буквенными столбцами.

Поместите следующее в модуль кода:

Function COLUMNLETTER(Optional rng As Range) As String
    'Returns the Column Letter of the top left cell in rng.

    If rng Is Nothing Then Set rng = Application.Caller
    COLUMNLETTER = Left(rng.Address(0, 0), IIf(rng.Column > 26, IIf(rng.Column > 702, 3, 2), 1))

End Function

= COLUMNLETTER () в любой ячейке вернет букву столбца ячейки.
= COLUMNLETTER (В3) в любой клетке будет возвращать B .

Эта пользовательская функция прекрасно работает при создании общих формул внутри функции INDIRECT.

=MID(ADDRESS(ROW(),COLUMN()),2,FIND("$",ADDRESS(ROW(),COLUMN()),2)-2)

Формула адреса работает, возвращая имя столбца и строки. Возвращенный формат всегда будет $(Column Letters)$(Row Numbers)- например, $AA$2или$XAA$243556

Если мы знаем, что $ всегда будет появляться в первом символе, мы можем использовать первую среднюю формулу, чтобы начать вытягивать символы после первого знака $ (то есть 2-го символа).

Затем мы находим следующий знак $ (как мы знаем, их будет только два), и мы знаем, сколько символов находится между первым и вторым знаком доллара. Остальное простое вычитание.

Вот как вы можете найти заголовок столбца (то есть букву):

=RIGHT(LEFT(ADDRESS(1,COLUMN()),LEN(ADDRESS(1,COLUMN()))-2),LEN(ADDRESS(1,COLUMN()))-3)

попробуй это:

=LEFT(ADDRESS(1,COLUMN(),4),LEN(ADDRESS(1,COLUMN(),4))-1)

Следующая формула работает независимо от того, где вы ее поместили (она вернет вам имя столбца).

=SUBSTITUTE(SUBSTITUTE(ADDRESS(ROW(),COLUMN()),"$",""),ROW(),"")

попробуй это:

= IF (COLUMN ()> 26, CHAR (COLUMN () / 26 +64), "") & CHAR (MOD (COLUMN () - 1,26) +65) & ROW ()

эта функция действует до "ZY1" или столбца = 701

=IF(COLUMN()>702,RIGHT(LEFT(ADDRESS(ROW(),COLUMN()),4),3),IF(COLUMN()>26,RIGHT(LEFT(ADDRESS(ROW(),COLUMN()),3),2),RIGHT(LEFT(ADDRESS(ROW(),COLUMN()),2),1)))