Как я могу выполнить поиск обратной строки в Excel без использования VBA?

У меня есть таблица Excel, содержащая список строк. Каждая строка состоит из нескольких слов, но количество слов в каждой строке отличается.

Используя встроенные функции Excel (без VBA), есть ли способ выделить последнее слово в каждой строке?

Примеры:

  Вы классифицированы как человек? -> человек?
Отрицательный, я эскимо мяса -> эскимо
                  Азиз! Свет! -> Свет!

Этот протестирован и работает (на основе оригинального поста Брэда):

=RIGHT(A1,LEN(A1)-FIND("|",SUBSTITUTE(A1," ","|",
     LEN(A1)-LEN(SUBSTITUTE(A1," ","")))))

Если ваши оригинальные строки могут содержать трубу "|" символ, затем замените оба вышеупомянутых с другим символом, который не появится в вашем источнике. (Я подозреваю, что оригинал Брэда был сломан, потому что непечатный символ был удален в переводе).

Бонус: как это работает (справа налево):

LEN(A1)-LEN(SUBSTITUTE(A1," ",""))- Количество пробелов в исходной строке
SUBSTITUTE(A1," ","|", ... )- Заменяет только последний пробел на |
FIND("|", ... )- Находит абсолютную позицию замененного |(это был последний пробел)
Right(A1,LEN(A1) - ... ))- Возвращает все символы после этого|

РЕДАКТИРОВАТЬ: для учета случая, когда исходный текст не содержит пробелов, добавьте следующее в начало формулы:

=IF(ISERROR(FIND(" ",A1)),A1, ... )

делая всю формулу сейчас:

=IF(ISERROR(FIND(" ",A1)),A1, RIGHT(A1,LEN(A1) - FIND("|",
    SUBSTITUTE(A1," ","|",LEN(A1)-LEN(SUBSTITUTE(A1," ",""))))))

Или вы можете использовать =IF(COUNTIF(A1,"* *")синтаксис другой версии.

Если исходная строка может содержать пробел в последней позиции, добавьте функцию обрезки при подсчете всех пробелов: Сделайте функцию следующей:

=IF(ISERROR(FIND(" ",B2)),B2, RIGHT(B2,LEN(B2) - FIND("|",
    SUBSTITUTE(B2," ","|",LEN(TRIM(B2))-LEN(SUBSTITUTE(B2," ",""))))))

Это техника, которую я использовал с большим успехом:

=TRIM(RIGHT(SUBSTITUTE(A1, " ", REPT(" ", 100)), 100))

Чтобы получить первое слово в строке, просто измените с ВПРАВО на ВЛЕВО

=TRIM(LEFT(SUBSTITUTE(A1, " ", REPT(" ", 100)), 100))

Также замените А1 на ячейку с текстом.

Более надежная версия ответа Джерри:

=TRIM(RIGHT(SUBSTITUTE(TRIM(A1), " ", REPT(" ", LEN(TRIM(A1)))), LEN(TRIM(A1))))

Это работает независимо от длины строки, начальных или конечных пробелов или чего-либо еще, и все еще довольно коротко и просто.

Я нашел это в Google, проверено в Excel 2003, и это работает для меня:

=IF(COUNTIF(A1,"* *"),RIGHT(A1,LEN(A1)-LOOKUP(LEN(A1),FIND(" ",A1,ROW(INDEX($A:$A,1,1):INDEX($A:$A,LEN(A1),1))))),A1)

[править] Мне не хватает представителя, чтобы комментировать, так что это, кажется, лучшее место ... Ответ BradC также не работает с конечными пробелами или пустыми ячейками ...
[2-е редактирование] на самом деле, он не работает для отдельные слова либо ...

=RIGHT(TRIM(A1),LEN(TRIM(A1))-FIND(CHAR(7),SUBSTITUTE(" "&TRIM(A1)," ",CHAR(7),
LEN(TRIM(A1))-LEN(SUBSTITUTE(" "&TRIM(A1)," ",""))+1))+1)

Это очень надежно - оно работает для предложений без пробелов, пробелов в начале / в конце, нескольких пробелов, пробелов в начале / в конце ... и я использовал char (7) для разделителя, а не вертикальную черту "|" на всякий случай, это желаемый текстовый элемент.

Это очень чистый и компактный, и работает хорошо.

{=RIGHT(A1,LEN(A1)-MAX(IF(MID(A1,ROW(1:999),1)=" ",ROW(1:999),0)))}

Это не ошибка ловушки ни для пробелов, ни для одного слова, но это легко добавить.

Изменить:
Это обрабатывает концевые пробелы, одиночное слово и сценарии пустых ячеек. Я не нашел способ сломать это.

{=RIGHT(TRIM(A1),LEN(TRIM(A1))-MAX(IF(MID(TRIM(A1),ROW($1:$999),1)=" ",ROW($1:$999),0)))}

=RIGHT(A1,LEN(A1)-FIND("`*`",SUBSTITUTE(A1," ","`*`",LEN(A1)-LEN(SUBSTITUTE(A1," ",""))))) 

Чтобы добавить к ответам Джерри и Джо, если вы хотите найти текст ДО последнего слова, которое вы можете использовать:

=TRIM(LEFT(SUBSTITUTE(TRIM(A1), " ", REPT(" ", LEN(TRIM(A1)))), LEN(SUBSTITUTE(TRIM(A1), " ", REPT(" ", LEN(TRIM(A1)))))-LEN(TRIM(A1))))

С «Моим маленьким котом» в А1 получилось бы «Мой маленький» (где Джо и Джерри дали бы «кот»

Точно так же, как Джерри и Джо выделяют последнее слово, оно просто получает все слева от этого (затем обрезает его обратно)

Представьте, что строка может быть полностью изменена. Тогда это действительно легко. Вместо того, чтобы работать над строкой:

"My little cat" (1)

ты работаешь с

"tac elttil yM" (2)

С помощью =LEFT(A1;FIND(" ";A1)-1)в A2 вы получаете "My"с (1) и "tac"с (2), который является обратным "cat", последнее слово в (1).

Есть несколько VBA, чтобы перевернуть строку. Я предпочитаю публичную функцию VBA ReverseString.

Установите выше, как описано. Затем с вашей строкой в ​​A1, например, "My little cat"и этой функцией в A2:

=ReverseString(LEFT(ReverseString(A1);IF(ISERROR(FIND(" ";A1));
  LEN(A1);(FIND(" ";ReverseString(A1))-1))))

вы увидите "cat"в A2.

Приведенный выше метод предполагает, что слова разделяются пробелами. Предложение IFотносится к ячейкам, содержащим отдельные слова = без пробелов в ячейке. Примечание: TRIMи CLEANоригинальная строка также полезны. В принципе, он переворачивает всю строку из A1 и просто находит первый пробел в перевернутой строке, которая находится рядом с последним (перевернутым) словом (т. Е. "tac "). LEFTвыбирает это слово, а другая перестановка строк восстанавливает первоначальный порядок слова ( " cat"). В -1конце FINDоператора удаляет пробел.

Идея заключается в том , что его легко извлечь первое (!) Слово в строке с LEFTи FINDING первого пробела. Однако для последнего (!) Слова RIGHTфункция является неправильным выбором, когда вы пытаетесь это сделать, потому что, к сожалению, в FIND нет флага для направления, в котором вы хотите проанализировать вашу строку.

Поэтому вся строка просто перевернута. LEFTи FINDработать как обычно, но извлеченная строка переворачивается. Но это не страшно, если вы знаете, как перевернуть строку. Первое ReverseStringутверждение в формуле делает эту работу.

=LEFT(A1,FIND(IF(
 ISERROR(
  FIND("_",A1)
 ),A1,RIGHT(A1,
  LEN(A1)-FIND("~",
   SUBSTITUTE(A1,"_","~",
    LEN(A1)-LEN(SUBSTITUTE(A1,"_",""))
   )
  )
 )
),A1,1)-2)

Скопируйте в столбец, выберите этот столбец и HOME> Редактирование> Найти и выбрать, Заменить:

Replace All,

После звездочки есть пробел.

Я перевел на PT-BR, так как мне это тоже нужно.

(Обратите внимание, что я изменил пространство на, \потому что мне нужно было имя файла только из строк пути.)

=SE(ÉERRO(PROCURAR("\",A1)),A1,DIREITA(A1,NÚM.CARACT(A1)-PROCURAR("|", SUBSTITUIR(A1,"\","|",NÚM.CARACT(A1)-NÚM.CARACT(SUBSTITUIR(A1,"\",""))))))

Другой способ добиться этого, как показано ниже

=IF(ISERROR(TRIM(MID(TRIM(D14),SEARCH("|",SUBSTITUTE(TRIM(D14)," ","|",LEN(TRIM(D14))-LEN(SUBSTITUTE(TRIM(D14)," ","")))),LEN(TRIM(D14))))),TRIM(D14),TRIM(MID(TRIM(D14),SEARCH("|",SUBSTITUTE(TRIM(D14)," ","|",LEN(TRIM(D14))-LEN(SUBSTITUTE(TRIM(D14)," ","")))),LEN(TRIM(D14)))))

У меня также была такая задача, и когда я закончил, используя вышеуказанный метод, у меня возник новый метод: почему бы вам не сделать это:

1. Переверните строку («string one» становится «eno gnirts»).
2. Используйте старый добрый Find (который жестко запрограммирован слева направо).
3. Переверните его в читаемую строку снова.

Как это звучит?