Пакетный файл. Удалить все файлы и папки в каталоге

Я хочу иметь командный файл, который удалит все папки и файлы в моей папке кеша для моего беспроводного инструментария.

В настоящее время у меня есть следующее:

cd "C:\Users\tbrollo\j2mewtk\2.5.2\appdb\RMS"
del *.db

Это удалит все файлы .db в моем каталоге RMS , однако я хочу удалить все из этого каталога. Как я могу это сделать?

del *.*вместо del *.db. Это удалит все.

Использование:

• Создать пакетный файл

• Скопируйте приведенный ниже текст в командный файл

  set folder="C:\test"
  cd /d %folder%
  for /F "delims=" %%i in ('dir /b') do (rmdir "%%i" /s/q || del "%%i" /s/q)
  

Это удалит все файлы и папки.

IF EXIST "C:\Users\tbrollo\j2mewtk\2.5.2\appdb\RMS" (
    rmdir "C:\Users\tbrollo\j2mewtk\2.5.2\appdb\RMS" /s /q
)

Это удалит все из папки (и самой папки).

del *.*удаляет только файлы, но не подкаталоги. Чтобы очистить содержимое каталога, вы можете использовать этот скрипт:

@echo off
setlocal enableextensions
if {%1}=={} goto :HELP
if {%1}=={/?} goto :HELP
goto :START

:HELP
echo Usage: %~n0 directory-name
echo.
echo Empties the contents of the specified directory,
echo WITHOUT CONFIRMATION. USE EXTREME CAUTION!
goto :DONE

:START
pushd %1 || goto :DONE
rd /q /s . 2> NUL
popd

:DONE
endlocal

В pushdизменениях в каталог которого вы хотите удалить ребенок. Затем, когда rdпросит удалить текущий каталог и все вложенные каталоги, удаление вложенных каталогов завершается успешно, но удаление текущего каталога завершается неудачно - потому что мы в нем. Это приводит к ошибке, которая 2> NULглотает. (2 - поток ошибок).

Я просто собрал это воедино из того, что написал morty346:

set folder="C:\test"
IF EXIST "%folder%" (
    cd /d %folder%
    for /F "delims=" %%i in ('dir /b') do (rmdir "%%i" /s/q || del "%%i" /s/q)
)

Он добавляет быструю проверку того, что папка, определенная в переменной, существует первой, меняет каталог на папку и удаляет содержимое.

Вы можете сделать это, используя delи /Sфлаг (чтобы указать, что нужно извлекать все файлы из всех подкаталогов):

del /S C:\Path\to\directory\*

Команда RD также может быть использована. Рекурсивно тихо удалить без запроса:

@RD /S /Q %VAR_PATH%

Rmdir (rd)

set "DIR_TO_DELETE=your_path_to_the_folder"

IF EXIST %DIR_TO_DELETE% (
    FOR /D %%p IN ("%DIR_TO_DELETE%\*.*") DO rmdir "%%p" /S /Q
    del %DIR_TO_DELETE%\*.* /F /Q
)

Попробуйте следующее; меня устраивает.

У меня есть приложение, которое сбрасывает данные в мою папку «C: \ tmp», и следующее работает лучше всего для меня. Он даже не спрашивает Да или Нет, чтобы удалить данные. Я составил график запуска через каждые 5 минут

cd "C:\tmp"

del *.* /Q

А еще лучше, скажем, я хочу удалить все в C:\windows\tempпапке.

@echo off
rd C:\windows\temp /s /q

Вы можете использовать robocopy для зеркалирования пустой папки в папку, которую вы очищаете.

robocopy "C:\temp\empty" "C:\temp\target" /E /MIR

Это также работает, если вы не можете удалить или воссоздать фактическую папку.

Требуется существующий пустой каталог.

использование

set dir="Your Folder Path Here"
rmdir /s %dir%
mkdir %dir%

Эта версия удаляется без запроса:

set dir="Your Folder Here"
rmdir /s /q %dir%
mkdir %dir%

Пример:

set dir="C:\foo1\foo\foo\foo3"
rmdir /s /q %dir%
mkdir %dir%

Это будет ясно C:\foo1\foo\foo\foo3.

_{(Я хотел бы упомянуть ответ Абдуллы Сабуина . Я перепутал его с копией . Я не заметил его пост. Я хотел бы поблагодарить вас, Мельпомена, за указание на ошибки!)}

Вы не можете удалить все с одним rmdirили delодним:

• rmdir /s /qне принимает групповые параметры. Так rmdir /s /q *будет ошибка.
• del /s /f /q удалит все файлы, но пустые подкаталоги останутся.

Мое предпочтительное решение (как я использовал во многих других пакетных файлах):

rmdir /s /q . 2>NUL

Просто измененная версия ответа ГрегМ :

set folder="C:\test"
cd /D %folder%
if NOT %errorlevel% == 0 (exit /b 1)
echo Entire content of %cd% will be deleted. Press Ctrl-C to abort
pause

REM First the directories /ad option of dir
for /F "delims=" %%i in ('dir /b /ad') do (echo rmdir "%%i" /s/q)

REM Now the files /a-d option of dir
for /F "delims=" %%i in ('dir /b /a-d') do (echo del "%%i" /q)

REM To deactivate simulation mode remove the word 'echo' before 'rmdir' and 'del'.

@echo off
@color 0A

echo Deleting logs

rmdir /S/Q c:\log\

ping 1.1.1.1 -n 5 -w 1000 > nul

echo Adding log folder back

md c:\log\

Вы были на правильном пути. Просто добавьте код, чтобы добавить папку, которая будет удалена снова.

Вы должны выполнить эту команду, чтобы удалить все файлы:

del*.*