Способ скрытия разделителей блоков SRC

13

Есть ли способ сохранить только исходный код внутри исходного кода, то есть сделать # + BEGIN_SRC и # + END_SRC невидимыми? Это косметика, но она проясняет ситуацию, когда приходится иметь дело со множеством коротких фрагментов кода. Например:

(defun org-xor (a b)
          "Exclusive or."
          (if a (not b) b))

вместо :

  #+BEGIN_SRC emacs-lisp
       (defun org-xor (a b)
          "Exclusive or."
          (if a (not b) b))
  #+END_SRC

org-mode loukios
источник

Мой комментарий под вопросом в этой полу-связанной теме показывает, как программно скрыть верхние / нижние колонтитулы исходного блока. emacs.stackexchange.com/q/26163/2287 - т.е.

(save-excursion (goto-char (point-max)) (while (re-search-backward "#\\+BEGIN_SRC\\|#\\+END_SRC" nil t) (let ((ov (make-overlay (line-beginning-position) (1+ (line-end-position))))) (overlay-put ov 'invisible t))))

чтобы показать все, используйте (remove-overlays). Дальнейшая работа должна быть сделана для отдельных записей, и удаление только отдельных наложений (вместо всех наложений), но это общая идея.

юрист

Спасибо, это интересно ... Я поиграю с этим.

Лукиос

5

Лицо для всех строк, начинающихся с #+, называется org-meta-line.

Вы можете настроить это лицо меньше, темнее и т. Д., Чтобы сделать его менее заметным.

Juancho
источник

Действительно. В качестве примера, я настроил его с помощью (set-face-attribute 'org-meta-line nil :height 0.8 :slant 'normal). Я считаю, что это очень помогает.

Харальд Ханче-Олсен

Спасибо за ваш ответ, это помогает. Я изменил высоту, кстати, но это не имеет никакого эффекта ...

loukios

Смотрите эту документацию Emacs Lisp на опции , которые можно назначить org-meta-line gnu.org/software/emacs/manual/html_node/elisp/...

salotz

4

Я использую следующий кусок кода, который идет некоторым путем. Это не идеально. Может быть, это когда-нибудь станет правильным minor-mode. ( источник ).

(with-eval-after-load 'org
  (defvar-local rasmus/org-at-src-begin -1
    "Variable that holds whether last position was a ")

  (defvar rasmus/ob-header-symbol ?☰
    "Symbol used for babel headers")

  (defun rasmus/org-prettify-src--update ()
    (let ((case-fold-search t)
          (re "^[ \t]*#\\+begin_src[ \t]+[^ \f\t\n\r\v]+[ \t]*")
          found)
      (save-excursion
        (goto-char (point-min))
        (while (re-search-forward re nil t)
          (goto-char (match-end 0))
          (let ((args (org-trim
                       (buffer-substring-no-properties (point)
                                                       (line-end-position)))))
            (when (org-string-nw-p args)
              (let ((new-cell (cons args rasmus/ob-header-symbol)))
                (cl-pushnew new-cell prettify-symbols-alist :test #'equal)
                (cl-pushnew new-cell found :test #'equal)))))
        (setq prettify-symbols-alist
              (cl-set-difference prettify-symbols-alist
                                 (cl-set-difference
                                  (cl-remove-if-not
                                   (lambda (elm)
                                     (eq (cdr elm) rasmus/ob-header-symbol))
                                   prettify-symbols-alist)
                                  found :test #'equal)))
        ;; Clean up old font-lock-keywords.
        (font-lock-remove-keywords nil prettify-symbols--keywords)
        (setq prettify-symbols--keywords (prettify-symbols--make-keywords))
        (font-lock-add-keywords nil prettify-symbols--keywords)
        (while (re-search-forward re nil t)
          (font-lock-flush (line-beginning-position) (line-end-position))))))

  (defun rasmus/org-prettify-src ()
    "Hide src options via `prettify-symbols-mode'.

  `prettify-symbols-mode' is used because it has uncollpasing. It's
  may not be efficient."
    (let* ((case-fold-search t)
           (at-src-block (save-excursion
                           (beginning-of-line)
                           (looking-at "^[ \t]*#\\+begin_src[ \t]+[^ \f\t\n\r\v]+[ \t]*"))))
      ;; Test if we moved out of a block.
      (when (or (and rasmus/org-at-src-begin
                     (not at-src-block))
                ;; File was just opened.
                (eq rasmus/org-at-src-begin -1))
        (rasmus/org-prettify-src--update))
      ;; Remove composition if at line; doesn't work properly.
      ;; (when at-src-block
      ;;   (with-silent-modifications
      ;;     (remove-text-properties (match-end 0)
      ;;                             (1+ (line-end-position))
      ;;                             '(composition))))
      (setq rasmus/org-at-src-begin at-src-block)))

  (defun rasmus/org-prettify-symbols ()
    (mapc (apply-partially 'add-to-list 'prettify-symbols-alist)
          (cl-reduce 'append
                     (mapcar (lambda (x) (list x (cons (upcase (car x)) (cdr x))))
                             `(("#+begin_src" . ?✎) ;; ➤ 🖝 ➟ ➤ ✎
                               ("#+end_src"   . ?□) ;; ⏹
                               ("#+header:" . ,rasmus/ob-header-symbol)
                               ("#+begin_quote" . ?»)
                               ("#+end_quote" . ?«)))))
    (turn-on-prettify-symbols-mode)
    (add-hook 'post-command-hook 'rasmus/org-prettify-src t t))
  (add-hook 'org-mode-hook #'rasmus/org-prettify-symbols))

Расмус
источник

Способ скрытия разделителей блоков SRC

Ответы: