Глобальное переопределение привязки клавиш в Emacs

Как я могу установить привязку ключа, которая глобально переопределяет и имеет приоритет над всеми другими привязками для этого ключа? Я хочу переопределить все карты основного / второстепенного режима и убедиться, что моя привязка всегда действует.

Это, конечно, не работает:

(global-set-key "\C-i" 'some-function)

Он работает text-mode, но когда я использую lisp-mode, C-iон восстанавливается lisp-indent-line.

Я могу пройти и переопределить эту привязку в lisp-modeкаждом другом режиме индивидуально, но должен быть более простой способ. Каждый раз, когда я устанавливаю новый режим для нового типа файла, мне приходилось возвращаться и проверять, не отменяются ли все мои привязки клавиш в новом режиме.

Я хочу сделать это, потому что хочу имитировать привязки, которые я уже изучил и усвоил у других редакторов.

Я использую второстепенный режим для всех своих привязок клавиш "override":

(defvar my-keys-minor-mode-map
  (let ((map (make-sparse-keymap)))
    (define-key map (kbd "C-i") 'some-function)
    map)
  "my-keys-minor-mode keymap.")

(define-minor-mode my-keys-minor-mode
  "A minor mode so that my key settings override annoying major modes."
  :init-value t
  :lighter " my-keys")

(my-keys-minor-mode 1)

Это дает дополнительное преимущество, заключающееся в возможности отключить все мои модификации одним махом (просто отключите второстепенный режим) в случае, если кто-то еще управляет клавиатурой или мне нужно увидеть, что делает привязка клавиш по умолчанию.

Обратите внимание, что вам может потребоваться отключить это в минибуфере:

(defun my-minibuffer-setup-hook ()
  (my-keys-minor-mode 0))

(add-hook 'minibuffer-setup-hook 'my-minibuffer-setup-hook)

В дополнение к ответу scottfrazer я написал следующее, чтобы мои привязки клавиш сохраняли приоритет, даже если впоследствии загруженные библиотеки вводят новые собственные таблицы клавиш.

Поскольку раскладки клавиатуры могут быть сгенерированы во время компиляции, loadмне показалось, что это лучшее место для этого.

(add-hook 'after-load-functions 'my-keys-have-priority)

(defun my-keys-have-priority (_file)
  "Try to ensure that my keybindings retain priority over other minor modes.

Called via the `after-load-functions' special hook."
  (unless (eq (caar minor-mode-map-alist) 'my-keys-minor-mode)
    (let ((mykeys (assq 'my-keys-minor-mode minor-mode-map-alist)))
      (assq-delete-all 'my-keys-minor-mode minor-mode-map-alist)
      (add-to-list 'minor-mode-map-alist mykeys))))

Установите use-package, оцените, и все готово:

(require 'bind-key)
(bind-key* "C-i" 'some-function)

Я нашел этот вопрос при поиске «emacs undefine org mode keybindings», потому что я хотел отвязать существующее поведение Cc Cb, чтобы моя глобальная карта для скрытого буфера работала в организационном буфере.

Это оказалось для меня самым простым решением:

(add-hook 'org-mode-hook
      (lambda ()
        (local-unset-key (kbd "C-c C-b"))))

Хотя ответ Скоттфразера - это именно то, о чем вы просили, я упомяну для потомков другое решение.

Из руководства Emacs :

«Не определяйте букву Cc как ключ в программах на Лиспе. Последовательности, состоящие из Cc и буквы (верхнего или нижнего регистра), зарезервированы для пользователей; это единственные последовательности, зарезервированные для пользователей, поэтому не блокируйте их».

Если вы привязываете свои личные глобальные привязки к копии с буквой, тогда вы «должны» быть в безопасности. Однако это всего лишь соглашение, и любой режим все еще может переопределить ваши привязки.

Если вы хотите «всегда использовать привязки клавиш на карте, если я явно не переопределяю их для конкретной карты режимов» и предполагая, что вы используете подход Скоттфразье , вам нужно:

(defun locally-override (key cmd)
  (unless (local-variable-p 'my-keys-minor-mode-map)
    (set (make-variable-buffer-local 'my-keys-minor-mode-map)
         (make-sparse-keymap))
    (set-keymap-parent my-keys-minor-mode-map 
                       (default-value 'my-keys-minor-mode-map)))
  (define-key my-keys-minor-mode-map key cmd))

Так

(locally-override "\C-i" nil)

должен удалить привязку "\ Ci" только из второстепенного режима в текущем буфере. Предупреждение: это полностью непроверено, но похоже на правильный подход. Точка установки родителя, а не просто копирование глобального значения my-keys-minor-mode-map заключается в том, чтобы любые последующие изменения глобального значения автоматически отражались в локальном значении.

Я не думаю, что ты сможешь. Это примерно эквивалентно тому, что вы хотите определить глобальную переменную, которую нельзя скрыть с помощью объявлений локальных переменных в функциях. Сфера просто так не работает.

Однако может быть способ написать функцию elisp для просмотра списка режимов и переназначения ее для каждого отдельного пользователя.

Если вы действительно не хотите сделать это самостоятельно, вам следует проверить, не делал ли это кто-нибудь еще.

Для Emacs есть пакет, который дает вашим Windows-подобным сочетаниям клавиш. Вы сможете найти его через Google.