Есть ли яснипет, производящий предзаполненный комментарий о кислороде?

10

Для следующей функции C ++:

bool importantStuff(double a, double b);

Он должен вывести следующий фрагмент, возможно, без тегов:

/**
 * <Insert description of importantStuff>
 *
 * @param a <Insert description of a>
 * @param b <Insert description of b>
 * @return <Insert description of the return value>
 */

Я осмотрел сеть, но ближе всего я получил ответ на этот старый вопрос SO, ответ на который зависит от не поддерживаемого режима doxymacs.

yasnippet c++ Rovanion
источник
Я думаю, c-sharp-modeесть кое-что, что делает это.
erikstokes
Вы хотите сделать это для новых или существующих функций?
свой день
Задавая вопрос, я думал о том, что из подписи функции генерируется комментарий о кислороде.
Рованион

Ответы:

4

Я использую следующее, которое представляет собой гибрид стандартного документа на основе doxymacs и семантического, основанного на abo-abo, уже упоминавшегося в качестве ответа - это требует только семантики и yasnippet. Это заранее заполняет еще несколько заполнителей yasnippet соответствующей информацией, а также версией abo-abo.


# -*- mode: snippet -*-
# name: dox
# key: dox
# type: command
# --
(unless (and (fboundp 'semantic-current-tag)
             semantic-mode)
  (error "Semantic required to use dox snippet"))
(let ((tag (senator-next-tag)))
  (while (or (null tag)
             (not (semantic-tag-of-class-p tag 'function)))
    (setq tag (senator-next-tag)))
  (let* ((name (semantic-tag-name tag))
         (attrs (semantic-tag-attributes tag))
         (args (plist-get attrs :arguments))
         (return-name (plist-get attrs :type))
         (idx 1))
    (if (listp return-name)
      (setq return-name (car return-name)))
    (yas/expand-snippet
     (format
      "/**
* @brief ${1:%s}
*
%s
%s*/
"
      name
      (mapconcat
       (lambda (x)
         (format "* @param %s ${%d:Description of %s}"
                 (car x) (incf idx) (car x)))
       args
       "\n")
      (if (and return-name (not (string-equal "void" return-name)))
          (format " * @return ${%d:%s}\n" (incf idx) return-name)
        "")))))
alexmurray
источник
Это решение абсолютно работает, но ждать семантического режима, чтобы пройти через весь необходимый код, немного громоздко. У меня также было emacs, застрявший в бесконечных циклах, если вместо этого я написал dox <tab> перед переменной. Но не может быть всего в этом мире: D
Рованион
за это должно быть проголосовано выше, чем выше, так как оно более богато, чем moo-doxygen
Алехандро Эриксон
3

Просто добавил эту функцию в аргументы функции .

Вот код, если вам интересно. Это использует CEDET:

(defun moo-doxygen ()
  "Generate a doxygen yasnippet and expand it with `aya-expand'.
The point should be on the top-level function name."
  (interactive)
  (move-beginning-of-line nil)
  (let ((tag (semantic-current-tag)))
    (unless (semantic-tag-of-class-p tag 'function)
      (error "Expected function, got %S" tag))
    (let* ((name (semantic-tag-name tag))
           (attrs (semantic-tag-attributes tag))
           (args (plist-get attrs :arguments))
           (ord 1))
      (setq aya-current
            (format
             "/**
* $1
*
%s
* @return $%d
*/
"
             (mapconcat
              (lambda (x)
                (format "* @param %s $%d"
                        (car x) (incf ord)))
              args
              "\n")
             (incf ord)))
      (aya-expand))))

Вам также нужен авто-ясниппет . Оба пакета доступны в MELPA.

Або-або
источник