Inno Setup: как автоматически удалить предыдущую установленную версию?

Я использую Inno Setup для создания установщика.

Я хочу, чтобы установщик автоматически удалил предыдущую установленную версию, а не перезаписал ее. Как я могу это сделать?

Вы должны иметь возможность прочитать строку удаления из реестра, учитывая AppId (т. Е. Значение, которое вы использовали AppIDв разделе [Setup]). Его можно найти в Software\Microsoft\Windows\CurrentVersion\Uninstall\{AppId}\(может быть либо HKLMили HKCU, поэтому лучше проверить оба), где {AppId}следует заменить фактическим значением, которое вы использовали. Найдите значения UninstallStringили QuietUninstallStringи используйте Execфункцию для его запуска из InitializeSetup()функции события.

Обновление: удалено неработающее альтернативное решение с использованием [Run]записи -section с {uninstallexe}- спасибо всем комментаторам, указавшим на это!

Я использовал следующее. Я не уверен, что это самый простой способ, но он работает.

Это использует, {#emit SetupSetting("AppId")}который полагается на препроцессор Inno Setup. Если вы не используете его, скопируйте и вставьте свой идентификатор приложения напрямую.

[Code]

{ ///////////////////////////////////////////////////////////////////// }
function GetUninstallString(): String;
var
  sUnInstPath: String;
  sUnInstallString: String;
begin
  sUnInstPath := ExpandConstant('Software\Microsoft\Windows\CurrentVersion\Uninstall\{#emit SetupSetting("AppId")}_is1');
  sUnInstallString := '';
  if not RegQueryStringValue(HKLM, sUnInstPath, 'UninstallString', sUnInstallString) then
    RegQueryStringValue(HKCU, sUnInstPath, 'UninstallString', sUnInstallString);
  Result := sUnInstallString;
end;


{ ///////////////////////////////////////////////////////////////////// }
function IsUpgrade(): Boolean;
begin
  Result := (GetUninstallString() <> '');
end;


{ ///////////////////////////////////////////////////////////////////// }
function UnInstallOldVersion(): Integer;
var
  sUnInstallString: String;
  iResultCode: Integer;
begin
{ Return Values: }
{ 1 - uninstall string is empty }
{ 2 - error executing the UnInstallString }
{ 3 - successfully executed the UnInstallString }

  { default return value }
  Result := 0;

  { get the uninstall string of the old app }
  sUnInstallString := GetUninstallString();
  if sUnInstallString <> '' then begin
    sUnInstallString := RemoveQuotes(sUnInstallString);
    if Exec(sUnInstallString, '/SILENT /NORESTART /SUPPRESSMSGBOXES','', SW_HIDE, ewWaitUntilTerminated, iResultCode) then
      Result := 3
    else
      Result := 2;
  end else
    Result := 1;
end;

{ ///////////////////////////////////////////////////////////////////// }
procedure CurStepChanged(CurStep: TSetupStep);
begin
  if (CurStep=ssInstall) then
  begin
    if (IsUpgrade()) then
    begin
      UnInstallOldVersion();
    end;
  end;
end;

Альтернативы

См. Также это сообщение в блоге «Пример сценария установки Inno для сравнения версий», в котором идет еще один шаг вперед, где читается номер версии любой ранее установленной версии и сравнивается этот номер с номером текущего установочного пакета.

Если вы «просто хотите удалить старые значки» (потому что ваши были изменены / обновлены), вы можете использовать это:

; attempt to remove previous versions' icons
[InstallDelete]
Type: filesandordirs; Name: {group}\*;

Это выполняется «в начале установки», поэтому в основном удаляются старые значки, а новые будут установлены там после того, как это будет полностью выполнено.

Я просто делаю это с каждой установкой значка «на случай, если что-то изменилось» (все равно все переустанавливается).

При использовании Inno Setup нет причин удалять предыдущую версию, если эта версия не была установлена ​​другой программой установки. В противном случае обновления выполняются автоматически.

Ответ Крейга Маккуина вполне жизнеспособен. Хотя я бы добавил такие комментарии:

• {#emit SetupSetting("AppId")}Код не работает для меня, так что я просто добавить свой App ID.
• Я не хотел запускать свою программу удаления, потому что у меня есть файл конфигурации INI, хранящийся в папке AppData /, которая удаляется программой удаления, и я не хочу, чтобы он стирался при установке новой версии. Итак, я немного изменил код, предоставленный Крейгом Маккуином, чтобы удалить каталог, в котором установлена ​​программа, после получения пути к ней.

Итак, что касается кода Крейга Маккуина, изменения таковы:

• Получите InstallLocationключ вместо UninstallStringключа.
• Используйте DelTreeфункцию вместоExec(sUnInstallString, ...)

Для тех, кто использует GetUninstallString()предложенное выше для принудительного удаления внутри CurStepChanged()и имеет проблемы с кэшированием диска, см. Ниже соответствующее решение, которое на самом деле ждет некоторое время после удаления, чтобы удалить exe-файл программы удаления!

Проблема с кешированием диска с inno-setup?

Вы можете запустить деинсталлятор в разделе [код]. Вы должны выяснить, как получить путь к существующему деинсталлятору. Для простоты, когда я устанавливаю свои приложения, я добавляю значение строки реестра, которое указывает на папку, содержащую программу удаления, и просто запускаю программу удаления в обратном вызове InitializeWizard.

Имейте в виду, что все имена деинсталляторов установки Inno имеют форму uninsnnn.exe, вы должны учитывать это в своем коде.

Я отредактировал код @Crain Mc-Queen, я думаю, что этот код лучше, потому что его не нужно изменять в другом проекте:

[Code]
function GetNumber(var temp: String): Integer;
var
  part: String;
  pos1: Integer;
begin
  if Length(temp) = 0 then
  begin
    Result := -1;
    Exit;
  end;
    pos1 := Pos('.', temp);
    if (pos1 = 0) then
    begin
      Result := StrToInt(temp);
    temp := '';
    end
    else
    begin
    part := Copy(temp, 1, pos1 - 1);
      temp := Copy(temp, pos1 + 1, Length(temp));
      Result := StrToInt(part);
    end;
end;

function CompareInner(var temp1, temp2: String): Integer;
var
  num1, num2: Integer;
begin
    num1 := GetNumber(temp1);
  num2 := GetNumber(temp2);
  if (num1 = -1) or (num2 = -1) then
  begin
    Result := 0;
    Exit;
  end;
      if (num1 > num2) then
      begin
        Result := 1;
      end
      else if (num1 < num2) then
      begin
        Result := -1;
      end
      else
      begin
        Result := CompareInner(temp1, temp2);
      end;
end;

function CompareVersion(str1, str2: String): Integer;
var
  temp1, temp2: String;
begin
    temp1 := str1;
    temp2 := str2;
    Result := CompareInner(temp1, temp2);
end;

function InitializeSetup(): Boolean;
var
  oldVersion: String;
  uninstaller: String;
  ErrorCode: Integer;
  vCurID      :String;
  vCurAppName :String;
begin
  vCurID:= '{#SetupSetting("AppId")}';
  vCurAppName:= '{#SetupSetting("AppName")}';
  //remove first "{" of ID
  vCurID:= Copy(vCurID, 2, Length(vCurID) - 1);
  //
  if RegKeyExists(HKEY_LOCAL_MACHINE,
    'SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\' + vCurID + '_is1') then
  begin
    RegQueryStringValue(HKEY_LOCAL_MACHINE,
      'SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\' + vCurID + '_is1',
      'DisplayVersion', oldVersion);
    if (CompareVersion(oldVersion, '{#SetupSetting("AppVersion")}') < 0) then      
    begin
      if MsgBox('Version ' + oldVersion + ' of ' + vCurAppName + ' is already installed. Continue to use this old version?',
        mbConfirmation, MB_YESNO) = IDYES then
      begin
        Result := False;
      end
      else
      begin
          RegQueryStringValue(HKEY_LOCAL_MACHINE,
            'SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\' + vCurID + '_is1',
            'UninstallString', uninstaller);
          ShellExec('runas', uninstaller, '/SILENT', '', SW_HIDE, ewWaitUntilTerminated, ErrorCode);
          Result := True;
      end;
    end
    else
    begin
      MsgBox('Version ' + oldVersion + ' of ' + vCurAppName + ' is already installed. This installer will exit.',
        mbInformation, MB_OK);
      Result := False;
    end;
  end
  else
  begin
    Result := True;
  end;
end;

Я, должно быть, что-то упускаю. Эти новые файлы копируются в каталог назначения до появления удаления старой установки. Затем деинсталлятор удаляет их и удаляет каталог.

Не используйте раздел [Run], а [UninstallRun]. Фактически, программы из раздела [Выполнить] выполняются после установки, что приводит к удалению вашей программы сразу после установки: - | Вместо этого перед установкой проверяется раздел [UninstallRun] .

Перейдите по этой ссылке: http://news.jrsoftware.org/news/innosetup/msg55323.html

В функции InitializeSetup () вы можете вызвать "MSIEXEC / x {идентификатор вашей программы}" после того, как пользователь предложит удалить старую версию.