Расширение орг-режима с большим количеством наценок

Я хочу добавить разметку и форматирование для такой разметки, то есть <kbd>...</kbd>с рамкой окружает такую ​​разметку. Я также хочу, чтобы разметка была совместима с (setq org-hide-emphasis-markers t). То есть, когда переменная установлена t, то <kbd>и </kbd>метки должны исчезнуть, оставив текст между ним с указанным форматированием выше.

Ответ, размещенный в этом вопросе: как постоянно выделять текст в режиме org , не решает эту проблему, поскольку он применим только для существующих разметок, не расширяя Org новыми разметками.

Я сделал что-то подобное . Это по-французски, но код должен говорить сам за себя. Я использую ‰маркер (я использую макет bepo ), а когда я делаю, отмеченный текст как стиль нажатой кнопки.

Я не владею лиспом, поэтому может быть место для улучшения.

Что я сделал, так это то, что при использовании ‰для маркера отмеченный текст имеет стиль нажатой кнопки, а при экспорте он переводится в<kbd>

Сначала я должен был определить новое лицо:

(defface my-face-org-keystroke
  '((t (:inherit shadow 
        :box (:line-width -2 ;neg. in order to keep the same size of lines
              :color "grey75"
              :style pressed-button)))) "Face for keystrokes"
        :group 'org-faces)

Затем настройте org-emphasis-alist:

(("*" bold)
 ("/" italic)
 ("_" underline)
 ("=" org-code verbatim)
 ("~" org-verbatim verbatim)
 ("+"
  (:strike-through t))
 ("‰" my-face-org-keystroke verbatim));This line is what you want to add

Для экспорта, возможно , потребуется загрузить ox.elс (require 'ox).

Затем каждый раз boldили codeпоявляется в функции (в ox-org.el), я создал похожую функцию (или изменил существующие):

;creation
(defun org-html-keystroke (keystroke contents info)
  "Transcode KEYSTROKE from Org to HTML.
CONTENTS is nil.  INFO is a plist holding contextual
information."
  (format (or (cdr (assq 'my-object-keystroke org-html-text-markup-alist)) "%s")
          (org-html-encode-plain-text (org-element-property :value keystroke))))


;creation
(defun org-element-my-object-keystroke-parser ()
  "Parse code object at point.

Return a list whose CAR is `my-object-keystroke' and CDR is a plist with
`:value', `:begin', `:end' and `:post-blank' keywords.

Assume point is at the first tilde marker."
  (interactive)
  (save-excursion
    (unless (bolp) (backward-char 1))
    (looking-at org-emph-re)
    (let ((begin (match-beginning 2))
          (value (org-match-string-no-properties 4))
          (post-blank (progn (goto-char (match-end 2))
                             (skip-chars-forward " \t")))
          (end (point)))
      (list 'my-object-keystroke
            (list :value value
                  :begin begin
                  :end end
                  :post-blank post-blank)))))

;creation
(defun org-element-my-object-keystroke-interpreter (keystroke contents)
  "Interpret KEYSTROKE object as Org syntax.
CONTENTS is nil."
  (format "‰%s‰" (org-element-property :value keystroke)))


;modification
(defconst org-element-object-successor-alist
  '((subscript . sub/superscript) (superscript . sub/superscript)
    (bold . text-markup) (code . text-markup) (italic . text-markup)
    (strike-through . text-markup) (underline . text-markup)
    (verbatim . text-markup) (entity . latex-or-entity)
    (latex-fragment . latex-or-entity) (my-object-keystroke . text-markup))
  "Alist of translations between object type and successor name.
Sharing the same successor comes handy when, for example, the
regexp matching one object can also match the other object.")

;modification
(defconst org-element-all-objects
  '(bold code entity export-snippet footnote-reference inline-babel-call
         inline-src-block italic line-break latex-fragment link macro
         radio-target statistics-cookie strike-through subscript superscript
         table-cell target timestamp underline verbatim my-object-keystroke)
  "Complete list of object types.")


;modification
(defun org-element-text-markup-successor ()
  "Search for the next text-markup object.

Return value is a cons cell whose CAR is a symbol among `bold',
`italic', `underline', `strike-through', `code' and `verbatim'
and CDR is beginning position."
  (save-excursion
    (unless (bolp) (backward-char))
    (when (re-search-forward org-emph-re nil t)
      (let ((marker (match-string 3)))
        (cons (cond
               ((equal marker "*") 'bold)
               ((equal marker "/") 'italic)
               ((equal marker "_") 'underline)
               ((equal marker "+") 'strike-through)
               ((equal marker "~") 'code)
               ((equal marker "=") 'verbatim)
               ((equal marker "‰") 'my-object-keystroke) 
               (t (error "Unknown marker at %d" (match-beginning 3))))
              (match-beginning 2))))))

Далее я определил my-htmlбэкэнд для экспорта:

(org-export-define-derived-backend 'my-html 'html
  :translate-alist '((my-object-keystroke . org-html-keystroke))
  :menu-entry ' (?h 1
                    ((?r "my-html"  org-html-export-to-my-html))))

(defun org-html-export-to-my-html
  (&optional async subtreep visible-only body-only ext-plist)
  "Export current buffer to a HTML file.

Return output file's name."
  (interactive)
  (let* ((extension (concat "." org-html-extension))
         (file (org-export-output-file-name extension subtreep))
         (org-export-coding-system org-html-coding-system))
    (org-export-to-file 'my-html file
      async subtreep visible-only body-only ext-plist)))


(defun org-html-publish-to-my-html (plist filename pub-dir)
  "Publish an org file to my-html.
Return output file name."
  (org-publish-org-to 'my-html filename
                      (concat "." (or (plist-get plist :html-extension)
                                      org-html-extension "html"))
                      plist pub-dir))

(defun org-html-convert-region-to-my-html ()
  "Assume the current region has org-mode syntax, and convert it to HTML.
This can be used in any buffer.  For example, you can write an
itemized list in org-mode syntax in an HTML buffer and use this
command to convert it."
  (interactive)
  (org-export-replace-region-by 'my-html))

Поэтому, когда я использую C-c C-e h rэто экспортируется правильно:

Как предложено OP в комментариях, вам может понадобиться использовать org-mode-restart(или org-reload) или убить / перезагрузить ваш буфер.

Редактировать: это работает в режиме org с версиями до 8.3 (то есть до 8.2.10)

С версиями ≥8.3.1, я должен изменить

• орг-элемент-все-объекты
• возможно орг-элемент-объект-ограничения
• орг-элемент - набор-регэкспы
• орг-элемент - объект-LEX

и, конечно, еще добавить функции

• орг-элемент-мой-объект-нажатие клавиши-анализатор
• орг-элемент-мой-объект-нажатие клавиши-переводчик

но

• орг-элемент-объект-преемник-ALIST
• орг-элемент-текст-разметка правопреемник

сейчас удалены.

Спасибо Чарльзу Берри за помощь.

Я не думаю, что возможно добавить маркеры для новых параметров разметки в режиме орг.

Согласно этому посту 2012 года, похоже, что «маркеры выделения в режиме org будут жестко закодированы». Выполнение быстрого поиска в org-emph-rein org.elне показывает никакого кода, который на самом деле генерируется org-emph-reиз org-emphasis-alist. Исходя из этого, похоже, что org-emph-reне будет искать ничего, что вы добавляете org-emphasis-alist.

Это согласуется с моим опытом (я могу переопределить существующие маркеры выделения, но не могу заставить режим org распознать |или &или H).

Я не эксперт здесь, и хотел бы узнать, что я не прав :)