Как получить выходные данные команды оболочки, выполненной с использованием в переменную из Jenkinsfile (groovy)?

У меня есть что-то подобное в Jenkinsfile (Groovy), и я хочу записать stdout и код выхода в переменную, чтобы позже использовать эту информацию.

sh "ls -l"

Как я могу это сделать, особенно если учесть, что вы не можете запустить какой-либо отличный код внутри Jenkinsfile?

Последняя версия shшага конвейера позволяет вам сделать следующее;

// Git committer email
GIT_COMMIT_EMAIL = sh (
    script: 'git --no-pager show -s --format=\'%ae\'',
    returnStdout: true
).trim()
echo "Git committer email: ${GIT_COMMIT_EMAIL}"

Другая особенность - returnStatusопция.

// Test commit message for flags
BUILD_FULL = sh (
    script: "git log -1 --pretty=%B | grep '\\[jenkins-full]'",
    returnStatus: true
) == 0
echo "Build full flag: ${BUILD_FULL}"

Эти параметры были добавлены на основе этой проблемы.

Смотрите официальную документацию для shкоманды.

Текущая версия конвейера изначально поддерживает returnStdoutи returnStatus, что позволяет получить вывод или статус из sh/ batsteps.

Пример:

def ret = sh(script: 'uname', returnStdout: true)
println ret

Официальная документация .

быстрый ответ таков:

sh "ls -l > commandResult"
result = readFile('commandResult').trim()

Я думаю, что существует запрос функции, чтобы можно было получить результат шага sh, но, насколько я знаю, в настоящее время нет другого варианта.

РЕДАКТИРОВАТЬ: JENKINS-26133

РЕДАКТИРОВАТЬ 2: Не совсем уверен, с какой версией, но шаги sh / bat теперь могут возвращать вывод std, просто:

def output = sh returnStdout: true, script: 'ls -l'

Если вы хотите получить стандартный вывод и знать, была ли команда выполнена успешно или нет, просто используйте returnStdout и оберните ее в обработчик исключений:

скриптовый конвейер

try {
    // Fails with non-zero exit if dir1 does not exist
    def dir1 = sh(script:'ls -la dir1', returnStdout:true).trim()
} catch (Exception ex) {
    println("Unable to read dir1: ${ex}")
}

вывод :

[Pipeline] sh
[Test-Pipeline] Running shell script
+ ls -la dir1
ls: cannot access dir1: No such file or directory
[Pipeline] echo
unable to read dir1: hudson.AbortException: script returned exit code 2

К сожалению, в hudson.AbortException отсутствует какой-либо полезный метод для получения этого статуса выхода, поэтому, если требуется фактическое значение, вам нужно разобрать его в сообщении (тьфу!)

В отличие от Javadoc, https://javadoc.jenkins-ci.org/hudson/AbortException.html сборка не завершается при обнаружении этого исключения. Это терпит неудачу, когда это не поймано!

Обновление: если вы также хотите получить вывод STDERR из команды оболочки, к сожалению, Jenkins не сможет должным образом поддерживать этот общий вариант использования. Билет на 2017 год JENKINS-44930 застрял в состоянии самоуверенного пинг-понга, пока не продвинулся в поиске решения - рассмотрите возможность добавления к нему своего положительного голоса.

Что касается решения сейчас , может быть несколько возможных подходов:

а) Перенаправить STDERR в STDOUT 2>&1 - но тогда вам придется проанализировать это из основного вывода, и вы не получите вывод, если команда не удалась - потому что вы находитесь в обработчике исключений.

б) перенаправить STDERR во временный файл (имя которого вы готовите ранее) 2>filename(но не забудьте впоследствии очистить файл) - т.е. основной код становится:

def stderrfile = 'stderr.out'
try {
    def dir1 = sh(script:"ls -la dir1 2>${stderrfile}", returnStdout:true).trim()
} catch (Exception ex) {
    def errmsg = readFile(stderrfile)
    println("Unable to read dir1: ${ex} - ${errmsg}")
}

c) Пойти другим путем, установить returnStatus=trueвместо этого, обойтись без обработчика исключений и всегда записывать вывод в файл, то есть:

def outfile = 'stdout.out'
def status = sh(script:"ls -la dir1 >${outfile} 2>&1", returnStatus:true)
def output = readFile(outfile).trim()
if (status == 0) {
    // output is directory listing from stdout
} else {
    // output is error message from stderr
}

Предостережение: приведенный выше код относится только к Unix / Linux - Windows требует совершенно других команд оболочки.

Это пример, который, я думаю, будет иметь смысл!

node('master'){
    stage('stage1'){
    def commit = sh (returnStdout: true, script: '''echo hi
    echo bye | grep -o "e"
    date
    echo lol''').split()


    echo "${commit[-1]} "

    }
}

Для тех, кому нужно использовать выходные данные в последующих командах оболочки, а не в groovy, можно сделать что-то вроде этого:

    stage('Show Files') {
        environment {
          MY_FILES = sh(script: 'cd mydir && ls -l', returnStdout: true)
        }
        steps {
          sh '''
            echo "$MY_FILES"
          '''
        }
    }

Я нашел примеры кода maven весьма полезными.

Самый простой способ - использовать этот способ

my_var=`echo 2` echo $my_var выход: 2

обратите внимание, что это не простая одинарная кавычка - обратная кавычка (`).