Расположение значков на рабочем столе слева, а не справа

Любой способ автоматически создать псевдоним или значки для отображения на левой стороне рабочего стола Apple. По умолчанию они идут вправо.

Невозможно заставить значки автоматически перемещаться влево (и располагаться по выбранному вами критерию).

В качестве обходного пути вы можете изменить параметры просмотра в Finder, чтобы не упорядочивать элементы по какому-либо критерию, и размещать значки вручную слева.

• Нажмите на пустое место на рабочем столе.
• Нажмите Cmd+ Jили с помощью мыши перейдите в меню Finder's View> Show View Options .
• В раскрывающемся списке « Сортировать по:» в диалоговом окне выберите « Нет» или « Привязать к сетке» .
• Вы сможете сбросить файлы в любом месте на рабочем столе, и они останутся там.

Посмотрите Основы Mac: Измените свои окна для получения дополнительной информации.

Также просмотрите страницы Основ Mac, чтобы узнать больше об использовании Mac.

Это не лучшее решение, но оно может работать, если больше ничего не делает ...

1. Создайте действие папки Automator, связанное с рабочим столом.
2. Добавить пункт: «запустить яблочный скрипт»

3. Вставьте следующий код в текстовое поле AppleScript:

   -- https://gist.github.com/mrienstra/8330528
   -- Based on http://www.tuaw.com/2012/12/24/applescript-desktop-icon-race/
   -- Inspired by http://namesakecomic.com/comic/happy-new-year-from-namesake/#comment-1182035013
   
   -- Rearranges Desktop icons to flow from left to right, top to bottom.
   
   -- To have this run automatically every time files are added or removed from the Desktop, set this script to run as a Desktop "Folder Action". (See https://developer.apple.com/library/mac/documentation/applescript/conceptual/applescriptlangguide/reference/ASLR_folder_actions.html )
   
   -- This is currently a rough proof-of-concept. It has only been tested with OS X 10.8.5 (Mountain Lion).
   
   -- Current known limitations: Does not work with "Label position" set to "Right" (specifically, icons will overlap).
   
   
   
   -- Adjust these for different spacing
   property theSpacingFactor : 1.0
   property theGutterXFactor : 0.57
   property theGutterYFactor : 0.57
   
   
   
   on rearrangeDesktopIcons()
       tell application "Finder"
           tell icon view options of window of desktop
               set theArrangement to arrangement
               set theArrangementString to theArrangement as string
               if {"not arranged", "«constant ****narr»", "snap to grid", "«constant ****grda»"} does not contain theArrangementString then
                   display alert "\"Rearrange Desktop Icons\" AppleScript says:" message "Cannot rearrange Desktop items, please change Desktop \"Sort by\" to \"None\" or \"Snap to Grid\"." giving up after 10
                   return
               end if
               set theIconSize to icon size
               set theLabelSize to text size
           end tell
   
           set theDesktopBounds to bounds of window of desktop
           set theDesktopWidth to item 3 of theDesktopBounds
           set theDesktopHeight to item 4 of theDesktopBounds
   
           -- Retrieve a list of items on the desktop
           set theDesktopItems to every item of desktop
           set theContestantOffset to theIconSize / 2
   
           set theSpacing to (theIconSize + theLabelSize + theContestantOffset) * theSpacingFactor
           set theGuttersX to theSpacing * theGutterXFactor
           set theGuttersY to theSpacing * theGutterYFactor
           set theMaxColumns to ((theDesktopWidth - theGuttersX * 2) / theSpacing) as integer
           set theMaxRows to ((theDesktopHeight - theGuttersY * 2) / theSpacing) as integer
           set theMaxLocations to theMaxRows * theMaxColumns
   
           set y to 1
           repeat with a from 1 to length of theDesktopItems
               set x to a mod theMaxColumns
               if x is 0 then
                   set x to theMaxColumns
               end if
   
               if a is greater than theMaxLocations then
                   set desktop position of item a of theDesktopItems to {theGuttersX, theGuttersY}
               else
                   set desktop position of item a of theDesktopItems to {theGuttersX + (x - 1) * theSpacing, theGuttersY + (y - 1) * theSpacing}
               end if
   
               if a mod theMaxColumns is 0 then
                   set y to y + 1
               end if
           end repeat
       end tell
   end rearrangeDesktopIcons
   
   
   
   on adding folder items to alias after receiving listOfAlias
       rearrangeDesktopIcons()
   end adding folder items to
   
   on removing folder items from alias after losing listOfAliasOrText
       rearrangeDesktopIcons()
   end removing folder items from
   
   rearrangeDesktopIcons()
   

Таким образом, всякий раз, когда файл добавляется на рабочий стол, все файлы будут переставлены в алфавитном порядке ...

Организуйте все папки в том порядке, в котором вы хотите. Затем в представлении нажмите «очистить». Это выровняет все красиво. Затем вы можете просто выделить все папки и расположить их именно там, где вы хотите. Маки не упорядочивают папки слева, только справа, но с помощью пары простых шагов все можно аккуратно упорядочить слева.

Я просто выделил все папки с правой стороны, затем схватил их все и приклеил влево.