Как заставить пакетный файл завершить работу при обнаружении ошибки?

У меня есть командный файл, который снова и снова вызывает один и тот же исполняемый файл с разными параметрами. Как сделать так, чтобы он немедленно завершился, если один из вызовов возвращает код ошибки любого уровня?

По сути, я хочу эквивалент MSBuild ContinueOnError=false.

Проверьте errorlevelв ifзаявлении, а затем exit /b(выход из б файла ATCH только, а не весь процесс cmd.exe) для отличных 0 значений.

same-executable-over-and-over.exe /with different "parameters"
if %errorlevel% neq 0 exit /b %errorlevel%

Если вы хотите, чтобы значение уровня ошибки распространялось за пределы вашего пакетного файла

if %errorlevel% neq 0 exit /b %errorlevel%

но если это внутри, forэто становится немного сложнее. Вам понадобится что-то похожее на:

setlocal enabledelayedexpansion
for %%f in (C:\Windows\*) do (
    same-executable-over-and-over.exe /with different "parameters"
    if !errorlevel! neq 0 exit /b !errorlevel!
)

Изменить: Вы должны проверить ошибку после каждой команды. В пакете cmd.exe / command.com нет общего типа конструкции «при ошибке». Я также обновил свой код для CodeMonkey , хотя я никогда не сталкивался с отрицательным уровнем ошибок ни в одном из моих пакетных операций на XP или Vista.

Добавьте || goto :labelк каждой строке, а затем определите :label.

Например, создайте этот файл .cmd:

@echo off

echo Starting very complicated batch file...
ping -invalid-arg || goto :error
echo OH noes, this shouldn't have succeeded.
goto :EOF

:error
echo Failed with error #%errorlevel%.
exit /b %errorlevel%

Смотрите также вопрос о выходе из подпрограммы пакетного файла .

Кратчайший:

command || exit /b

Если вам нужно, вы можете установить код выхода:

command || exit /b 666

И вы также можете войти:

command || echo ERROR && exit /b

Одно незначительное обновление, вы должны изменить проверки «if errorlevel 1» на следующее ...

IF %ERRORLEVEL% NEQ 0 

Это потому, что в XP вы можете получить отрицательные числа как ошибки. 0 = нет проблем, все остальное - проблема.

И помните, как DOS обрабатывает тесты «IF ERRORLEVEL». Он вернет true, если номер, который вы проверяете, это число или больше, поэтому, если вы ищете конкретные номера ошибок, вам нужно начать с 255 и продолжить работу.

Вот программа polyglot для BASH и Windows CMD, которая выполняет серию команд и завершает свою работу в случае сбоя любой из них:

#!/bin/bash 2> nul

:; set -o errexit
:; function goto() { return $?; }

command 1 || goto :error

command 2 || goto :error

command 3 || goto :error

:; exit 0
exit /b 0

:error
exit /b %errorlevel%

Я использовал этот тип вещей в прошлом для сценария непрерывной интеграции для нескольких платформ .

Я предпочитаю форму команды ИЛИ, так как считаю ее наиболее читаемой (в отличие от наличия if после каждой команды). Однако наивно способ сделать это, command || exit /b %ERRORLEVEL%является неправильным .

Это связано с тем, что пакетное развертывание переменных происходит при первом чтении строки, а не при их использовании. Это означает, что если commandв приведенной выше строке произойдет сбой, пакетный файл завершится правильно, но завершится с кодом возврата 0, потому что это значение, которое %ERRORLEVEL%было в начале строки. Очевидно, что это нежелательно в нашем скрипте, поэтому мы должны включить отложенное расширение , например:

SETLOCAL EnableDelayedExpansion

command-1 || exit /b !ERRORLEVEL!
command-2 || exit /b !ERRORLEVEL!
command-3 || exit /b !ERRORLEVEL!
command-4 || exit /b !ERRORLEVEL!

Этот фрагмент будет выполнять команды 1-4, и в случае сбоя любой из них он завершится с тем же кодом завершения, что и неудачная команда.

Мы не всегда можем зависеть от ERRORLEVEL, потому что много раз внешние программы или пакетные сценарии не возвращают коды завершения.

В этом случае мы можем использовать общие проверки для сбоев, как это:

IF EXIST %outfile% (DEL /F %outfile%)
CALL some_script.bat -o %outfile%
IF NOT EXIST %outfile%  (ECHO ERROR & EXIT /b)

И если программа выводит что-то на консоль, мы можем это проверить.

some_program.exe 2>&1 | FIND "error message here" && (ECHO ERROR & EXIT /b)
some_program.exe 2>&1 | FIND "Done processing." || (ECHO ERROR & EXIT /b)

Независимо от того, как я пытался, уровень ошибки всегда остается 0, даже если msbuild не удалось. Итак, я построил мой обходной путь:

Создайте проект и сохраните журнал в Build.log

SET Build_Opt=/flp:summary;logfile=Build.log;append=true

msbuild "myproj.csproj" /t:rebuild /p:Configuration=release /fl %Build_Opt%

искать строку «0 Error» в журнале сборки, установить результат в var

FOR /F "tokens=* USEBACKQ" %%F IN (`find /c /i "0 Error" Build.log`) DO (
    SET var=%%F
)
echo %var%

получить последний символ, который указывает, сколько строк содержит строку поиска

set result=%var:~-1%

echo "%result%"

если строка не найдена, то ошибка> 0, сборка не удалась

if "%result%"=="0" ( echo "build failed" )

Это решение было вдохновлено постом Mechaflash в разделе Как настроить вывод команд в качестве переменной в командном файле

и https://ss64.com/nt/syntax-substring.html

@echo off

set startbuild=%TIME%

C:\WINDOWS\Microsoft.NET\Framework\v3.5\msbuild.exe c:\link.xml /flp1:logfile=c:\link\errors.log;errorsonly /flp2:logfile=c:\link\warnings.log;warningsonly || goto :error

copy c:\app_offline.htm "\\lawpccnweb01\d$\websites\OperationsLinkWeb\app_offline.htm"

del \\lawpccnweb01\d$\websites\OperationsLinkWeb\bin\ /Q

echo Start Copy: %TIME%

set copystart=%TIME%

xcopy C:\link\_PublishedWebsites\OperationsLink \\lawpccnweb01\d$\websites\OperationsLinkWeb\ /s /y /d

del \\lawpccnweb01\d$\websites\OperationsLinkWeb\app_offline.htm

echo Started Build: %startbuild%
echo Started Copy: %copystart%
echo Finished Copy: %TIME%

c:\link\warnings.log

:error

c:\link\errors.log