Я использую следующую функцию

=DAYS360(A2, A35)

чтобы вычислить разницу между двумя датами в моем столбце. Однако столбец постоянно расширяется, и в настоящее время мне приходится вручную изменять «A35», когда я обновляю свою электронную таблицу.

Есть ли способ (в Google Таблицах) найти последнюю непустую ячейку в этом столбце, а затем динамически установить этот параметр в приведенной выше функции?

Может быть более красноречивый способ, но я придумал его:

Функция поиска последней заполненной ячейки в столбце:

=INDEX( FILTER( A:A ; NOT( ISBLANK( A:A ) ) ) ; ROWS( FILTER( A:A ; NOT( ISBLANK( A:A ) ) ) ) )

Итак, если вы объедините его с вашей текущей функцией, это будет выглядеть так:

=DAYS360(A2,INDEX( FILTER( A:A ; NOT( ISBLANK( A:A ) ) ) ; ROWS( FILTER( A:A ; NOT( ISBLANK( A:A ) ) ) ) ))

Чтобы найти последнюю непустую ячейку, вы можете использовать INDEXи MATCHтакие функции:

=DAYS360(A2; INDEX(A:A; MATCH(99^99;A:A; 1)))

Думаю, это немного быстрее и проще.

Если A2: A содержит даты подряд, то INDEX (A2: A, COUNT (A2: A)) вернет последнюю дату. Окончательная формула

=DAYS360(A2,INDEX(A2:A,COUNT(A2:A)))

Мой любимый:

=INDEX(A2:A,COUNTA(A2:A),1)

Итак, для необходимости OP:

=DAYS360(A2,INDEX(A2:A,COUNTA(A2:A),1))

Если столбец расширялся только за счет добавленных подряд дат, как в моем случае, я использовал только функцию MAX, чтобы получить последнюю дату.

Окончательная формула будет такой:

=DAYS360(A2; MAX(A2:A)) 

Хотя на вопрос уже дан ответ, есть красноречивый способ сделать это.

Use just the column name to denote last non-empty row of that column.

Например:

Если ваши данные находятся внутри, A1:A100и вы хотите добавить еще несколько данных в столбец A, скажем, это может быть A1:A105или даже A1:A1234позже, вы можете использовать этот диапазон:

A1:A

Итак, чтобы получить последнее непустое значение в диапазоне, мы будем использовать 2 функции:

• COUNTA
• ИНДЕКС

Ответ есть =INDEX(B3:B,COUNTA(B3:B)).

Вот объяснение:

COUNTA(range) возвращает количество значений в диапазоне, мы можем использовать это, чтобы получить количество строк.

INDEX(range, row, col)возвращает значение в диапазоне в позиции rowи col( col=1если не указано)

Примеры:

INDEX(A1:C5,1,1) = A1
INDEX(A1:C5,1) = A1 # implicitly states that col = 1
INDEX(A1:C5,1,2) = A2
INDEX(A1:C5,2,1) = B1
INDEX(A1:C5,2,2) = B2
INDEX(A1:C5,3,1) = C1
INDEX(A1:C5,3,2) = C2

Для изображения выше наш диапазон будет B3:B. Таким образом , мы будем считать , сколько значений есть в диапазоне B3:Bот COUNTA(B3:B)первого. В левой части он будет производить, 8так как есть 8 значений, в то время как он будет производить 9в правой части. Мы также знаем, что последнее значение находится в 1-м столбце диапазона, B3:Bпоэтому colпараметр INDEXдолжен быть равен 1, а rowпараметр должен быть COUNTA(B3:B).

PS : пожалуйста, проголосуйте за ответ @ bloodymurderlive, поскольку он написал его первым, я просто объясняю это здесь.

Вот еще один:

=indirect("A"&max(arrayformula(if(A:A<>"",row(A:A),""))))

С окончательным уравнением:

=DAYS360(A2,indirect("A"&max(arrayformula(if(A:A<>"",row(A:A),"")))))

Другие уравнения здесь работают, но мне нравится это, потому что оно упрощает получение номера строки, что, как мне кажется, мне нужно делать чаще. Просто номер строки будет таким:

=max(arrayformula(if(A:A<>"",row(A:A),"")))

Первоначально я пытался найти именно это, чтобы решить проблему с электронной таблицей, но не смог найти ничего полезного, в котором просто указан номер строки последней записи, поэтому, надеюсь, это будет полезно для кого-то.

Кроме того, у этого есть дополнительное преимущество, заключающееся в том, что он работает для любого типа данных в любом порядке, и вы можете иметь пустые строки между строками с содержимым, и он не учитывает ячейки с формулами, которые оцениваются как "". Он также может обрабатывать повторяющиеся значения. В целом это очень похоже на уравнение, которое использует здесь max ((G: G <> "") * row (G: G)), но упрощает выбор номера строки, если это то, что вам нужно. ,

В качестве альтернативы, если вы хотите поместить сценарий в свой лист, вы можете облегчить себе жизнь, если планируете делать это много раз. Вот этот сценарий:

function lastRow(sheet,column) {
  var ss = SpreadsheetApp.getActiveSpreadsheet();
  if (column == null) {
    if (sheet != null) {
       var sheet = ss.getSheetByName(sheet);
    } else {
      var sheet = ss.getActiveSheet();
    }
    return sheet.getLastRow();
  } else {
    var sheet = ss.getSheetByName(sheet);
    var lastRow = sheet.getLastRow();
    var array = sheet.getRange(column + 1 + ':' + column + lastRow).getValues();
    for (i=0;i<array.length;i++) {
      if (array[i] != '') {       
        var final = i + 1;
      }
    }
    if (final != null) {
      return final;
    } else {
      return 0;
    }
  }
}

Здесь вы можете просто ввести следующее, если хотите, чтобы последняя строка на том же листе, который вы в настоящее время редактируете:

=LASTROW()

или если вам нужна последняя строка определенного столбца с этого листа или определенного столбца с другого листа, вы можете сделать следующее:

=LASTROW("Sheet1","A")

И для последней строки конкретного листа в целом:

=LASTROW("Sheet1")

Затем, чтобы получить фактические данные, вы можете использовать косвенные:

=INDIRECT("A"&LASTROW())

или вы можете изменить приведенный выше сценарий в последних двух строках возврата (последние две, поскольку вам нужно будет поместить и лист, и столбец, чтобы получить фактическое значение из фактического столбца) и заменить переменную следующим:

return sheet.getRange(column + final).getValue();

и

return sheet.getRange(column + lastRow).getValue();

Одним из преимуществ этого сценария является то, что вы можете выбрать, хотите ли вы включать уравнения, которые оцениваются как "". Если аргументы не добавлены, будут учитываться уравнения, оцениваемые как «», но если вы укажете лист и столбец, они теперь будут учитываться. Кроме того, есть большая гибкость, если вы хотите использовать варианты сценария.

Наверное, перебор, но все возможно.

А как насчет этой формулы для получения последнего значения:

=index(G:G;max((G:G<>"")*row(G:G)))

И это будет окончательная формула вашей исходной задачи:

=DAYS360(G10;index(G:G;max((G:G<>"")*row(G:G))))

Предположим, что ваша начальная дата - в G10.

Я пошел другим путем. Поскольку я знаю, что буду добавлять что-то в строку / столбец один за другим, я нахожу последнюю строку, сначала подсчитывая поля, в которых есть данные. Я продемонстрирую это в колонке:

=COUNT(A5:A34)

Итак, допустим, что возвращено 21. A5 на 4 строки ниже, поэтому мне нужно получить 21-ю позицию с 4-й строки вниз. Я могу сделать это, используя несанкционированное использование, например:

=INDIRECT("A"&COUNT(A5:A34)+4)

Он находит количество строк с данными и возвращает мне число, которое я использую в качестве модификатора индекса.

для ряда:

=ARRAYFORMULA(INDIRECT("A"&MAX(IF(A:A<>"", ROW(A:A), ))))

для столбца:

=ARRAYFORMULA(INDIRECT(ADDRESS(1, MAX(IF(1:1<>"", COLUMN(1:1), )), 4)))

Это кажется самым простым решением, которое я нашел для получения последнего значения в постоянно расширяющемся столбце:

=INDEX(A:A,COUNTA(A:A),1)

Это работает для меня. Получите последнее значение столбца A в листе Google:

=index(A:A,max(row(A:A)*(A:A<>"")))

(Он также пропускает пустые строки между ними, если они есть)

Вычислите разницу между последней датой в столбце A и датой в ячейке A2.

=MAX(A2:A)-A2

Это даст содержимое последней ячейки:

=indirect("A"&max(ARRAYFORMULA(row(a:a)*--(a:a<>""))))

Это даст адрес последней ячейки:

="A"&max(ARRAYFORMULA(row(a:a)*--(a:a<>"")))

Это даст строку последней ячейки:

=max(ARRAYFORMULA(row(a:a)*--(a:a<>"")))

Может, вы предпочтете сценарий. Этот сценарий намного короче, чем огромный, опубликованный кем-то другим:

Перейдите в редактор скриптов и сохраните этот скрипт:

function getLastRow(range){
  while(range.length>0 && range[range.length-1][0]=='') range.pop();
  return range.length;
}

Как только это будет сделано, вам просто нужно ввести это в ячейку:

=getLastRow(A:A)

Любитель делает это так: «= СЦЕПИТЬ (« A », COUNTUNIQUE (A1: A9999))», где A1 - первая ячейка в столбце, а A9999 находится дальше по этому столбцу, чем я ожидал иметь какие-либо записи. Этот результирующий A # можно использовать с функцией INDIRECT по мере необходимости.

Чтобы найти номер последней непустой строки (с пропуском пробелов между ними), я использовал ниже для поиска столбца A.

=ArrayFormula(IFNA(match(2,1/(A:A<>""))))