Любой способ установить / добавить теги для файла с Applescript под Mavericks?

Попытка переместить некоторые из моих сценариев из меток в теги под Mavericks, но я не могу найти способ установить / добавить теги с помощью Applescript.

Кто-нибудь знает, как это сделать? Насколько я понимаю, теги на самом деле не новы, а просто являются более важной частью обновленного Finder.

Вы можете использовать xattr. Это копирует теги из файла1 в файл2:

xattr -wx com.apple.metadata:_kMDItemUserTags "$(xattr -px com.apple.metadata:_kMDItemUserTags file1)" file2
xattr -wx com.apple.FinderInfo "$(xattr -px com.apple.FinderInfo file1)" file2

Теги хранятся в списке свойств в виде единого массива строк:

$ xattr -p com.apple.metadata:_kMDItemUserTags file3|xxd -r -p|plutil -convert xml1 - -o -
<?xml version="1.0" encoding="UTF-8"?>
<!DOCTYPE plist PUBLIC "-//Apple//DTD PLIST 1.0//EN" "http://www.apple.com/DTDs/PropertyList-1.0.dtd">
<plist version="1.0">
<array>
    <string>Red
6</string>
    <string>aa</string>
    <string>Orange
7</string>
    <string>Yellow
5</string>
    <string>Green
2</string>
    <string>Blue
4</string>
    <string>Purple
3</string>
    <string>Gray
1</string>
</array>
</plist>

Теги для цветов имеют такие значения, как Red\n6(где \nперевод строки).

Если флаг kColor в com.apple.FinderInfo не установлен, Finder не показывает круги для цветов рядом с файлами. Если флаг kColor установлен в оранжевый цвет, а файл имеет красную метку, Finder отображает как красные, так и оранжевые кружки. Вы можете установить флаг kColor с помощью AppleScript:

do shell script "xattr -w com.apple.metadata:_kMDItemUserTags '(\"Red\\n6\",\"new tag\")' ~/desktop/file4"
tell application "Finder" to set label index of file "file4" of desktop to item 1 of {2, 1, 3, 6, 4, 5, 7}

'("Red\n6","new tag")' это синтаксис plist старого стиля для этого:

<?xml version="1.0" encoding="UTF-8"?>
<!DOCTYPE plist PUBLIC "-//Apple//DTD PLIST 1.0//EN" "http://www.apple.com/DTDs/PropertyList-1.0.dtd">
<plist version="1.0">
<array>
    <string>Red
6</string>
    <string>new tag</string>
</array>
</plist>

xattr -p com.apple.FinderInfo file|head -n1|cut -c28-29печатает значение битов, используемых для флага kColor. Красный - это C, оранжевый - это E, желтый - это A, зеленый - это 4, синий - это 8, пурпурный - это 6, а серый - это 2. (Флаг, который добавляет 1 к значениям, не используется в OS X.)

Ответ был опубликован в списке пользователей Applescript:

http://lists.apple.com/archives/applescript-users/2015/Jan/msg00193.html

цитата из кода страницы, написанная Шейном Стэнли

Вы можете сделать это достаточно легко с AppleScriptObjC. Вот обработчики для получения тегов, установки тегов и добавления тегов:

use scripting additions
use framework "Foundation"

on returnTagsFor:posixPath -- get the tags
    set aURL to current application's |NSURL|'s fileURLWithPath:posixPath -- make URL
    set {theResult, theTags} to aURL's getResourceValue:(reference) forKey:(current application's NSURLTagNamesKey) |error|:(missing value)
    if theTags = missing value then return {} -- because when there are none, it returns missing value
    return theTags as list
end returnTagsFor:

on setTags:tagList forPath:posixPath -- set the tags, replacing any existing tags
    set aURL to current application's |NSURL|'s fileURLWithPath:posixPath -- make URL
    aURL's setResourceValue:tagList forKey:(current application's NSURLTagNamesKey) |error|:(missing value)
end setTags:forPath:

on addTags:tagList forPath:posixPath -- add to existing tags
    set aURL to current application's |NSURL|'s fileURLWithPath:posixPath -- make URL
    -- get existing tags
    set {theResult, theTags} to aURL's getResourceValue:(reference) forKey:(current application's NSURLTagNamesKey) |error|:(missing value)
    if theTags ≠ missing value then -- add new tags
        set tagList to (theTags as list) & tagList
        set tagList to (current application's NSOrderedSet's orderedSetWithArray:tagList)'s allObjects() -- delete any duplicates
    end if
    aURL's setResourceValue:tagList forKey:(current application's NSURLTagNamesKey) |error|:(missing value)
end addTags:forPath:

Если вы сохраните их в библиотеке сценариев, вы также можете использовать их из Mavericks.

- Шейн Стэнли www.macosxautomation.com/applescript/apps/