Прокрутите каждую строку диапазона в Excel

117

Это одна из тех вещей, для которых, я уверен, есть встроенная функция (и, возможно, мне уже говорили об этом в прошлом), но я ломаю голову, чтобы вспомнить об этом.

Как пройти через каждую строку многоколоночного диапазона с помощью Excel VBA? Все учебники, которые я искал, похоже, упоминают только работу с одномерным диапазоном ...

excel vba loops excel-2003 Маргарет
источник
codevba.com/excel/for_each_cell_in_range.htm#.Xyd8qCgzaUk
Фрэнк Мьят Чт,

Ответы:

151 
Dim a As Range, b As Range

Set a = Selection

For Each b In a.Rows
    MsgBox b.Address
Next
Майк
источник
149

Что-то вроде этого:

Dim rng As Range
Dim row As Range
Dim cell As Range

Set rng = Range("A1:C2")

For Each row In rng.Rows
  For Each cell in row.Cells
    'Do Something
  Next cell
Next row
Дэвид Андрес
источник
8

Просто наткнулся на это и подумал, что предлагаю свое решение. Обычно мне нравится использовать встроенную функциональность по назначению диапазона многомерному массиву (я думаю, что это также JS Programmer во мне).

Я часто пишу такой код:

Sub arrayBuilder()

myarray = Range("A1:D4")

'unlike most VBA Arrays, this array doesn't need to be declared and will be automatically dimensioned

For i = 1 To UBound(myarray)

    For j = 1 To UBound(myarray, 2)

    Debug.Print (myarray(i, j))

    Next j

Next i

End Sub

Назначение диапазонов переменным - очень мощный способ манипулировать данными в VBA.

tc_NYC
источник
мне этот способ нравится больше всего!
athos
2
Два основных преимущества в пользу его: 1) метод массива всегда быстрее , чем цикл через ряд, 2) это просто»s , и вы можете использовать его в обоих направлениях и записать обратно массив после некоторых вычислений: Range("A1:D4") = myarray. Примечание: Dim myarray как вариант; Обратите внимание, что по умолчанию это массив 2dim на основе 1
TM
7

В циклах я всегда предпочитаю использовать Cellsкласс, используя ссылочный метод R1C1, например:

Cells(rr, col).Formula = ...

Это позволяет мне быстро и легко петлю над Диапазон ячеек легко:

Dim r As Long
Dim c As Long

c = GetTargetColumn() ' Or you could just set this manually, like: c = 1

With Sheet1 ' <-- You should always qualify a range with a sheet!

    For r = 1 To 10 ' Or 1 To (Ubound(MyListOfStuff) + 1)

        ' Here we're looping over all the cells in rows 1 to 10, in Column "c"
        .Cells(r, c).Value = MyListOfStuff(r)

        '---- or ----

        '...to easily copy from one place to another (even with an offset of rows and columns)
        .Cells(r, c).Value = Sheet2.Cells(r + 3, 17).Value


    Next r

End With
LimaNightHawk
источник