cmake и libpthread

188

Я бегу RHEL 5.1и использую gcc.

Как мне сказать cmakeдобавить -pthreadв компиляцию и линковку?

pthreads cmake dimba
источник
1
Можете ли вы выбрать ответ для этого?
Джаред Берроуз,
1
Чувак, ты должен выбрать @ Мануэля в качестве ответа.
@ Ehsan Thehouse ответ лучше! :-)
Ela782

Ответы:

208

@ Мануэль был частью пути. Вы также можете добавить опцию компилятора, например так:

Если у вас CMake 3.1.0+, это станет еще проще :

set(THREADS_PREFER_PTHREAD_FLAG ON)
find_package(Threads REQUIRED)
target_link_libraries(my_app PRIVATE Threads::Threads)

Если вы используете CMake 2.8.12+, вы можете упростить это до:

find_package(Threads REQUIRED)
if(THREADS_HAVE_PTHREAD_ARG)
  target_compile_options(my_app PUBLIC "-pthread")
endif()
if(CMAKE_THREAD_LIBS_INIT)
  target_link_libraries(my_app "${CMAKE_THREAD_LIBS_INIT}")
endif()

Старые версии CMake могут потребовать:

find_package(Threads REQUIRED)
if(THREADS_HAVE_PTHREAD_ARG)
  set_property(TARGET my_app PROPERTY COMPILE_OPTIONS "-pthread")
  set_property(TARGET my_app PROPERTY INTERFACE_COMPILE_OPTIONS "-pthread")
endif()
if(CMAKE_THREAD_LIBS_INIT)
  target_link_libraries(my_app "${CMAKE_THREAD_LIBS_INIT}")
endif()

Если вы хотите использовать один из первых двух методов с CMake 3.1+, он вам тоже понадобится set(THREADS_PREFER_PTHREAD_FLAG ON).

дом
источник
Похоже, например, что CMake 3.0.2 не установит THREADS_HAVE_PTHREAD_ARG, если будет найдена библиотека pthread ( NOT CMAKE_HAVE_THREADS_LIBRARY), например, в Ubuntu 15.04 :(
mlt
1
Версия для CMake 2.8.12+ не будет работать должным образом из-за того, как работает код /usr/share/cmake-2.8/Modules/FindThreads.cmake(например, см. Здесь apt-browse.org/browse/ubuntu/trusty/main/all/cmake-data/… ) в основном, THREADS_HAVE_PTHREAD_ARGустановлено , только если другие варианты флага не были найдены (то есть. -lpthread, -lpthreadили -lthread)
j1elo
Это приводит к ошибке «Невозможно указать библиотеки ссылок для целевого« my_app », которое не создано этим проектом». - как вы включаете это универсально, не делая это индивидуально для каждой цели?
Крис Додд
Первый по-прежнему самый простой способ в 2020 / cmake 3.17?
Джей
Что произойдет, если вы не установите флаг THREADS_PREFER_PTHREAD_FLAG, просто найдите и создадите ссылку?
Джей
199

Следующее должно быть чистым (использующим find_package) и работать (модуль find называется FindThreads):

cmake_minimum_required (VERSION 2.6) 
find_package (Threads)
add_executable (myapp main.cpp ...)
target_link_libraries (myapp ${CMAKE_THREAD_LIBS_INIT})
Manuel
источник
2
Это не работает при использовании только в проекте CXX. Кто-нибудь знает хороший обходной путь?
Симон
1
@ Симон немного опоздал, но, пожалуйста, смотрите это: stackoverflow.com/questions/15193785/…
congusbongus
@CongXu Спасибо! Хорошо знать!
Симон
1
Это решение работает на Mac OS X, Centos 6 и Solaris 10.
bernardn
1
Обратите внимание, что здесь не будет установлен флаг компилятора
-pthread
26

Вот правильный ответ:

ADD_EXECUTABLE(your_executable ${source_files})

TARGET_LINK_LIBRARIES( your_executable
pthread
)

эквивалентно 

-lpthread
Надир СУАЛЕМ
источник
Это эквивалентно. «-pthread» жертвует гораздо больше - при компиляции это -D_REENTRANT, во время ссылки -lpthread. В некоторых системах даже может быть больше, чем это.
Димба
2
SET (CMAKE_CXX_FLAGS_DEBUG "... -lpthread") SET (CMAKE_CXX_FLAGS_RELEASE "... -lpthread")
Надир СУАЛЕМ
21
Это решение будет работать, как только вы перейдете с Linux на FreeBSD или Windows.
Алекс
4
Не работает, "target_link_libraries (your_executable pthread)" это то, как это должно быть написано.
Overv
6
Это не правильный ответ ни в коем случае. Даже если вам не нравится ответ The House, и, учитывая, что он был написан в 2009 году, он полностью не кросс-платформенный. Используйте ответ thehouse - и если вам это не нравится, тогда выбирайте что-то подобное, target_link_libraries(target "$<$<CXX_COMPILER_ID:GNU>:-pthread>$<$<CXX_COMPILER_ID:Clang>:-pthreads>")которое, по крайней мере, основано на цели и не терпит неудачу на Windows и других платформах.
Ela782