Как выполнить сглаживание линий SIA ​​или Безье в PostGIS?

Может ли кто-нибудь предоставить пример SQL для сглаживания линейных строк из таблицы Постгиса с использованием кривых Безье или алгоритма итеративного усреднения ( SIA )?

Я создал небольшой наивный скрипт, который на основе некоторой эвристики преобразует входные строки LineStrings в CompoundCurves.

Что оно делает:

• Обрезает острые углы, чтобы создать визуально более привлекательные результаты, чем исходные данные.
• Использует plpgsql. Никаких дополнительных расширений не требуется.
• Принимает необязательный «коэффициент сглаживания» между 0 и 100 помимо геометрии.

Что он не делает:

• Обрабатывает MultiLineStrings. Для любого другого типа геометрии он просто возвращает входные данные.
• Использует значения Z и М. Это просто отбрасывает их. Используйте это только для 2D картографических целей.
• Создает математически правильные результаты. Результаты далеки от правильных и в некоторых случаях могут даже быть визуально неэстетичными (например, острые углы). Я не проверял это полностью. Всегда просматривайте результаты!
• Работает быстро. Я уверен, что это может быть переписано в гораздо более оптимальную форму.
• Делает реальное сглаживание. Есть намного лучшие алгоритмы (например, Chaiken или упомянутые в вопросе), которые можно использовать для реального сглаживания. Этот ответ нацелен на людей, подобных мне, в поисках чистого подхода PostGIS, автоматически создающего некие изогнутые линии из реальных данных.

Сценарий:

CREATE OR REPLACE FUNCTION CreateCurve(geom geometry, percent int DEFAULT 40)
    RETURNS geometry AS
$$
DECLARE
    result text;
    p0 geometry;
    p1 geometry;
    p2 geometry;
    intp geometry;
    tempp geometry;
    geomtype text := ST_GeometryType(geom);
    factor double precision := percent::double precision / 200;
    i integer;
BEGIN
    IF percent < 0 OR percent > 100 THEN
        RAISE EXCEPTION 'Smoothing factor must be between 0 and 100';
    END IF;
    IF geomtype != 'ST_LineString' OR factor = 0 THEN
        RETURN geom;
    END IF;
    result := 'COMPOUNDCURVE((';
    p0 := ST_PointN(geom, 1);
    IF ST_NPoints(geom) = 2 THEN
        p1:= ST_PointN(geom, 2);
        result := result || ST_X(p0) || ' ' || ST_Y(p0) || ',' || ST_X(p1) || ' ' || ST_Y(p1) || '))';
    ELSE
        FOR i IN 2..(ST_NPoints(geom) - 1) LOOP
            p1 := ST_PointN(geom, i);
            p2 := ST_PointN(geom, i + 1);
            result := result || ST_X(p0) || ' ' || ST_Y(p0) || ',';
            tempp := ST_Line_Interpolate_Point(ST_MakeLine(p1, p0), factor);
            p0 := ST_Line_Interpolate_Point(ST_MakeLine(p1, p2), factor);
            intp := ST_Line_Interpolate_Point(
                ST_MakeLine(
                    ST_Line_Interpolate_Point(ST_MakeLine(p0, p1), 0.5),
                    ST_Line_Interpolate_Point(ST_MakeLine(tempp, p1), 0.5)
                ), 0.5);
            result := result || ST_X(tempp) || ' ' || ST_Y(tempp) || '),CIRCULARSTRING(' || ST_X(tempp) || ' ' || ST_Y(tempp) || ',' || ST_X(intp) || ' ' ||
            ST_Y(intp) || ',' || ST_X(p0) || ' ' || ST_Y(p0) || '),(';
        END LOOP;
        result := result || ST_X(p0) || ' ' || ST_Y(p0) || ',' || ST_X(p2) || ' ' || ST_Y(p2) || '))';
    END IF;
    RETURN ST_SetSRID(result::geometry, ST_SRID(geom));
END;
$$
LANGUAGE 'plpgsql' IMMUTABLE;

Поскольку он возвращает кривые в геометрическом типе, если вы хотите использовать его в ГИС, такой как QGIS, вы должны обернуть его в функции PostGIS, преобразовав их вокруг. Предполагаемый синтаксис использования:

SELECT ST_AsText(ST_CurveToLine(CreateCurve(geom))) AS geom FROM linestringtable;

Эта проблема все еще остается открытой в PostGIS (и других инструментах ГИС), как указано в книге «PostGIS in Action» в главе 2.2.6 «Кривые геометрии».

Вот некоторые ссылки на алгоритмы и код:

• http://www.codeproject.com/Articles/31859/Draw-a-Smooth-Curve-through-a-Set-of-2D-Points-wit
• http://www.antigrain.com/research/bezier_interpolation/index.html (также используется функцией LineSmoother в JTS!)
• http://www.java2v.com/Code/Java/2D-Graphics-GUI/Interpolatesgivenpointsbyabeziercurve.htm
• http://www.ibiblio.org/e-notes/Splines/Bezier.java

Вы можете попытаться преобразовать свои линии линий в кривые с помощью ST_LineToCurve, а затем вернуться к строкам линий с помощью ST_CurveToLine .

Вы можете установить желаемое количество сегментов на четверть круга в ST_CurveToLine.