Dim wkbkdestination As Workbook
Dim destsheet As Worksheet

For Each ThisWorkSheet In wkbkorigin.Worksheets 
    'this throws subscript out of range if there is not a sheet in the destination 
    'workbook that has the same name as the current sheet in the origin workbook.
    Set destsheet = wkbkdestination.Worksheets(ThisWorkSheet.Name) 
Next

В основном я просматриваю все листы в исходной книге, а затем устанавливаю destsheetв целевой книге лист с тем же именем, что и повторяемый в настоящее время лист в исходной книге.

Как я могу проверить, существует ли этот лист? Что-то вроде:

If wkbkdestination.Worksheets(ThisWorkSheet.Name) Then 

Некоторым не нравится этот подход из-за «неуместного» использования обработки ошибок, но я думаю, что он считается приемлемым в VBA ... Альтернативный подход - зацикливать все листы, пока не найдете совпадение.

Function WorksheetExists(shtName As String, Optional wb As Workbook) As Boolean
    Dim sht As Worksheet

    If wb Is Nothing Then Set wb = ThisWorkbook
    On Error Resume Next
    Set sht = wb.Sheets(shtName)
    On Error GoTo 0
    WorksheetExists = Not sht Is Nothing
End Function

Если вас особенно интересуют только рабочие листы, вы можете использовать простой вызов Evaluate:

Function WorksheetExists(sName As String) As Boolean
    WorksheetExists = Evaluate("ISREF('" & sName & "'!A1)")
End Function

Для этого вам не нужна обработка ошибок. Все, что вам нужно сделать, это перебрать все рабочие листы и проверить, существует ли указанное имя:

For i = 1 To Worksheets.Count
    If Worksheets(i).Name = "MySheet" Then
        exists = True
    End If
Next i

If Not exists Then
    Worksheets.Add.Name = "MySheet"
End If

Поскольку проверка членов коллекции - это общая проблема, вот абстрактная версия ответа Тима:

Функция содержит (objCollection как объект, strName как String) как логическое
    Dim o as Object
    При ошибке Возобновить Далее
    установить o = objCollection (strName)
    Содержит = (Err.Number = 0)
    Err.Clear
 Конечная функция

Эта функция может быть использована с любой коллекцией как объект ( Shapes, Range, Names, Workbooksи т.д.).

Чтобы проверить наличие листа, используйте If Contains(Sheets, "SheetName") ...

Исправлено: Без обработки ошибок:

Function CheckIfSheetExists(SheetName As String) As Boolean
      CheckIfSheetExists = False
      For Each WS In Worksheets
        If SheetName = WS.name Then
          CheckIfSheetExists = True
          Exit Function
        End If
      Next WS
End Function

В случае , если кто -то хочет , чтобы избежать VBA и тест , если таблица существует чисто в формуле ячейки, можно с помощью ISREFи INDIRECTфункции:

=ISREF(INDIRECT("SheetName!A1"))

Это вернется, TRUEесли книга содержит лист с именем SheetNameи в FALSEпротивном случае.

Я написал это:

Function sheetExist(sSheet As String) As Boolean
On Error Resume Next
sheetExist = (ActiveWorkbook.Sheets(sSheet).Index > 0)
End Function

Мое решение очень похоже на Tims, но также работает в случае листов, отличных от рабочих листов - диаграмм

Public Function SheetExists(strSheetName As String, Optional wbWorkbook As Workbook) As Boolean
    If wbWorkbook Is Nothing Then Set wbWorkbook = ActiveWorkbook 'or ThisWorkbook - whichever appropriate
    Dim obj As Object
    On Error GoTo HandleError
    Set obj = wbWorkbook.Sheets(strSheetName)
    SheetExists = True
    Exit Function
HandleError:
    SheetExists = False
End Function

.

Поместите тест в функцию, и вы сможете повторно использовать его, и у вас будет лучшая читаемость кода.

НЕ используйте команду «Возобновить после ошибки», поскольку она может конфликтовать с другой частью вашего кода.

Sub DoesTheSheetExists()
    If SheetExist("SheetName") Then
        Debug.Print "The Sheet Exists"
    Else
        Debug.Print "The Sheet Does NOT Exists"
    End If
End Sub

Function SheetExist(strSheetName As String) As Boolean
    Dim i As Integer

    For i = 1 To Worksheets.Count
        If Worksheets(i).Name = strSheetName Then
            SheetExist = True
            Exit Function
        End If
    Next i
End Function

Спустя много лет, но мне просто нужно было это сделать, и мне не понравилось ни одно из опубликованных решений ... Так что я придумал одно, и все благодаря магии (жест радужной руки Губки Боба) "Evaluate ()"!

Evaluate("IsError(" & vSheetName & "!1:1)")

Возвращает ИСТИНА, если Лист НЕ существует; ЛОЖЬ, если лист ДЕЙСТВИТЕЛЬНО существует. Вы можете заменить любой диапазон на «1: 1», но я не советую использовать одну ячейку, потому что, если она содержит ошибку (например, # N / A), она вернет True.

Компактная wsExistsфункция _{^{( без обработки ошибок!)}}

Вот короткая и простая функция, которая не полагается на обработку ошибок, чтобы определить, существует ли рабочий лист ( и правильно объявлено, что оно работает в любой ситуации!)

Function wsExists(wsName As String) As Boolean
    Dim ws: For Each ws In Sheets
    wsExists = (wsName = ws.Name): If wsExists Then Exit Function
    Next ws
End Function

Пример использования:

В следующем примере добавляется новый рабочий лист с именем myNewSheet, если он еще не существует:

If Not wsExists("myNewSheet") Then Sheets.Add.Name = "myNewSheet"

Больше информации:

• MSDN: For Each… NextЗаявление (VBA)
• MSDN: ExitЗаявление (VBA)
• MSDN: операторы сравнения (VBA)

Почему бы просто не использовать небольшой цикл, чтобы определить, существует ли указанный лист? Скажем, если вы искали Рабочий лист с именем «Лист1» в текущей открытой книге.

Dim wb as Workbook
Dim ws as Worksheet

Set wb = ActiveWorkbook

For Each ws in wb.Worksheets

    if ws.Name = "Sheet1" then
        'Do something here
    End if

Next

Если вы поклонник WorksheetFunction.или работаете из неанглоязычной страны с неанглоязычным Excel, это хорошее решение, которое работает:

WorksheetFunction.IsErr(Evaluate("'" & wsName & "'!A1"))

Или в такой функции:

Function WorksheetExists(sName As String) As Boolean
    WorksheetExists = Not WorksheetFunction.IsErr(Evaluate("'" & sName & "'!A1"))
End Function

Public Function WorkSheetExists(ByVal strName As String) As Boolean
   On Error Resume Next
   WorkSheetExists = Not Worksheets(strName) Is Nothing
End Function

sub test_sheet()

 If Not WorkSheetExists("SheetName") Then
 MsgBox "Not available"
Else MsgBox "Available"
End If

End Sub

    For Each Sheet In Worksheets
    If UCase(Sheet.Name) = "TEMP" Then
    'Your Code when the match is True
        Application.DisplayAlerts = False
        Sheet.Delete
        Application.DisplayAlerts = True
    '-----------------------------------
    End If
Next Sheet

Измените "Данные" на любое имя листа, которое вы тестируете ...

On Error Resume Next 

Set DataSheet = Sheets("Data")

If DataSheet Is Nothing Then

     Sheets.Add(after:=ActiveSheet).Name = "Data"
     ''or whatever alternate code you want to execute''
End If

On Error GoTo 0

Без всяких сомнений, что указанная выше функция может работать, я только что получил следующий код, который работает очень хорошо:

Sub Sheet_exist ()
On Error Resume Next
If Sheets("" & Range("Sheet_Name") & "") Is Nothing Then
    MsgBox "doesnt exist"
Else
    MsgBox "exist"
End if
End sub

Примечание: Sheets_Nameздесь я прошу пользователя ввести имя, поэтому это может быть не то же самое для вас.

Я сделал еще одну вещь: удалил лист только в том случае, если он существует - чтобы не получить ошибку, если его нет:

Excel.DisplayAlerts = False 
Dim WS
For Each WS In Excel.Worksheets
    If WS.name = "Sheet2" Then
        Excel.sheets("Sheet2").Delete
        Exit For
    End If
Next
Excel.DisplayAlerts = True

Я придумал простой способ сделать это, но не создавал для него новую сабвуфер. Вместо этого я просто «проверил» подпрограмму, над которой работал. Предположим, что имя листа, которое мы ищем, - «Sheet_Exist», и мы просто хотим активировать его, если он найден:

Dim SheetCounter As Integer

SheetCounter = 1

Do Until Sheets(SheetCounter).Name = "Sheet_Exist" Or SheetCounter = Sheets.Count + 1
 SheetCounter = SheetCounter +1
Loop
If SheetCounter < Sheets.Count + 1 Then
 Sheets("Sheet_Exist").Activate
Else
 MsgBox("Worksheet ""Sheet_Exist"" was NOT found")
End If

Я также добавил всплывающее окно, когда лист не существует.

Я знаю, что это старый пост, но вот еще одно простое и быстрое решение.

Public Function worksheetExists(ByVal wb As Workbook, ByVal sheetNameStr As String) As Boolean

On Error Resume Next
worksheetExists = (wb.Worksheets(sheetNameStr).Name <> "")
Err.Clear: On Error GoTo 0

End Function

Коротко и чисто:

Function IsSheet(n$) As Boolean
    IsSheet = Not IsError(Evaluate(n & "!a1"))
End Function

На самом деле у меня был простой способ проверить, существует ли лист, а затем выполнить некоторую инструкцию:

В моем случае я хотел удалить лист, а затем воссоздать тот же лист с тем же именем, но код был прерван, если программа не смогла удалить лист, поскольку он уже был удален

Sub Foo ()

    Application.DisplayAlerts = False

    On Error GoTo instructions
    Sheets("NAME OF THE SHEET").Delete

    instructions:

    Sheets.Add After:=Sheets(Sheets.Count)
    ActiveSheet.Name = "NAME OF THE SHEET"

End Sub