Как рекурсивно искать / grep содержимое файла в каталоге / подкаталогах в Emacs?

Я использую Emacs в течение достаточно долгого времени, и я до сих пор почему-то не могу понять, каков наилучший (рекурсивно) grep для строки в каталоге (проекта) и получения результатов, представленных в виде буфера с задержкой или в некоторых других полезный способ. Пожалуйста, просветите меня.

Ну, поскольку оригинальный вопрос не упоминается rgrep, я пойду дальше и укажу здесь. Это самый простой вариант, уже встроенный в Emacs, и я обнаружил, что его более чем достаточно для большинства вещей.

Из документации,

Recursively grep for REGEXP in FILES in directory tree rooted at DIR.

Поиск ограничен именами файлов, соответствующими шаблону оболочки FILES.

Так, например, чтобы найти все файлы питона под моей домашней директории для использования some_function, я бы назвал его some_function, *.py, в ~/качестве аргументов. Результаты отображаются в новом буфере.

Я с удовольствием пользуюсь M-x find-grep-diredгодами. Он возвращает результаты в виде буфера Dired, который вы можете использовать.

Решение 1 (лучшее решение):

Установить адвокат ( https://github.com/abo-abo/swiper/blob/master/counsel.el )

Потом M-x counsel-git-grep.

Никаких настроек не требуется (git знает корень проекта и файлы для исключения). И то, git grepи другое counselэффективно.

Проект должен управляться git.

адвокат требует режима плюща.

Решение 2:

Это решение использует grep и работает на любом проекте. Он уступает Solution 1, потому что он медленнее и требует ручной настройки. Он также основан на режиме плюща.

(defvar simple-project-root "~/.emacs.d")
(defun simple-grep ()
  (interactive)
  (unless (featurep 'ivy)
    (require 'ivy))
  (let* ((default-directory (file-name-as-directory simple-project-root))
         (keyword (read-string "Keyword:")))
    (ivy-read (format "Grep at %s:" simple-project-root)
              (split-string (shell-command-to-string (format "grep -rsnI %s ." keyword)) "\n" t)
              :action (lambda (val)
                        (let* ((lst (split-string val ":"))
                               (linenum (string-to-number (cadr lst))))
                          ;; open file
                          (find-file (car lst))
                          ;; goto line if line number exists
                          (when (and linenum (> linenum 0))
                            (goto-char (point-min))
                            (forward-line (1- linenum))))))))

Вам нужно создать .dir-locals.el для настройки simple-project-root, см. Https://www.gnu.org/software/emacs/manual/html_node/emacs/Directory-Variables.html для технических деталей.

Код в решении 2 - просто прототип. Моя реальная реализация намного сложнее. Смотрите counsel-etags-grepв https://github.com/redguardtoo/counsel-etags/blob/master/counsel-etags.el

Резюме:

Это два лучших решения, которые я знаю.

Если существуют какие-либо другие лучшие решения, они должны по крайней мере решить следующие проблемы, чтобы быть готовыми к производству,

• как получить ключевое слово для grep (например, получить ключевое слово из выбранного региона)

• избежать ключевого слова

• если существует более эффективная программа grep, мы должны использовать ее (ripgrep, the_silver_searcher / ag, ... и т. д.), либо использовать альтернативный вариант grep по умолчанию

• Окно кандидата должно использовать всю ширину экрана, и пользователи могут фильтровать кандидатов в интерактивном режиме (именно поэтому люди используют плющ или шлем)

• мы должны показать относительный путь в окне кандидата

• возможность повторно использовать предыдущий результат. Таким образом, предыдущий результат должен быть сохранен. Вы можете использовать ivy-resumeот ivyили helm-resumeотhelm

• Когда вы сохраняете предыдущий полученный результат, контекст предыдущего результата также должен быть сохранен. Например, в коде решения 2. default-directoryесть контекст. См. Https://github.com/abo-abo/swiper/issues/591 для получения дополнительной информации.

• Расширенное регулярное выражение следует использовать, потому что оно проще и уже используется counsel-git-grepthe_silver_searcher / ag.

Я хотел бы добавить еще одно решение к решению @chen bin, которое также использует counsel(но для этого вам не нужно поддерживать проект git).

Вам нужно установить ag (серебряный поисковик) и counselпредоставить команду, counsel-agкоторая ищет в текущем каталоге введенную строку.

Если вы хотите искать в проекте (а не только в текущем рабочем каталоге), добавьте это в .emacs:

  (defun rag/counsel-ag-project-at-point ()
    "use counsel ag to search for the word at point in the project"
    (interactive)
    (counsel-ag (thing-at-point 'symbol) (projectile-project-root)))

Эта функция будет использоваться agдля рекурсивного поиска в корневом каталоге проекта.

Редактировать : вышеупомянутая функция по умолчанию является символом в точке поиска. Если вам не нравится это поведение, замените (thing-at-point 'symbol)на nil. И если вы хотите результаты поиска в своем собственном буфере, нажмитеC-c C-o

Edit2 : если вы ripgrepустановили, вы можете заменить counsel-agс counsel-rgв приведенной выше функции , и это будет так же , как нормально :)

Вот пример пользовательской функции grep, которая рекурсивно подбирает содержимое файла (используя регулярное выражение для поискового запроса) в каталоге и его подкаталогах и отображает результаты со строками контекста до и после. Встроенные библиотеки compile.elи grep.elбиблиотеки предоставляют несколько методов для перехода к местоположению в файле, содержащем результаты поиска. Нет необходимости устанавливать что-либо еще, чтобы этот пример работал - все, что нужно, - это полная версия Emacs и компьютер с grepустановленной утилитой. Переменная grep-programможет быть скорректирована так, чтобы указывать на конкретное местоположение grepутилиты, если значение по умолчанию недостаточно.

(defun recursive-grep ()
"Recursively grep file contents.  `i` case insensitive; `n` print line number;
`I` ignore binary files; `E` extended regular expressions; `r` recursive"
(interactive)
  (let* ((search-term (read-string "regex:  "))
         (search-path
           (directory-file-name (expand-file-name (read-directory-name "directory:  "))))
         (default-directory (file-name-as-directory search-path))
         (grep-command
           (concat
             grep-program
             " "
             "-inIEr --color=always -C2"
             " "
             search-term
             " "
             search-path)))
    (compilation-start grep-command 'grep-mode (lambda (mode) "*grep*") nil)))