CMake & CTest: make test не создает тесты

Я пробую CTest в CMake, чтобы автоматически запускать некоторые из моих тестов с использованием make testtarget. Проблема в том, что CMake не «понимает», что тест, который я хочу запустить, должен быть построен, поскольку он является частью проекта.

Поэтому я ищу способ явно указать эту зависимость.

Возможно , это ошибка в CMake (ранее отслеживавшаяся здесь ), которая не работает из коробки. Обходной путь - сделать следующее:

add_test(TestName ExeName)
add_custom_target(check COMMAND ${CMAKE_CTEST_COMMAND}
                  DEPENDS ExeName)

Затем вы можете запустить, make checkи он скомпилирует и запустит тест. Если у вас есть несколько тестов, вам придется использовать DEPENDS exe1 exe2 exe3 ...в строке выше.

На самом деле есть способ использовать make test. Вам необходимо определить сборку исполняемого файла теста как один из тестов, а затем добавить зависимости между тестами. То есть:

ADD_TEST(ctest_build_test_code
         "${CMAKE_COMMAND}" --build ${CMAKE_BINARY_DIR} --target test_code)
ADD_TEST(ctest_run_test_code test_code)
SET_TESTS_PROPERTIES(ctest_run_test_code
                     PROPERTIES DEPENDS ctest_build_test_code)

Я использую вариант ответа Richq. На верхнем уровне CMakeLists.txtя добавляю настраиваемую цель build_and_testдля создания и запуска всех тестов:

find_package(GTest)
if (GTEST_FOUND)
    enable_testing()
    add_custom_target(build_and_test ${CMAKE_CTEST_COMMAND} -V)
    add_subdirectory(test)
endif()

В различных CMakeLists.txtфайлах подпроектов test/я добавляю каждый исполняемый файл теста в зависимости от build_and_test:

include_directories(${CMAKE_SOURCE_DIR}/src/proj1)
include_directories(${GTEST_INCLUDE_DIRS})
add_executable(proj1_test proj1_test.cpp)
target_link_libraries(proj1_test ${GTEST_BOTH_LIBRARIES} pthread)
add_test(proj1_test proj1_test)
add_dependencies(build_and_test proj1_test)

При таком подходе мне просто нужно make build_and_testвместо make test(или make all test), и он имеет преимущество только в создании тестового кода (и его зависимостей). Жаль, что я не могу использовать целевое имя test. В моем случае это не так уж и плохо, потому что у меня есть сценарий верхнего уровня, который выполняет отладку вне дерева и выпускает (и перекрестно компилирует) сборки, вызывая, cmakeа затем makeи переводя testв build_and_test.

Очевидно, что GTest не требуется. Я просто использую / люблю Google Test и хотел поделиться полным примером его использования с CMake / CTest. IMHO, этот подход также имеет то преимущество, что позволяет мне использовать ctest -V, который показывает вывод Google Test во время выполнения тестов:

1: Running main() from gtest_main.cc
1: [==========] Running 1 test from 1 test case.
1: [----------] Global test environment set-up.
1: [----------] 1 test from proj1
1: [ RUN      ] proj1.dummy
1: [       OK ] proj1.dummy (0 ms)
1: [----------] 1 test from proj1 (1 ms total)
1:
1: [----------] Global test environment tear-down
1: [==========] 1 test from 1 test case ran. (1 ms total)
1: [  PASSED  ] 1 test.
1/2 Test #1: proj1_test .......................   Passed    0.03 sec

Если вы пытаетесь подражать make check, вам может пригодиться эта вики-запись:

http://www.cmake.org/Wiki/CMakeEmulateMakeCheck

Я только что проверил, что он успешно выполняет то, что написано (CMake 2.8.10).

Избавьте себя от головной боли:

make all test

Работает для меня "из коробки" и будет создавать зависимости перед запуском теста. Учитывая, насколько это просто, это почти делает встроенную make testфункциональность удобной, поскольку дает вам возможность запускать последние тесты компиляции, даже если ваш код сломан.

Если вы используете CMake> = 3.7, то рекомендуется использовать фикстуры :

add_executable(test test.cpp)
add_test(test_build
  "${CMAKE_COMMAND}"
  --build "${CMAKE_BINARY_DIR}"
  --config "$<CONFIG>"
  --target test
)
set_tests_properties(test_build PROPERTIES FIXTURES_SETUP    test_fixture)
add_test(test test)
set_tests_properties(test       PROPERTIES FIXTURES_REQUIRED test_fixture)

Это делает следующее:

• Добавляет testисполняемую цель, созданную изtest.cpp
• Добавляет test_build«тест», который запускает Cmake для построения цели.test
• Помечает test_buildтест как задачу настройки приспособленияtest_fixture
• Добавьте testтест, который просто запускает testисполняемый файл
• Обозначает testтест как требующий приспособления test_fixture.

Итак, каждый раз, когда testнужно запустить тест test_build, он сначала запускает тест , который создает необходимый исполняемый файл.

Вот что я придумал и использовал:

set(${PROJECT_NAME}_TESTS a b c)

enable_testing()
add_custom_target(all_tests)
foreach(test ${${PROJECT_NAME}_TESTS})
        add_executable(${test} EXCLUDE_FROM_ALL ${test}.cc)
        add_test(NAME ${test} COMMAND $<TARGET_FILE:${test}>)
        add_dependencies(all_tests ${test})
endforeach(test)

build_command(CTEST_CUSTOM_PRE_TEST TARGET all_tests)
string(CONFIGURE \"@CTEST_CUSTOM_PRE_TEST@\" CTEST_CUSTOM_PRE_TEST_QUOTED ESCAPE_QUOTES)
file(WRITE "${CMAKE_BINARY_DIR}/CTestCustom.cmake" "set(CTEST_CUSTOM_PRE_TEST ${CTEST_CUSTOM_PRE_TEST_QUOTED})" "\n")

YMMV

Ответ Деррика, упрощенный и прокомментированный:

# It is impossible to make target "test" depend on "all":
# https://gitlab.kitware.com/cmake/cmake/-/issues/8774
# Set a magic variable in a magic file that tells ctest
# to invoke the generator once before running the tests:
file(WRITE "${CMAKE_BINARY_DIR}/CTestCustom.cmake"
    "set(CTEST_CUSTOM_PRE_TEST ${CMAKE_MAKE_PROGRAM})\n"
)

Это не совсем правильно, так как не решает проблему параллелизма при запуске ninja all test, если кто-то это сделает. Напротив, потому что теперь у вас есть два процесса ниндзя.

(Ftr, я также разделял это решение здесь .)

Все вышеперечисленные ответы идеальны. Но на самом деле CMake использует CTest в качестве инструментов тестирования, поэтому стандартный метод (я думаю, что это так) для выполнения этой миссии:

enable_testing ()
add_test (TestName TestCommand)
add_test (TestName2 AnotherTestCommand)

Затем запустите cmake и make для создания целей. После этого вы можете либо запустить make test , либо просто запустить

ctest

вы получите результат. Это проверено в CMake 2.8.

Подробности см. По адресу: http://cmake.org/Wiki/CMake/Testing_With_CTest#Simple_Testing.

Все ответы хороши, но они подразумевают нарушение традиции запускать тест по команде make test. Я проделал такой трюк:

add_test(NAME <mytest>
WORKING_DIRECTORY ${CMAKE_BINARY_DIR}
COMMAND sh -c "make <mytarget>; $<TARGET_FILE:<mytarget>>")

Это означает, что тест состоит из сборки (необязательно) и запуска исполняемой цели.