Как установить ⌘ + H, чтобы включить показ скрытых файлов

Я хочу, чтобы мой Mac показывал скрытые файлы, когда я нажимаю ⌘ + H (как в Ubuntu). Я могу видеть скрытые файлы, помещая эту defaults write com.apple.finder AppleShowAllFiles YESкоманду в терминал, но я хочу получить сочетание клавиш для этого. Кроме того, если ⌘ + H уже используется каким-либо другим процессом, пожалуйста, дайте мне знать, какой может быть ближайший и наиболее связанный ярлык для этого нового процесса и как назначить его соответствующему процессу показа скрытых файлов.

Редактировать в ноябре 2018 года
Это все спорный со времен Высокой Сьерры. В Finder Cmd ⌘ Shift ⇧ . [точка, полная остановка] будет переключать невидимые файлы на лету, больше ничего не нужно.

Cmd ⌘ H это общесистемный ярлык для «Скрыть переднее приложение»

Чтобы попытаться привязать к этому новый ярлык, вы можете использовать Automator для добавления службы, но я до сих пор не знаю, как бы вы убедили его переопределить существующую систему по умолчанию.

Это работает как Сервис, если вы используете не системный ключ, но не с Cmd ⌘ H

on run {input, parameters}

    set newHiddenVisiblesState to "YES"
    try
        set oldHiddenVisiblesState to do shell script "defaults read com.apple.finder AppleShowAllFiles"
        if oldHiddenVisiblesState is in {"1", "YES"} then
            set newHiddenVisiblesState to "NO"
        end if
    end try
    do shell script "defaults write com.apple.finder AppleShowAllFiles " & newHiddenVisiblesState


    tell application "Finder"
        set theWindows to every Finder window
        repeat with i from 1 to number of items in theWindows
            set this_item to item i of theWindows
            set theView to current view of this_item
            if theView is list view then
                set current view of this_item to icon view
            else
                set current view of this_item to list view

            end if
            set current view of this_item to theView
        end repeat
    end tell

    return input
end run

Редактировать для El Capitan ...
Я заметил, что обновление окна Finder больше не работает в El Capitan, поэтому это модифицированная версия, вместо этого она выходит из Finder.

on run {input, parameters}      
    --Toggle Invisibles, El Capitan Version     
set newHiddenVisiblesState to "YES"
try
    set oldHiddenVisiblesState to do shell script "defaults read com.apple.finder AppleShowAllFiles"
    if oldHiddenVisiblesState is in {"1", "YES"} then
        set newHiddenVisiblesState to "NO"
    end if
end try
do shell script "defaults write com.apple.finder AppleShowAllFiles " & newHiddenVisiblesState & "; killall Finder"
end run

Я думаю, вы могли бы заставить его работать только для Finder, если бы вы указали какую-то другую ключевую команду для Hide Finder - так как она отображается как элемент меню, можно было бы переопределить только для этого приложения [поместив что-то «бесполезное» как альтернатива], оставляя вас свободными затем использовать Cmd ⌘ H для переключения невидимых только из Finder.

Проверено - работает ли так

Cmd ⌘ Shift ⇧ . переключит отображение скрытых файлов в поисковике (в Sierra или более поздних версиях (но работает в диалоге открытия файлов в более ранних версиях)).