Как напечатать несколько переменных в строке?

Скажем, у меня есть некоторые переменные, которые я хочу распечатать на терминале, какой самый простой способ вывести их в строку?

В настоящее время я делаю что-то вроде этого:

Serial.print("Var 1:");Serial.println(var1);
Serial.print(" Var 2:");Serial.println(var2);
Serial.print(" Var 3:");Serial.println(var3);

Есть лучший способ сделать это?

ardprintfэто функция, которую я взломал вместе, которая симулирует printfчерез последовательное соединение. Эта функция (указана внизу) может быть вставлена ​​в начало файлов, где эта функция необходима. Это не должно создавать никаких конфликтов.

Это можно назвать похожим на printf. Посмотрите это в действии в этом примере:

void setup()
{
  Serial.begin(9600);
}

void loop()
{
  int l=2;
  char *j = "test";
  long k = 123456789;
  char s = 'g';
  float f = 2.3;

  ardprintf("test %d %l %c %s %f", l, k, s, j, f);

  delay(5000);

}

Ожидаемый результат:

test 2 123456789 g test 2.30

Прототип функции:

int ardprintf(char *, ...);

Возвращает количество аргументов, обнаруженных в вызове функции.

Это определение функции:

#ifndef ARDPRINTF
#define ARDPRINTF
#define ARDBUFFER 16
#include <stdarg.h>
#include <Arduino.h>

int ardprintf(char *str, ...)
{
  int i, count=0, j=0, flag=0;
  char temp[ARDBUFFER+1];
  for(i=0; str[i]!='\0';i++)  if(str[i]=='%')  count++;

  va_list argv;
  va_start(argv, count);
  for(i=0,j=0; str[i]!='\0';i++)
  {
    if(str[i]=='%')
    {
      temp[j] = '\0';
      Serial.print(temp);
      j=0;
      temp[0] = '\0';

      switch(str[++i])
      {
        case 'd': Serial.print(va_arg(argv, int));
                  break;
        case 'l': Serial.print(va_arg(argv, long));
                  break;
        case 'f': Serial.print(va_arg(argv, double));
                  break;
        case 'c': Serial.print((char)va_arg(argv, int));
                  break;
        case 's': Serial.print(va_arg(argv, char *));
                  break;
        default:  ;
      };
    }
    else 
    {
      temp[j] = str[i];
      j = (j+1)%ARDBUFFER;
      if(j==0) 
      {
        temp[ARDBUFFER] = '\0';
        Serial.print(temp);
        temp[0]='\0';
      }
    }
  };
  Serial.println();
  return count + 1;
}
#undef ARDBUFFER
#endif

** Чтобы напечатать %символ, используйте %%. *

Теперь доступно на Github Gists .

Обычно я не ставлю два ответа на вопрос, но я только сегодня нашел это , где вы можете использовать printf без буфера.

// Function that printf and related will use to print
int serial_putchar(char c, FILE* f) {
    if (c == '\n') serial_putchar('\r', f);
    return Serial.write(c) == 1? 0 : 1;
}

FILE serial_stdout;

void setup(){
    Serial.begin(9600);

    // Set up stdout
    fdev_setup_stream(&serial_stdout, serial_putchar, NULL, _FDEV_SETUP_WRITE);
    stdout = &serial_stdout;

    printf("My favorite number is %6d!\n", 12);
}

void loop() {
  static long counter = 0;
  if (millis()%300==0){
    printf("millis(): %ld\tcounter: %ld (%02X)\n", millis(), counter, counter++);
    delay(1);    
  }
}

Это все еще имеет ограничение с плавающей запятой.

редактировать: я думал, что я бы немного протестировать это, и это работает довольно хорошо. Я добавил лучший тест в цикл с форматированным выводом.

Это, вероятно, не лучше, просто другое. Вы можете использовать объект String для вывода. Эти объекты позволяют объединять и поддерживать автоматическое приведение типов.

Serial.begin(9600);
String label = "Var";
const byte nValues = 3;
int var[nValues] = {36, 72, 49};

for (int i = 0; i < nValues; i++) {
    String stuff = label + i + ": ";
    Serial.println(stuff + var[i]);
}

Обычно я использовал вкладки, чтобы улучшить последовательность в последовательном. Выстраивание вещей, как я, позволяет arduino срабатывать как можно быстрее, при этом он может заметить определенные изменения в переменных.

Попробуйте что-то вроде этого:

Serial.println("Var 1:\tVar 2tVar 3:");
Serial.print("\t");
Serial.print(var1);
Serial.print("\t");
Serial.print(var2);
Serial.print("\t");
Serial.print(var3);
Serial.println();

Или как то так:

Serial.print("Var 1:");Serial.println(var1);
Serial.print("\tVar 2:");Serial.println(var2);
Serial.print("\tVar 3:");Serial.println(var3);

Я использую это только для отладки, но:

int a = 10;
int b = 20;
Serial.println("a = " + String(a) + " and b = " + String(b));

Я новичок в мире Arduino, но недавно я обнаружил, что это обычный C ++ (без исключений и, вероятно, полиморфизм). Но вы все еще можете наслаждаться шаблонами. Поэтому мое решение заключается в использовании следующих шаблонов:

void myprint(void)
{
  Serial.println("");
}

template<typename ...Args>
void myprint(const uint64_t & val, Args && ...args)
{
  serialPrintUint64(val);
  myprint(args...);
}

template<typename T, typename ...Args>
void myprint(const T & t, Args && ...args)
{
  Serial.print(t);
  myprint(args...);
}

....

// somewhere in your code
myprint("type: ", results.decode_type, 
        "\t value: ", results.value, 
        "\t addr: ", results.address,
        "\t cmd: ", results.command);

Приятно, что здесь не используется дополнительная память и дополнительная обработка.

Я обычно (мучительно) придерживаюсь нескольких строк, Serial.printно когда это становится запутанным, я возвращаюсь к sprintf. Это раздражает тем, что у вас должен быть доступный буфер для этого.

Использование так же просто (??) как:

char buffer[35]; // you have to be aware of how long your data can be
                 // not forgetting unprintable and null term chars
sprintf(buffer,"var1:%i\tvar2:%i\tvar3:%i",var1,var2,var3);
Serial.println(buffer);

Предупреждение, хотя (по умолчанию) не поддерживает плавающие типы.

Использование Streaming.hвместо

Serial.print("Var 1:");Serial.println(var1);
Serial.print(" Var 2:");Serial.println(var2);
Serial.print(" Var 3:");Serial.println(var3);

можно написать

Serial << "Var 1:" << var1) << " Var 2:" << var2 << " Var 3:" << var3 << endl;

Определение <<в Streaming.hфактически переводит , что в серию обычных Serial.print()вызовов. То есть <<является синтаксическим сахаром, реализованным без увеличения размера кода.

Если вы не Streaming.hустановили, получите Streaming5.zipот arduiniana.org . Разархивируйте его в директорию вашей библиотеки, например в ~/sketchbook/libraries. Добавьте линию #include <Streaming.h>в эскизы, где вы используете <<в качестве оператора потока.

Предоставляются спецификаторы преобразования базы _HEX, _DEC, _OCT и _BIN, а также функция _FLOAT (с количеством десятичных знаков) и endl. Например, чтобы вывести значения широты и долготы в форме типа «Ваши координаты -23.123, 135.4567», можно написать:

Serial << "Your coordinates are " << _FLOAT(latitude,3) << ", " << _FLOAT(longitude,4) << endl;

Это также может быть написано как

Serial << F("Your coordinates are ") << _FLOAT(latitude,3) << ", " << _FLOAT(longitude,4) << endl;

который будет хранить более длинную строку в PROGMEM вместо того, чтобы переносить ее в RAM.

Обратите внимание, Streaming.h что не создает никаких строк как таковых; он просто доставляет текст своих <<аргументов в поток. Класс PString в arduiniana может построить строки из потока входов, если строки вместо поточного вывода желательны и необходимы.

Использование будет зависеть от типа данных ваших переменных.

Если бы они были int, это было бы, %dили %i если бы они были string, это было бы%s

Упаковщик для печати

Вы можете изменить лимит в зависимости от ваших требований

#include <stdarg.h>
void p(char *fmt, ... ){
    char buf[128]; // resulting string limited to 128 chars
    va_list args;
    va_start (args, fmt );
    vsnprintf(buf, 128, fmt, args);
    va_end (args);
    Serial.print(buf); // Output result to Serial
}

Источник: https://playground.arduino.cc/Main/Printf

Примеры использования:

p("Var 1:%s\nVar 2:%s\nVar 3:%s\n", var1, var2, var3); // strings
p("Var 1:%d\nVar 2:%d\nVar 3:%d\n", var1, var2, var3); // numbers

ESP8266

Его встроенный в Serialкласс каркас. Нет необходимости в дополнительной библиотеке или функции.

// strings
Serial.printf("Var 1:%s\nVar 2:%s\nVar 3:%s\n", var1, var2, var3);
// numbers
Serial.printf("Var 1:%d\nVar 2:%d\nVar 3:%d\n", var1, var2, var3);

Подробнее о советах по форматированию на странице справки по формату printf: http://www.cplusplus.com/reference/cstdio/printf/

\n является escape-последовательностью для перевода строки.

Escape-последовательности используются для представления определенных специальных символов в строковых литералах и символьных литералах.

Источник: http://en.cppreference.com/w/cpp/language/escape

[РЕДАКТИРОВАТЬ] - Как упомянул @Juraj, он недоступен на большинстве модулей AVR. Поэтому я добавил упоминание ESP8266 и оболочку printf для распространенных модулей AVR.

Одним из возможных решений является:

Serial.println((String)"Var 1:" + var1 + " Var 2:" + var2 + " Var 3:" + var3);

С http://playground.arduino.cc/Main/Printf Я заметил, что это нормально работает на моем mega2560

Вот и все, что сработало, нет необходимости в vsnprintf_P или PROGMEM ...

#include "Arduino.h"
void local_printf(const char *format, ...)
{
static char line[80];
va_list args;
va_start(args, format);
int len = vsnprintf(line, sizeof(line), format, args);
va_end(args);
for (char *p = &line[0]; *p; p++) {
    if (*p == '\n') {
        Serial.write('\r');
    }
    Serial.write(*p);
}
if (len >= sizeof(line))
    Serial.write('$');
}

void setup()
{
Serial.begin(115200);
local_printf("%s:%d: %s\n", __FILE__, __LINE__, __PRETTY_FUNCTION__);
}

void loop()
{
static int count=0;
local_printf("%s:%d: %s %d\n", __FILE__, __LINE__, __PRETTY_FUNCTION__, count++);
delay(1*1000);
}

// src/main.c:24: void setup()
// src/main.c:30: void loop() 0
// src/main.c:30: void loop() 1

int Money_amount = 55;

Serial.print(String("New amount: $" + Money_amount));

Вы увидите на терминале:

New amount: $55