Emacs эквивалентно VIM CI "?

Есть ли в emacs эквивалент команды VIM ci? В основном я хочу заменить текст внутри набора кавычек.

В VIM я могу ci) или ci] или ci}, чтобы "изменить внутренний *" ...

Вверху моей головы самая близкая команда, M-z "которая удаляет все от точки до следующего вхождения символа ".

Существует также C-M-k, иначе говоря, «kill сбалансированное выражение», которое удаляет оператор в круглых скобках или строку в двойных кавычках и т. Д. На основе текущего определения режимов «сбалансированного выражения» и символа, находящегося в данный момент под точкой (т. Е. Оно работает только если курсор находится на открытии "" "или" ("и т. д.).

По аналогии с предложением Джастина CM-SPACE дает вам «mark-sexp», который выберет балансировку, кавычки и т. Д., А затем вы можете Cw или что-то еще, чтобы заставить его уйти. В случае, если вы хотите ВИДЕТЬ, что вы собираетесь удалить, прежде чем удалить это ...

Да! Эквивалентом команды VIM ci "команда в Emacs является ... ci" :-)
http://www.emacswiki.org/emacs-de/Vimpulse

Просто наткнулся на этот вопрос; Вот индивидуальное решение, которое работает для меня:

(defun seek-backward-to-char (chr)
  "Seek backwards to a character"
  (interactive "cSeek back to char: ")
  (while (not (= (char-after) chr))
    (forward-char -1)))


(defun delete-between-pair (char)
  "Delete in between the given pair"
  (interactive "cDelete between char: ")
  (seek-backward-to-char char)
  (forward-char 1)
  (zap-to-char 1 char)
  (insert char)
  (forward-char -1))

Затем свяжите delete -ween-pair с любым ключом, который вам нравится. Для меня это связано с Cz я.

Боюсь, я не знаю о функции CIM VIM, но вы смотрели на Emacs regexp replace? Я не могу говорить с точной семантикой или с тем, насколько легко ее использовать в сравнении, но я бы использовал то, что, как я думаю, вы хотите.

• Руководство по Emacs по замене регулярных выражений
• Замечания по соответствию Emacs регулярному выражению
• Обязательный мультфильм

Я сделал второстепенный режим, который предоставляет некоторые из тех средств Vim, которые называются Markit .

Magnars (автор сайта EmacsRocks) написал этот плагин, чтобы делать именно то, что вы просите.

https://github.com/magnars/change-inner.el

Очевидно, вы также можете использовать режим зла.

Вот моя версия, которая удалит все внутри (или включая) совпадающую пару символов. Пары символов определены в списке, так что соответствующий начальный / конечный символ известен. Я сопоставил его с "Cc i" для изменения и "Cc a" для изменения всех.

Он также копирует удаленные символы в буфер обмена для последующего вставки.

; Re-create ci" ca"...
(defun seek-backward-to-char (chr)
  "Seek backwards to a character"
  (interactive "cSeek back to char: ")
  (while (not (= (char-after) chr))
    (forward-char -1)))

(setq char-pairs
      '(( ?\" . ?\" )
        ( ?\' . ?\' )
        ( ?\( . ?\) )
        ( ?\[ . ?\] )
        ( ?\{ . ?\} )
        ( ?<  . ?>  )))

(defun get-char-pair (chr)
  (let ((result ()))
    (dolist (x char-pairs)
      (setq start (car x))
      (setq end (cdr x))
      (when (or (= chr start) (= chr end))
        (setq result x)))
      result))

(defun get-start-char (chr)
  (car (get-char-pair chr)))
(defun get-end-char (chr)
  (cdr (get-char-pair chr)))

(defun seek-to-matching-char (start end count)
  (while (> count 0)
    (if (= (following-char) end)
        (setq count (- count 1))
      (if (= (following-char) start)
          (setq count (+ count 1))))
    (forward-char 1)))

(defun seek-backward-to-matching-char (start end count)
  (if (= (following-char) end)
      (forward-char -1))
  (while (> count 0)
    (if (= (following-char) start)
        (setq count (- count 1))
      (if (= (following-char) end)
          (setq count (+ count 1))))
    (if (> count 0)
        (forward-char -1))))

(defun delete-between-pair (char)
  "Delete in between the given pair"
  (interactive "cDelete between char: ")
  (seek-backward-to-matching-char (get-start-char char) (get-end-char char) 1)
  (forward-char 1)
  (setq mark (point))
  (seek-to-matching-char (get-start-char char) (get-end-char char) 1)
  (forward-char -1)
  (kill-region mark (point)))

(defun delete-all-pair (char)
  "Delete in between the given pair and the characters"
  (interactive "cDelete all char: ")
  (seek-backward-to-matching-char (get-start-char char) (get-end-char char) 1)
  (setq mark (point))
  (forward-char 1)
  (seek-to-matching-char (get-start-char char) (get-end-char char) 1)
  (kill-region mark (point)))

(global-set-key (kbd "C-c i") 'delete-between-pair)
(global-set-key (kbd "C-c a") 'delete-all-pair)

Это было то, чего мне не хватало в Vim, и zap-to-char, похоже, это не правильно.

Вот моя скромная попытка воссоздать "ci" и "ca":

(defun change-outer (str)
  (interactive "sChange outer: ")
  (condition-case nil
      (search-backward str (line-beginning-position))
    (error (search-forward str (line-end-position))
       (forward-char -1)))
  (kill-sexp)
)

(defun change-inner (str)
  (interactive "sChange inner: ")
  (condition-case nil
      (search-backward str (line-beginning-position))
    (error (search-forward str (line-end-position))
       (forward-char -1)))
  (push-mark)
  (forward-sexp)
  (forward-char -1)
  (exchange-point-and-mark)
  (forward-char 1)
  (kill-region (point) (mark))
)

Обычно условие-случай не является необходимым, поскольку третий (необязательный) параметр search-forward / search-backward предназначен для указания того, что делать в случае сбоя поиска. Но по какой-то причине размещение второго поиска в качестве третьего параметра для первого приводит к странному поведению.

Я попробовал решения здесь, но нашел, что каждое из них хотело в некотором роде, таким образом, я придумал это. Он принимает начальный или конечный разделитель и использует встроенные функции Emacs, чтобы не нуждаться в таблице перевода для разделителей.

(defun change-inner (prefix character)
  "Kill region inside delimiters, using either beginning or
ending delimiter.  With prefix arg, kill including delimiters."

  (interactive "p\nc")
  (let ((initial-point (point))
        (start)
        (end)
        (move-point-by (if (> prefix 1) 0 1)))

    (condition-case nil
        (progn
          ;; Search forward for given char
          (search-forward (char-to-string character))
          (setq end (- (point) move-point-by))

          (condition-case nil
              (backward-sexp)
            (error (backward-list)))

          (setq start (+ (point) move-point-by))
          (kill-region start end)
          (or prefix (forward-char)))

      (error (progn
               ;; Reset and search backward for given char
               (goto-char initial-point)
               (search-backward (char-to-string character))
               (setq start (+ (point) move-point-by))

               (condition-case nil
                   (forward-list)
                 (error (forward-sexp))))

             (setq end (- (point) move-point-by))
             (kill-region start end)
             (or prefix (backward-char))))))
(global-set-key (kbd "M-i") 'change-inner)

(defun change-outer ()
  (interactive)
  (let ((current-prefix-arg '(4)))
    (call-interactively 'change-inner)))
(global-set-key (kbd "M-o") 'change-outer)